Object selection with color

[Philip-John]

I found a lisp by Lee Mac (see below link) to select objects by color and it's fine.

object select by color

Can anybody modify the same lisp to select objects within a selection only, and not the entire drawing?

[dlanorh]

Find this section in the lisp and insert the blue text. This will comment out the red text allowing it to be "re-instated" should that be required later. If you want to make it permanent just remove "_X"

           (sssetfirst nil
               (ssget ;(ssget "_X"
                   (if l
                       (list

[Philip-John]

Thanks a lot dlanorh,

Your solution is working. But it is not working if there no selection. Can you make it select objects in entire drawing if there is no selection.

Thanks & regards

Philip John

[dbhunia]

Try this ......

(defun c:SelectByColour ( / c d e l )
(princ "\nSelect objects from which you want to filter your objects....")
(ssget)
   (if (setq e (car (entsel "\nSelect the Colour to Filter...")))
       (progn
           (setq c
               (cond
                   (   (cdr (assoc 62 (entget e)))   )
                   (   (abs (cdr (assoc 62 (tblsearch "LAYER" (cdr (assoc 8 (entget e)))))))   )
               )
           )                     
           (while (setq d (tblnext "LAYER" (null d)))
               (if (= c (abs (cdr (assoc 62 d))))
                   (setq l (cons "," (cons (cdr (assoc 2 d)) l)))
               )
           )
           (sssetfirst nil
               (ssget "_p"
                   (if l
                       (list
                           (cons -4 "<OR")
                               (cons 62 c)
                               (cons -4 "<AND")
                                   (cons 62 256)
                                   (cons 8 (apply 'strcat (cdr l)))
                               (cons -4 "AND>")
                           (cons -4 "OR>")
                       )
                       (list (cons 62 c))
                   )
               )
           )
       )
   )
   (princ)
)

[Philip-John]

Thank you dbhunia and dlanorh for your support,

Working as I requested