Need Help: Please modify the code to change lineweight for non Xref layers only

[le-tan-phuc]

I got this lisp from the internet but it change all layers included Xref layers
Someone can help me to exclude Xref layers please. Sorry for my bad English.
;;Change All layer in Default lineweight to 0.05 lineweight
(defun c:C005 ()
((lambda (/ n l w)
(while (setq n (cdr (assoc 2 (tblnext "LAYER" (not n)))))
(setq w (cdr (assoc 370 (setq l (entget (tblobjname "LAYER" n))))))
(if (= w -3)
(entmod (subst '(370 . 5) (cons 370 w) l))))))
(princ)
)

[komondormrex · Accepted solution]

(defun c:C005 ()
	(
		(lambda (/ n l w)
			(while (setq n (cdr (assoc 2 (tblnext "LAYER" (not n)))))
				(if (not (wcmatch n "*|*"))
					(progn
						(setq w (cdr (assoc 370 (setq l (entget (tblobjname "LAYER" n))))))
						(if (= w -3)
						(entmod (subst '(370 . 5) (cons 370 w) l)))
					)
				)
			)
		)
	)
	(princ)
)

[le-tan-phuc]

it works perfectly
Thank you so much Komondormrex !

[Kent1Cooper · Accepted solution]

Another way, using a different determination of whether a Layer is Xref-dependent [the DXF 70 value containing the 16 bit, rather than the | in the Layer name]:

(defun C:C005 (/ lname ldata); All non-Xref Layers of default LW to 0.05 LW
  (while (setq lname (cdr (assoc 2 (tblnext "LAYER" (not lname)))))
    (setq ldata (entget (tblobjname "LAYER" lname)))
    (if (and (member '(370 . -3) ldata) (= (logand (cdr (assoc 70 ldata)) 16) 0))
      (entmod (subst '(370 . 5) (assoc 370 ldata) ldata))
    ); if
  ); while
  (prin1)
)

[le-tan-phuc]

this code work great also
Thank you for sharing this knowledge Mr Kent1Cooper.