- Home
- /
- Architecture, Engineering & Construction
- /
- AutoCAD Forums
- /
- Visual LISP, AutoLISP and General Customization Forum
- /
- Populate text field with sum of lines, polylines, and arcs
Populate text field with sum of lines, polylines, and arcs
Options
- Subscribe to RSS Feed
- Mark Topic as New
- Mark Topic as Read
- Float this Topic for Current User
- Bookmark
- Subscribe
- Mute
- Printer Friendly Page
Populate text field with sum of lines, polylines, and arcs
Collaborator
807 Views
5 Replies
Replies (5)
Message 3 of 6
- Mark as New
- Bookmark
- Subscribe
- Mute
- Subscribe to RSS Feed
- Permalink
- Report
That looks promising. Thanks!
AEC Collection 2022
WIN 10 PRO
Dell 3650, Intel i9-11900k @ 3.50GHz, 64 GB
NVIDIA QUADRO RTX 4000
http://www.cobbfendley.com
WIN 10 PRO
Dell 3650, Intel i9-11900k @ 3.50GHz, 64 GB
NVIDIA QUADRO RTX 4000
http://www.cobbfendley.com
Message 4 of 6
- Mark as New
- Bookmark
- Subscribe
- Mute
- Subscribe to RSS Feed
- Permalink
- Report
That works really well.
I tried to do some editing so that it would automatically select the layer and objects I wanted.
After my edits when I use AP to load I get this message on the command line Specify point or table cell [Object/eXit] <eXit>: so it looks like it trying to run something when I close the AP dialog box.
When I cancel the above and run the lisp it will select the items but it after selecting objects its stops, doesn't continue to the sum and text portion. I've posted the code; my edits are lines 151-154.
;;----------------------------------------------------------------------;;
;; Length Field Commands ;;
;;----------------------------------------------------------------------;;
(defun c:lf ( ) (lengthfield nil t "%lu6")) ;; Current units, subtraction prompt
(defun c:lfm ( ) (lengthfield nil nil "%lu6%ct8[0.001]")) ;; Current units with 0.001 conversion factor (mm->m), no subtraction prompt
;;----------------------------------------------------------------------;;
;; Area Field Commands ;;
;;----------------------------------------------------------------------;;
(defun c:af ( ) (areafield nil t "%lu6%qf1")) ;; Current units, subtraction prompt
(defun c:afm ( ) (areafield nil nil "%lu6%qf1%ct8[1e-6]")) ;; Current units with 1e-6 (0.000001) conversion factor (mm2->m2), no subtraction prompt
;;----------------------------------------------------------------------;;
;;----------------------=={ Length & Area Field }==---------------------;;
;; ;;
;; This program offers two commands to allow a user to generate a ;;
;; field expression referencing either the area or the ;;
;; length/perimeter/circumference of one or more selected objects. ;;
;; In the case of selecting multiple objects, the field expression ;;
;; will reference the sum of the areas or lengths of all objects in ;;
;; the selection. ;;
;; ;;
;; The user may opt to specify a point at which to create a new ;;
;; multiline text object housing the field expression, pick a table ;;
;; cell in which the field should be inserted, or select an existing ;;
;; single-line text, multiline text, multileader, or attribute to ;;
;; be populated with the field expression. ;;
;; ;;
;; Upon issuing the command syntax 'LF' (Length Field) at the AutoCAD ;;
;; command-line, the program first prompts the user to make a ;;
;; selection of objects for which to return the length summation. ;;
;; ;;
;; At this prompt, the user may select any number of Arcs, Circles, ;;
;; Lines, 2D Polylines (light or heavy), or 3D Polylines. ;;
;; ;;
;; Alternatively, upon issuing the command syntax 'AF' (Area Field) ;;
;; at the AutoCAD command-line, the program will prompt the user to ;;
;; make a selection of objects for which to return the area summation. ;;
;; ;;
;; At this prompt, the user may select any number of Arcs, Circles, ;;
;; Ellipses, Hatches, 2D Polylines (light or heavy), Regions, or ;;
;; Splines. If the selected object is open, the area is computed as ;;
;; though a straight line connects the start point and endpoint. ;;
;; ;;
;; The user is then prompted to specify a point or table cell to ;;
;; insert a field expression referencing the summation of the lengths ;;
;; or areas of the selected objects. ;;
;; ;;
;; At this prompt, the user may also choose the 'Object' option in ;;
;; order to populate the content of an existing annotation object ;;
;; with the field expression. ;;
;; ;;
;; Upon choosing this option, the user may select any single-line ;;
;; text (DText), multiline text (MText), single-line or multiline ;;
;; attribute, attributed block, or multileader (MLeader) with either ;;
;; multiline text or attributed block content. ;;
;; ;;
;; If the user selects an attributed block or attributed multileader ;;
;; with more than one attribute, the user is presented with a dialog ;;
;; interface listing the available attributes, and is prompted to ;;
;; select a destination for the field expression. ;;
;; ;;
;; The user may optionally predefine the target block/multileader ;;
;; attribute by specifying the attribute tag where noted at the top ;;
;; of the program source code. ;;
;; ;;
;; The resulting field expression will display the sum of the lengths ;;
;; or areas of the selected objects, formatted using the field ;;
;; formatting code specified at the top of each command definition. ;;
;; ;;
;;----------------------------------------------------------------------;;
;; Author: Lee Mac, Copyright © 2017 - www.lee-mac.com ;;
;;----------------------------------------------------------------------;;
;; Version 1.0 - 2017-08-06 ;;
;; ;;
;; - First release. ;;
;;----------------------------------------------------------------------;;
;; Version 1.1 - 2017-08-06 ;;
;; ;;
;; - Program modified to account for selection of existing annotation ;;
;; objects which already contain a field expression. ;;
;;----------------------------------------------------------------------;;
;; Version 1.2 - 2018-10-29 ;;
;; ;;
;; - Restructured program to use standard LM:outputtext function. ;;
;; - Incorporated Area Field functionality and added new 'AF' command. ;;
;;----------------------------------------------------------------------;;
;; Version 1.3 - 2018-11-04 ;;
;; ;;
;; - Changed 'c:lf' and 'c:af' commands to functions accepting an ;;
;; optional attribute tag and field formatting argument to enable ;;
;; the user to create multiple commands with varying parameters. ;;
;;----------------------------------------------------------------------;;
;; Version 1.4 - 2022-09-05 ;;
;; ;;
;; - Added optional prompt for lengths & areas to be subtracted. ;;
;;----------------------------------------------------------------------;;
;; tag - [str] Optional target attribute tag (nil for none)
;; sub - [bol] Optional subtraction prompt (t/nil)
;; fmt - [str] Optional field formatting string (nil for none)
(defun lengthfield ( tag sub fmt / *error* ftr idx lst obj prp ss1 ss2 )
(defun *error* ( msg )
(LM:endundo (LM:acdoc))
(if (and msg (not (wcmatch (strcase msg t) "*break,*cancel*,*exit*")))
(princ (strcat "\nError: " msg))
)
(princ)
)
(LM:startundo (LM:acdoc))
(setq pfn
(lambda ( obj )
(cdr
(assoc (vla-get-objectname obj)
'(
("AcDbArc" . "ArcLength")
("AcDbCircle" . "Circumference")
("AcDbLine" . "Length")
("AcDbPolyline" . "Length")
("AcDb2dPolyline" . "Length")
("AcDb3dPolyline" . "Length")
)
)
)
)
)
(setq ftr
(list
(list
'(000 . "ARC,CIRCLE,LINE,*POLYLINE")
'(-04 . "<NOT")
'(-04 . "<AND")
'(000 . "POLYLINE") '(-04 . "&") '(070 . 80)
'(-04 . "AND>")
'(-04 . "NOT>")
(if (= 1 (getvar 'cvport))
(cons 410 (getvar 'ctab))
'(410 . "Model")
)
)
)
)
(setq sel1 (ssget "_X" '((-4 . "<AND")(000 . "ARC,LINE,*POLYLINE")(8 . "DNP")(-4 . "AND>"))))
(sssetfirst nil sel1)
(princ)
)
(LM:outputtext tag (apply 'strcat lst))
)
)
(*error* nil) (princ)
)
;;----------------------------------------------------------------------;;
;; tag - [str] Optional target attribute tag (nil for none)
;; sub - [bol] Optional subtraction prompt (t/nil)
;; fmt - [str] Optional field formatting string (nil for none)
;; Output Text - Lee Mac
;; Prompts the user to specify a point at which to create an MText object containing the supplied string or to
;; select a table cell, text, mtext, multileader, attribute, or attributed block to be populated with the supplied string.
;; tag - [str] Optional target attribute tag
;; str - [str] Field expression or other text content
(defun LM:outputtext ( tag str / ent enx flg idx obj oid sel tab tmp typ )
(if
(setq tmp
(ssget "_X"
(list '(0 . "ACAD_TABLE")
(if (= 1 (getvar 'cvport))
(cons 410 (getvar 'ctab))
'(410 . "Model")
)
)
)
)
(repeat (setq idx (sslength tmp))
(setq tab (cons (vlax-ename->vla-object (ssname tmp (setq idx (1- idx)))) tab))
)
)
(while
(not
(progn
(if flg
(progn
(setvar 'errno 0)
(initget "Point eXit")
(setq sel (nentsel "\nSelect text, mtext, mleader, attribute or attributed block [Point/eXit] <eXit>: "))
)
(progn
(initget "Object eXit")
(setq sel (getpoint "\nSpecify point or table cell [Object/eXit] <eXit>: "))
)
)
(cond
( (= 7 (getvar 'errno))
(prompt "\nMissed, try again.")
)
( (or (null sel) (= "eXit" sel)))
( (= "Point" sel)
(setq flg nil)
)
( (= "Object" sel)
(not (setq flg t))
)
( flg
(setq ent (car sel)
enx (entget ent)
typ (cdr (assoc 0 enx))
obj (vlax-ename->vla-object ent)
)
(cond
( (and (= 2 (length sel)) (wcmatch typ "TEXT,MTEXT"))
(if (vlax-write-enabled-p obj)
(LM:outputtext:puttextstring obj str)
(prompt "\nThe selected text object is on a locked layer.")
)
)
( (and (= "ATTRIB" typ)
(/= 'str (type tag))
)
(if (vlax-write-enabled-p obj)
(progn
(LM:outputtext:puttextstring obj str)
(if (wcmatch (strcase str t) "*%<\\ac*>%*") (LM:outputtext:updatefield ent))
)
(prompt "\nThe selected attribute is on a locked layer.")
)
)
( (and
(or
(and (= "ATTRIB" typ)
(setq tmp (cdr (assoc 330 enx)))
)
(and (setq tmp (last (cadddr sel)))
(= "INSERT" (cdr (assoc 0 (entget tmp))))
)
)
(setq tmp (vlax-invoke (vlax-ename->vla-object tmp) 'getattributes))
(or
(and (= 'str (type tag))
(setq idx (vl-position (strcase tag) (mapcar 'vla-get-tagstring tmp)))
(setq obj (nth idx tmp))
)
(and (not (cdr tmp))
(setq obj (car tmp))
)
(and (setq idx (LM:listbox "Choose Attribute" (mapcar 'vla-get-tagstring tmp) 2))
(setq obj (nth (car idx) tmp))
)
)
)
(if (vlax-write-enabled-p obj)
(progn
(LM:outputtext:puttextstring obj str)
(if (wcmatch (strcase str t) "*%<\\ac*>%*") (LM:outputtext:updatefield (vlax-vla-object->ename obj)))
)
(prompt "\nThe selected attribute is on a locked layer.")
)
)
( (and (= 2 (length sel)) (= "MULTILEADER" typ))
(setq typ (cdr (assoc 172 (reverse enx))))
(cond
( (and (<= acblockcontent typ acmtextcontent) (not (vlax-write-enabled-p obj)))
(prompt "\nThe selected multileader is on a locked layer.")
)
( (= acmtextcontent typ)
(LM:outputtext:puttextstring obj str)
(if (wcmatch (strcase str t) "*%<\\ac*>%*") (vla-regen (LM:acdoc) acactiveviewport))
t
)
( (and
(= acblockcontent typ)
(setq tmp (LM:getmleaderattributes obj))
(or
(and (= 'str (type tag))
(setq oid (cdr (assoc (strcase tag) tmp)))
)
(and (not (cdr tmp))
(setq oid (cdar tmp))
)
(and (setq idx (LM:listbox "Choose Attribute" (mapcar 'car tmp) 2))
(setq oid (cdr (nth (car idx) tmp)))
)
)
)
(LM:setmleaderattributevalue obj oid str)
(if (wcmatch (strcase str t) "*%<\\ac*>%*") (vla-regen (LM:acdoc) acactiveviewport))
t
)
( (prompt "\nThe select multileader has no editable content."))
)
)
( (prompt "\nThe selected object is not text, mtext, multileader, attribute or attributed block."))
)
)
( (setq tmp (LM:getcell tab (trans sel 1 0)))
(if (vlax-write-enabled-p (car tmp))
(not (vl-catch-all-error-p (vl-catch-all-apply 'vla-settext (append tmp (list str)))))
(prompt "\nThe selected table cell belongs to a table on a locked layer.")
)
)
( (vla-addmtext
(vlax-get-property (LM:acdoc) (if (= 1 (getvar 'cvport)) 'paperspace 'modelspace))
(vlax-3D-point (trans sel 1 0))
0.0
str
)
)
)
)
)
)
)
(defun LM:outputtext:puttextstring ( obj str )
(vla-put-textstring obj "") ;; To clear any existing field
(vla-put-textstring obj str)
t
)
(defun LM:outputtext:updatefield ( ent / cmd rtn )
(setq cmd (getvar 'cmdecho))
(setvar 'cmdecho 0)
(setq rtn (vl-cmdf "_.updatefield" ent ""))
(setvar 'cmdecho cmd)
rtn
)
;; ssget - Lee Mac
;; A wrapper for the ssget function to permit the use of a custom selection prompt
;; msg - [str] selection prompt
;; arg - [lst] list of ssget arguments
(defun LM:ssget ( msg arg / sel )
(princ msg)
(setvar 'nomutt 1)
(setq sel (vl-catch-all-apply 'ssget arg))
(setvar 'nomutt 0)
(if (not (vl-catch-all-error-p sel)) sel)
)
;; Get MLeader Attributes - Lee Mac
;; Returns an association list of attribute tags & object IDs for all attributes held by an mleader block
;; mld - [vla] MLeader vla-object
;; Returns: [lst] List of ((<Attribute Tag> . <Object ID>) ... )
(defun LM:getmleaderattributes ( mld / rtn )
(vlax-for obj (vla-item (vla-get-blocks (vla-get-document mld)) (vla-get-contentblockname mld))
(if
(and
(= "AcDbAttributeDefinition" (vla-get-objectname obj))
(= :vlax-false (vla-get-constant obj))
)
(setq rtn (cons (cons (strcase (vla-get-tagstring obj)) (LM:intobjectid obj)) rtn))
)
)
(reverse rtn)
)
;; Object ID (integer) - Lee Mac
;; Returns an integer representing the ObjectID of a supplied VLA-Object
;; Compatible with 32-bit & 64-bit systems
(defun LM:intobjectid ( obj )
(if (vlax-property-available-p obj 'objectid32)
(defun LM:intobjectid ( obj ) (vla-get-objectid32 obj))
(defun LM:intobjectid ( obj ) (vla-get-objectid obj))
)
(LM:intobjectid obj)
)
;; Set MLeader Attribute Value - Lee Mac
;; obj - [vla] MLeader vla-object
;; idx - [int] Attribute Definition Object ID
;; str - [str] Attribute value
(defun LM:setmleaderattributevalue ( obj idx str )
(if (vlax-method-applicable-p obj 'setblockattributevalue32)
(defun LM:setmleaderattributevalue ( obj idx str ) (vla-setblockattributevalue32 obj idx str))
(defun LM:setmleaderattributevalue ( obj idx str ) (vla-setblockattributevalue obj idx str))
)
(LM:setmleaderattributevalue obj idx str)
)
;; List Box - Lee Mac
;; Displays a DCL list box allowing the user to make a selection from the supplied data.
;; msg - [str] Dialog label
;; lst - [lst] List of strings to display
;; bit - [int] 1=allow multiple; 2=return indexes
;; Returns: [lst] List of selected items/indexes, else nil
(defun LM:listbox ( msg lst bit / dch des tmp rtn )
(cond
( (not
(and
(setq tmp (vl-filename-mktemp nil nil ".dcl"))
(setq des (open tmp "w"))
(write-line
(strcat "listbox:dialog{label=\"" msg "\";spacer;:list_box{key=\"list\";multiple_select="
(if (= 1 (logand 1 bit)) "true" "false") ";width=50;height=15;}spacer;ok_cancel;}"
)
des
)
(not (close des))
(< 0 (setq dch (load_dialog tmp)))
(new_dialog "listbox" dch)
)
)
(prompt "\nError Loading List Box Dialog.")
)
( t
(start_list "list")
(foreach itm lst (add_list itm))
(end_list)
(setq rtn (set_tile "list" "0"))
(action_tile "list" "(setq rtn $value)")
(setq rtn
(if (= 1 (start_dialog))
(if (= 2 (logand 2 bit))
(read (strcat "(" rtn ")"))
(mapcar '(lambda ( x ) (nth x lst)) (read (strcat "(" rtn ")")))
)
)
)
)
)
(if (< 0 dch)
(unload_dialog dch)
)
(if (and tmp (setq tmp (findfile tmp)))
(vl-file-delete tmp)
)
rtn
)
;; Get Cell - Lee Mac
;; If the supplied point lies within a cell boundary,
;; returns a list of: (<VLA Table Object> <Row> <Col>)
(defun LM:getcell ( lst pnt / dir )
(setq dir (vlax-3D-point (trans (getvar 'viewdir) 1 0))
pnt (vlax-3D-point pnt)
)
(vl-some
'(lambda ( tab / row col )
(if (= :vlax-true (vla-hittest tab pnt dir 'row 'col))
(list tab row col)
)
)
lst
)
)
;; ObjectID - Lee Mac
;; Returns a string containing the ObjectID of a supplied VLA-Object
;; Compatible with 32-bit & 64-bit systems
(defun LM:objectid ( obj )
(eval
(list 'defun 'LM:objectid '( obj )
(if (wcmatch (getenv "PROCESSOR_ARCHITECTURE") "*64*")
(if (vlax-method-applicable-p (vla-get-utility (LM:acdoc)) 'getobjectidstring)
(list 'vla-getobjectidstring (vla-get-utility (LM:acdoc)) 'obj ':vlax-false)
'(LM:ename->objectid (vlax-vla-object->ename obj))
)
'(itoa (vla-get-objectid obj))
)
)
)
(LM:objectid obj)
)
;; Entity Name to ObjectID - Lee Mac
;; Returns the 32-bit or 64-bit ObjectID for a supplied entity name
(defun LM:ename->objectid ( ent )
(LM:hex->decstr
(setq ent (vl-string-right-trim ">" (vl-prin1-to-string ent))
ent (substr ent (+ (vl-string-position 58 ent) 3))
)
)
)
;; Hex to Decimal String - Lee Mac
;; Returns the decimal representation of a supplied hexadecimal string
(defun LM:hex->decstr ( hex / foo bar )
(defun foo ( lst rtn )
(if lst
(foo (cdr lst) (bar (- (car lst) (if (< 57 (car lst)) 55 48)) rtn))
(apply 'strcat (mapcar 'itoa (reverse rtn)))
)
)
(defun bar ( int lst )
(if lst
(if (or (< 0 (setq int (+ (* 16 (car lst)) int))) (cdr lst))
(cons (rem int 10) (bar (/ int 10) (cdr lst)))
)
(bar int '(0))
)
)
(foo (vl-string->list (strcase hex)) nil)
)
;; Start Undo - Lee Mac
;; Opens an Undo Group.
(defun LM:startundo ( doc )
(LM:endundo doc)
(vla-startundomark doc)
)
;; End Undo - Lee Mac
;; Closes an Undo Group.
(defun LM:endundo ( doc )
(while (= 8 (logand 8 (getvar 'undoctl)))
(vla-endundomark doc)
)
)
;; Active Document - Lee Mac
;; Returns the VLA Active Document Object
(defun LM:acdoc nil
(eval (list 'defun 'LM:acdoc 'nil (vla-get-activedocument (vlax-get-acad-object))))
(LM:acdoc)
)
;;----------------------------------------------------------------------;;
(vl-load-com)
(princ
(strcat
"\n:: LengthAreaField.lsp | Version 1.4 | \\U+00A9 Lee Mac "
((lambda ( y ) (if (= y (menucmd "m=$(edtime,0,yyyy)")) y (strcat y "-" (menucmd "m=$(edtime,0,yyyy)")))) "2017")
" www.lee-mac.com ::"
"\n:: \"LF\" for Length Field | \"AF\" for Area Field ::"
)
)
(princ)
;;----------------------------------------------------------------------;;
;; End of File ;;
;;----------------------------------------------------------------------;;
AEC Collection 2022
WIN 10 PRO
Dell 3650, Intel i9-11900k @ 3.50GHz, 64 GB
NVIDIA QUADRO RTX 4000
http://www.cobbfendley.com
WIN 10 PRO
Dell 3650, Intel i9-11900k @ 3.50GHz, 64 GB
NVIDIA QUADRO RTX 4000
http://www.cobbfendley.com
Message 5 of 6
- Mark as New
- Bookmark
- Subscribe
- Mute
- Subscribe to RSS Feed
- Permalink
- Report
Accepted solution
In original code of LeeMac you can modify this:
line 5:
(defun c:lf ( ) (lengthfield nil t "%lu6")) ;; Current units, subtraction promptto
(defun c:lf ( ) (lengthfield nil nil "%lu6")) ;; Current units, subtraction prompt
and for area idem at line 12 : t->nil for elimate the subtraction because you want use (ssget "_X")
At line 134 to 149 replace by this
(setq ftr
(list "_X"
(list
'(000 . "ARC,LINE,*POLYLINE") '(08 . "DNP")
'(-04 . "<NOT")
'(-04 . "<AND")
'(000 . "POLYLINE") '(-04 . "&") '(070 . 80)
'(-04 . "AND>")
'(-04 . "NOT>")
(if (= 1 (getvar 'cvport))
(cons 410 (getvar 'ctab))
'(410 . "Model")
)
)
)
)You can remove the prompt at line 151:
(if (setq ss1 (LM:ssget "" ftr))For area make the same change line 188 at 203 and at line 205 for the prompt.
And normally should work as you desire...
Message 6 of 6
- Mark as New
- Bookmark
- Subscribe
- Mute
- Subscribe to RSS Feed
- Permalink
- Report
That worked! I was able to also edit for linetype selection also.
Thanks, I appreciate your time and help.
AEC Collection 2022
WIN 10 PRO
Dell 3650, Intel i9-11900k @ 3.50GHz, 64 GB
NVIDIA QUADRO RTX 4000
http://www.cobbfendley.com
WIN 10 PRO
Dell 3650, Intel i9-11900k @ 3.50GHz, 64 GB
NVIDIA QUADRO RTX 4000
http://www.cobbfendley.com
