Remember previous DCL values(Default Values)
@desmund08 Here is my code that uses a file to store DCL tile values.
(setq _dialog_state_paths
(mapcar '(lambda (x)(strcat (getvar 'tempprefix) x))
(list
"dialog_1.txt"
"dialog_2.txt"
)
)
)
(defun create_temporary_files ( / f)
(foreach file _dialog_state_paths
(cond
((not (findfile file))
(setq f (open file "w"))
(close f)
(setq f nil)
)
)
)
)
(defun string_to_list ( str del / pos )
(if (setq pos (vl-string-search del str))
(cons (substr str 1 pos) (string_to_list (substr str (+ pos 1 (strlen del))) del))
(list str)
)
)
(defun dialog_out(filename keylist / file1 val)
(setq file1 (open filename "w"))
(foreach key keylist
(setq val (get_tile key))
(if val
(progn
(write-line (strcat key " " val) file1)
)
)
)
(close file1)
(princ)
)
(defun dialog_in (filename / f lin)
(setq f (open filename "r"))
(while (setq lin (read-line f))
(setq lin (string_to_list lin " "))
(set_tile (car lin) (cadr lin))
)
(close f)
(princ)
)
(defun file_to_list (filename / f lin ret)
(setq f (open filename "r"))
(while (setq lin (read-line f))
(setq lin (string_to_list lin " "))
(setq ret (cons (cons (car lin) (cadr lin)) ret))
)
(close f)
(reverse ret)
)
(defun list_to_file (lst filename / f)
(setq f (open filename "w"))
(foreach el lst
(write-line (strcat (car el) " " (cdr el)) f)
)
(close f)
)
(defun replace_list_element (lst key val / old_item new_item)
(setq
old_item (assoc key lst)
new_item (cons key val)
lst (subst new_item old_item lst)
)
)
;usage
(setq dcl_tiles '("tile_1" "tile_2" "tile_3" "tile_4") ; this are names of dcl tiles
(dialog_out (nth 0 _dialog_state_paths) dcl_tiles)
(dialog_in (nth 0 _dialog_state_paths) dcl_tiles)
Output files are created in system temporary directory.
In variable _dialog_state_paths place names of output files and run function create_temporary_files to create them
(create_temporary_files)
For any function handles DCL dialogs use functions dialog_in and dialog_out to read or store values.
DCL tile names of particular dialog should be stored inside localized variable dcl_tiles that is a list of tile names.
Here you also have helper functions list_to_file, file_to_list and replace_list_element that can be used to store values in a list for further usage in a code.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
I you would use my code then simply use this pattern
(new_dialog "dialog_id" dcl_id)
(action_tile "bla" "(bla_action)")
.
.
.
(dialog_in (nth i _dialog_state_paths)); i is order num of file name
(start_dialog)
(done_dialog id)
In function that handle dialog before exit use dialog_out
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
In attachment you have a sample lisp with dcl file. Try to figure out how it works.
Run it with command TESTDCL.
Place test.dcl in to root of your D disc or change path inside a code.
Best way to learn programming is to read code and to rewrite it to your particular case.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@desmund08 wrote:
I have a lisp with dcl that is working already but I want my previous values to be the default value when I run the program again.
Desmund
I would use Drawing Properties. Not only the program will save the default on the current session, but also on the drawing itself. The last value will be the default wehn the file is opened once again.
(defun C:fruitBasket (/ _WhatIsSelected _SummaryInfo aDoc dProps dcl_id)
(Defun _WhatIsSelected ()
(mapcar
'(lambda (r)
(vl-some '(lambda (rd)
(if (eq "1" (get_tile rd))
rd
)
)
r
)
)
'(("fruit1" "fruit2" "fruit3")
("storage1" "storage2" "storage3")
("quantity1" "quantity2" "quantity3"
"quantity4" "quantity5" "quantity10"
"quantity15"
)
)
)
)
(defun _SummaryInfo (lst dp)
((lambda (n)
(mapcar
'(lambda (key)
(cond
((vl-catch-all-error-p
(vl-catch-all-apply
'vla-GetCustomByKey
(list dp (Car key) 'value)
)
)
(vla-AddCustomInfo dp (Car key) (Cadr key))
(Cadr key)
)
(lst
(vla-SetCustomByKey
dp
(Car key)
(setq v (nth (Setq n (1+ n)) lst))
)
v
)
(value)
)
)
'(("RADIO1" "fruit1")
("RADIO2" "storage1")
("RADIO3" "quantity1")
)
)
)
-1
)
)
(setq aDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
(setq dProps (vla-get-SummaryInfo aDoc))
(setq dcl_id (load_dialog "D:\\Downloads\\DCL_TEST.DCL"))
(if (not (new_dialog "FRUIT_TEST" dcl_id))
(exit)
) ;if
(mapcar '(lambda (r) (set_tile r "1"))
(_SummaryInfo lst dProps)
)
(action_tile "cancel" "(setq dia 1)(done_dialog)")
(action_tile
"accept"
"(setq lst (_WhatIsSelected))
(_SummaryInfo lst dProps)(setq dia 2) (done_dialog)"
)
(start_dialog)
(unload_dialog dcl_id)
lst
)
HTH
@desmund08 wrote:
Thanks @pbejse for always replying to my posts.
The correct block will only be inserted on the second try without changing the tiles.
Permit me to modify your dcl file.
:boxed_column {
key="RADIO2";
label = "STORAGE";
:radio_button{label="Plastic Bag"; key="0";}
:radio_button{label="Paper Bag"; key="1"; }
:radio_button{label="No need";key="2";}
}
}
: boxed_column{
key="RADIO3";
label="QUANTITY";
:radio_button{label="1";key="00";}
:radio_button{label="2";key="01";}
:radio_button{label="3";key="02";}
:radio_button{label="4";key="03";}
:radio_button{label="5";key="04";}
:radio_button{label="10";key="05";}
:radio_button{label="15";key="06";
}
}
The key represents the position of the path and block name respectively [ 0 index ]
(setq _Path&block '( ("c:\\xxx\\" ("111" "222" "333" "444" "555" "666" "777"))
("c:\\yyy\\" ("xx1" "xx2" "xx3" "xx4" "xx5" "xx6" "xx7"))
("c:\\zzz\\" ("y1" "y2" "y3" "y4" "y5" "y6" "y7"))))
The lisp would be a lot shorter and includes all the combinations of fruit and storage
(cond ( (zerop flag) (princ "\nCancelled.") ) ( (and (= flag 1) (setq storage (nth (atoi (Cadr lst)) _Path&block) quantity (nth (atoi (Caddr lst)) (cadr storage)) ) (findfile (setq filetoInsert (strcat (car storage) quantity ".dwg")) ) ) (command "-insert" filetoInsert "\\" 1 1 "\\") ) ( T (princ (strcat "\n" filetoInsert " Not found")) ) )
HTH
@desmund08 wrote:
When I change the fruit but same storage and quantity, the block inserted is always the same.
I see, post here what would be the result if
Apple , Paper Bag, 5
Strawberry, Paper bag, 5
Strawberry, No need, 4
Orange,No need, 5
Apple , No need, 5
@desmund08 wrote:
Apple , Paper Bag, 5 - xx5
Strawberry, Paper bag, 5 - xx5
Strawberry, No need, 4 - y4
Orange,No need, 5 - y5
Apple , No need, 5 - y5
What you posted is exactly what the result from the code
c:\yyy\xx5.dwg
c:\yyy\xx5.dwg
c:\zzz\y4.dwg
c:\zzz\y5.dwg
c:\zzz\y5.dwg
I'm asking for the supposedly "correct" results Desmund
