Mtext replace color
As a start, look at StackStyleForce.lsp here. It locates the code elements within Mtext that define stacked fractions, but if you look in Mtext content at the code for assigning internal override colors, it's very similar -- an alteration of that approach could probably be made to do what you want. Are you capable of adjusting something like that?
@msarqui wrote:
I am sorry Kent, but I have no clue how to edit this level of lisp. My knowledge is very basic 😞
msarqui,
a quick and dirty 'demo'
(vl-load-com)
(defun c:demo (/ obj ss str)
(if (setq ss (ssget "_+.:E:S:L" '((0 . "MTEXT"))))
(progn
(setq obj (vlax-ename->vla-object (ssname ss 0))
str (vla-get-textstring obj)
)
(while (wcmatch str "*\\C1;*")
(setq str (vl-string-subst "\\C216;" "\\C1;" str))
)
(vla-put-textstring obj str)
)
)
(princ)
)
EDIT: If you don't understand something, just ask...
Hope this helps,
Henrique
@msarqui wrote:
Henrique, I changed C1 (Red) for C2 (Yellow). Because I don't have Red in my exemple, but my AutoCAD stops.
Hi msarqui,
my demo was write just to show a way to change the color within a MTEXT entity....
To change the color 2, perhaps something like this:
(tested with your dwg, without any problems)
(vl-load-com)
(defun c:demo (/ obj ss str)
(if (setq ss (ssget "_+.:E:S:L" '((0 . "MTEXT"))))
(progn
(setq obj (vlax-ename->vla-object (ssname ss 0))
str (vla-get-textstring obj)
)
(while (wcmatch str "*\\C2;*")
(setq str (vl-string-subst "\\C216;" "\\C2;" str))
)
(vla-put-textstring obj str)
)
)
(princ)
)
Hope this helps,
Henrique
@Anonymous wrote:
....
(while (vl-string-search (strcat "\\C" (itoa oldColor)) txt)
(setq txt (vl-string-subst (strcat "\\C" (itoa newColor)) (strcat "\\C" (itoa oldColor)) txt))
....
One thing that needs to be adjusted about that:
If you ask for it to change, for example, color 1 to color 25, the red parts above will also change color 11 to color 251, and color 125 to color 2525 [which surprisingly doesn't result in an error, but just voids the color assignment]. If you ask it to change color 1 to color 11, it will get stuck in an endless loop, trying to change 1 to 11 and then 11 to 111 and then 111 to 1111, and so on.
Color assignment codes have a semicolon after the color number, so the lines above can be changed to include that, and look at only completed color numbers:
....
(while (vl-string-search (strcat "\\C" (itoa oldColor) ";") txt)
(setq txt (vl-string-subst (strcat "\\C" (itoa newColor) ";") (strcat "\\C" (itoa oldColor) ";") txt))
....
@msarqui wrote:
Henrique : You're right, your routine works, it is really fast and I don't have the weird behavior. Could you modify a little to ask the user to enter the old color number and after ask the new color number? Like Gilsonrss's routine do? If it's not too hard.
Hi msarqui,
I didn'd see your reply, sorry.
Like Gilson's routine... (sorry for borrowing your code Gilson)
(vl-load-com)
(defun c:demo (/ new obj old ss str)
(if (and (setq old (getint "\nEnter the old color number:"))
(<= 0 old 256)
(setq new (getint "\nEnter the new color number:"))
(<= 0 new 256)
(princ "\nSelect Mtext object to change color: ")
(setq ss (ssget "_:L" '((0 . "MTEXT"))))
)
(repeat (setq i (sslength ss))
(setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
str (vla-get-textstring obj)
)
(while (vl-string-search (strcat "\\C" (itoa old) ";") str)
(setq str (vl-string-subst
(strcat "\\C" (itoa new) ";")
(strcat "\\C" (itoa old) ";")
str
)
)
)
(vla-put-textstring obj str)
)
)
(princ)
)
Hope this helps,
Henrique
@msarqui wrote:
Gilson's routine have yet some text that insists on not to change.
@Anonymous
Gilson's routine, using AUTO LISP, is limited to 250 characters, if a string have more then 250 characters, the string will be divided in multi strings, associated to dxf 3 with 250 characters, and the last string to dxf 1.
Using the AUTO LISP approach, we'll have to test the dxf 3 existence, strcat the sub-strings in one, change the color, divide the string in sub-strings with 250 characters, subst each dxf 3 and the dxf1, entmode.... many lines of code...
That's why I chose to use the VL approach.
@msarqui wrote:
Henrique's routine do the change everywhere.
Thanks for your help, it saved-me hundreds hours of work.
You're welcome, msarqui
Glad I could help
Henrique
Hi Marcelo,
do you need to change Text/Mtext inside the blocks, or Attribut Text/MText color?
Dealing with attributes, we can change each "INSERT" Attribute Text/MText independently, but you'll have to take into account, ATTSYNC will synchronize the Text/Mtext Attributes with the table defined Attribute...
As you have said, you need to go to block editor to change the Text/MText... do you have multiple blocks with the same attribute string?
Cheers
Henrique
Marcelo,
let's see if I did understood your goal...
(vl-load-com)
(defun c:ChangeTextColor (/ ch_str_color attlst new i obj objn old ss)
(defun ch_str_color (str old new /)
(while (vl-string-search (strcat "\\C" (itoa old) ";") str)
(setq str (vl-string-subst
(strcat "\\C" (itoa new) ";")
(strcat "\\C" (itoa old) ";")
str
);vl
);setq str
);while
str
);;ch_str_color
(if (and (princ "\n Select Text, Mtext or Attribute object to change its color: ")
(setq ss (ssget "_:L"
'((-4 . "<OR")
(0 . "MTEXT,TEXT")
(-4 . "<AND")
(0 . "INSERT")
(66 . 1)
(-4 . "AND>")
(-4 . "OR>")
)
)
)
(setq old (getint "\n Enter the old color number: "))
(<= 0 old 256)
(setq new (getint "\n Enter the new color number: "))
(<= 0 new 256)
);and
(repeat (setq i (sslength ss))
(setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
objn (vla-get-objectname obj)
);setq
(cond ((= objn "AcDbMText")
(vla-put-textstring obj (ch_str_color (vla-get-textstring obj) old new))
)
((and (= objn "AcDbText")
(= (vla-get-color obj) old)
)
(vla-put-color obj new)
)
((= objn "AcDbBlockReference")
(setq attlst (vlax-invoke obj 'GetAttributes))
(foreach att attlst
(if (= (vla-get-mtextattribute att) :vlax-false)
(if (= (vla-get-color att) old)
(vla-put-color att new)
)
(vla-put-textstring att (ch_str_color (vla-get-textstring att) old new))
)
)
)
);; cond
);repeat
);if and
(princ)
)
Hope this helps,
Henrique
