Programming Challenge 11/22
You forgot to mention there are 2 solutions minimum a simple left and right circles has a solution of a top or bottom line, never mind that you could end up with the bow tie answer.
Hi,
My 2 cents.
(defun challenge11 (circle1 circle2 / c1 c2 r1 r2 a1 b c d a2)
(setq c1 (getpropertyvalue circle1 "Center")
r1 (getpropertyvalue circle1 "Radius")
c2 (getpropertyvalue circle2 "Center")
r2 (getpropertyvalue circle2 "Radius")
a1 (angle c1 c2)
b (- r1 r2)
c (distance c1 c2)
d (sqrt (- (* c c) (* b b)))
a2 (atan d b)
)
(list
;; first tangent
(entmakex
(list (cons 0 "LINE")
(cons 10 (polar c1 (+ a1 a2) r1))
(cons 11 (polar c2 (+ a1 a2) r2))
)
)
;; second tangent
(entmakex
(list (cons 0 "LINE")
(cons 10 (polar c1 (- a1 a2) r1))
(cons 11 (polar c2 (- a1 a2) r2))
)
)
)
)
The same as in reply #5 rewritten in a more DRY (Don't Repeat Yourself) style.
;; assign
;; Assigns DXF values of the supplied ename to the symbols
;;
;; Arguments
;; ename : ename of the object
;; codeSymList : list of dotted pairs (dxfGroupCode . symbol)
;;
;; Example;
;; (assign line '((10 . startPt) (11 . endPt)))
(defun assign (ename codeSymList / l)
(setq l (entget ename))
(mapcar
'(lambda (x) (set (cdr x) (cdr (assoc (car x) l))))
codeSymList
)
)
(defun challenge11 (circle1 circle2 / c1 r1 c2 r2 a1 b c d a2)
(assign circle1 '((10 . c1) (40 . r1)))
(assign circle2 '((10 . c2) (40 . r2)))
(setq a1 (angle c1 c2)
b (- r1 r2)
c (distance c1 c2)
d (sqrt (- (* c c) (* b b)))
a2 (atan d b)
)
(mapcar
'(lambda (a)
(entmakex
(list (cons 0 "LINE")
(cons 10 (polar c1 a r1))
(cons 11 (polar c2 a r2))
)
)
)
(list (+ a1 a2) (- a1 a2))
)
)
@john.uhden a écrit :
If there is a shorter line vs. a longer line, we want the shorter one.
I forgot that. This version draws the "inside" tangents.
(defun assign (ename codeSymList / l)
(setq l (entget ename))
(mapcar
'(lambda (x) (set (cdr x) (cdr (assoc (car x) l))))
codeSymList
)
)
(defun insideTangents (circle1 circle2 / c1 r1 c2 r2 a1 b c d a2)
(assign circle1 '((10 . c1) (40 . r1)))
(assign circle2 '((10 . c2) (40 . r2)))
(setq a1 (angle c1 c2)
b (/ r1 r2)
c (/ (* (distance c1 c2) b) (+ 1 b))
d (sqrt (- (* c c) (* r1 r1)))
a2 (atan d r1)
)
(mapcar
'(lambda (a)
(entmakex
(list (cons 0 "LINE")
(cons 10 (polar c1 a r1))
(cons 11 (polar c2 (+ a pi) r2))
)
)
)
(list (+ a1 a2) (- a1 a2))
)
)
Regards @john.uhden
Here my focus...
(defun c:tanC (/ spm smj smin p1 r1 p2 r2 pmid d scn1 scn2 lpt px1 prx1 px2 prx2
pt1 pt2 pt3 pt4
)
(setq
spm (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
)
(setq smj (car (entsel "Select Greater Circle: "))
smin (car (entsel "Select smaller circle: "))
p1 (cdr (assoc 10 (entget smj)))
r1 (cdr (assoc 40 (entget smj)))
p2 (cdr (assoc 10 (entget smin)))
r2 (cdr (assoc 40 (entget smin)))
pmid (mapcar '* (mapcar '+ p1 p2) '(0.5 0.5 0.))
d (distance p1 p2)
)
;circles aux.
(setq scn1 (vla-addcircle spm (vlax-3d-point pmid) (* d 0.5))
scn2 (vla-addcircle spm (vlax-3d-point p1) (- r1 r2))
)
(setq lpt (vlax-safearray->list
(vlax-variant-value (vla-intersectwith scn1 scn2 acextendnone))
)
) ;List intersecciones
(setq px1 (list (nth 0 lpt) (nth 1 lpt) (nth 2 lpt))
prx1 (vlax-curve-getparamatpoint scn2 px1)
px2 (list (nth 3 lpt) (nth 4 lpt) (nth 5 lpt))
prx2 (vlax-curve-getparamatpoint scn2 px2)
pt1 (vlax-curve-getpointatparam smj prx1)
pt2 (vlax-curve-getpointatparam smin prx1)
)
(vla-addline spm (vlax-3d-point pt1) (vlax-3d-point pt2))
(setq pt3 (vlax-curve-getpointatparam smj prx2)
pt4 (vlax-curve-getpointatparam smin prx2)
)
(vla-addline spm (vlax-3d-point pt3) (vlax-3d-point pt4))
(vla-erase scn1)
(vla-erase scn2)
)
Carlos Calderon G
>Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@john.uhden a écrit :
But you didn't demonstrate which one(s) is/are the shortest.
The crossing ones are always shortest.
@john.uhden a écrit :
@Anonymous
BTW, I think @_gile is right... The lines that cross between the two circles are always the shortest.
Yes, because r1+r2 is always greater than r1-r2.
