Mtext Formatting In A Field

Anonymous · ‎10-13-2015

Hello!

I am hoping someone here can help with this problem. I am trying to have some text that is stored in a variable output in a field that should be a different color from rest of the text. I have looked high and low in multilple forums but have not found the exact the solution I need. I have stubled upon the Mtext formatting codes, I have seen a few examples, but when I try to replicate it does not work for me. I don't understand how they are to be used in a LISP routine. I know how to change the color of the text the usual way, I would think there is a way to code it. Below is a screen capture of what I am hoping to accomplish, currently all the text is blue:

This is the line of code that produces the top two lines:

(setq dwg (strcat "DWG. PER CUST E-MAIL:" (chr 10) (vl-filename-base (getvar "dwgname")) ".dxf" (chr 10) "DWG#: " dwg2))

I hope I have explained this well enough to be understood.

Thank you in advance for your time and attention!

Joe

rkmcswain · ‎10-13-2015

Are you asking how to set the colors of the partial strings inside the mtext block?

If so....

(vl-cmdf ".mtext" (getpoint "\nPick Point") "_W" 0.0
	 (strcat "\\C6;DWG. PER CUST E-MAIL:\\P80721354_-.DXF\\P\\C5;REV: NONE\\P1 1/2"
		 (CHR 34)
		 " 50 HSLA\\P19"
		 (CHR 34)
		 " B.EA\\P12.028# EA.\\PJK\\P9/25/15")
	 "")

R.K. McSwain ● ● ● ● | CADpanacea | on twitter

hmsilva · ‎10-13-2015

@Anonymous wrote:

Hello!

I am hoping someone here can help with this problem. I am trying to have some text that is stored in a variable output in a field that should be a different color from rest of the text. I have looked high and low in multilple forums but have not found the exact the solution I need. I have stubled upon the Mtext formatting codes, I have seen a few examples, but when I try to replicate it does not work for me. I don't understand how they are to be used in a LISP routine. I know how to change the color of the text the usual way, I would think there is a way to code it. Below is a screen capture of what I am hoping to accomplish, currently all the text is blue:

This is the line of code that produces the top two lines:
(setq dwg (strcat "DWG. PER CUST E-MAIL:" (chr 10) (vl-filename-base (getvar "dwgname")) ".dxf" (chr 10) "DWG#: " dwg2))
I hope I have explained this well enough to be understood.

Thank you in advance for your time and attention!

Joe

Hi Joe,

in addition to RK advices, and if the 'blue' is bylayer, you'll only have to override the color for color 6...

ex.

(setq dwg (strcat "{\\C6;DWG. PER CUST E-MAIL:" "\\P" (vl-filename-base (getvar "dwgname")) ".dxf}" (chr 10) dwg2 ))

sorry but I did remove the "DWG#: "....

Hope this helps,
Henrique

Anonymous · ‎10-14-2015

Thank you for responding rk! No, I am just needing the top two lines changed. I should've included the whole routine so that you could see what is generating the text.

Thanks again!

Anonymous · ‎10-14-2015

Thank you hm! Yes, the blue is setup as bylayer.

I will give these ideas a try and let you and rk know if it worked or not.

Thank you both, again!

Anonymous · ‎10-14-2015

hmsilva,

Sorry to say the code didn't work. Below is a screenshot of the output:

Here is the code:

(setq dwg (strcat "{\\C6;DWG. PER CUST E-MAIL:" "\\P" (vl-filename-base (getvar "dwgname")) ".dxf}" "\\P" "DWG#: " dwg2))

It seems the mtext formatting code is being ignored. Thank you for trying. Do you have any ideas as to why the mtext formatting is being ignored?

Joe

Anonymous · ‎10-14-2015

rkmcswain,

Your code worked when I tried it as it's own program. When I tried to incorporate it into my code, it worked the same as Henrique's. I will attach the entire routine I am using. There are only 4 other lines that would need to have the mtext formatting. I am certain as you read it, there will be some wincing. It doesn't look very good, but it does give me the result's I need.

Thank you again!

Joe

hmsilva · ‎10-15-2015

@Anonymous wrote:

hmsilva,

Sorry to say the code didn't work. Below is a screenshot of the output:

...

It seems the mtext formatting code is being ignored. Thank you for trying. Do you have any ideas as to why the mtext formatting is being ignored?

Hi Joe,

unfortunately, it seems that 'fields' evaluates the text string as a 'text' string and ignores the 'mtext' formatting codes...

Internal MText editor, also ignores the 'mtext' formatting codes, if we enter formatting codes the editor evalutes as text characters, not formatting codes, if we define an external text editor, ie. notepad, the the formatting codes are evaluated as formatting codes in MText, but not in fields...

Sorry, but I can´t find a way to format text inside a field... 😞

Henrique

Anonymous · ‎10-15-2015

Thank you Henrique! I appreciate your assistance so far.

I was thinking along the same lines at the end of the day yesterday. As I was doing some searching yesterday, I found a few ideas that have to do with converting the fields to text. It seems to me after that it would be possible to apply the mtext formatting...Would you have any ideas is this direction?

hmsilva · ‎10-15-2015

@Anonymous wrote:
Thank you Henrique! I appreciate your assistance so far.

I was thinking along the same lines at the end of the day yesterday. As I was doing some searching yesterday, I found a few ideas that have to do with converting the fields to text. It seems to me after that it would be possible to apply the mtext formatting...Would you have any ideas is this direction?

Hi Joe,

this thread may be useful...

Hope this helps,
Henrique

Anonymous · ‎10-15-2015

Hi Henrique,

Thank you for the link! I think I am seeing a connection between what I am trying to do and the code in the thread. I believe it will be useful, as soon as I can try something out. I'll let you what I come up with.

Thanks again!

Joe

Anonymous · ‎10-15-2015

Henrique,

I tried the code from the link and it does work, but, it converts all the fields. I only need it to convert 1 field. I don't know if it makes a difference, the fields I have are all custom defined fields.

Thank you again!

Joe

hmsilva · ‎10-15-2015

@Anonymous wrote:
Henrique,

I tried the code from the link and it does work, but, it converts all the fields. I only need it to convert 1 field. I don't know if it makes a difference, the fields I have are all custom defined fields.

Thank you again!

Joe

Joe,

to convert only the field we need to convert, we have fo provide to the 'ssfield' function, a test sting not present in other fields, the more complete, better.

If the field you need to convert it's the only field using the dwg variable,

(ssfield "Lisp.dwg>%")

should do the trick...

Hope this helps,
Henrique

Anonymous · ‎10-16-2015

Henrique,

I tried it as you had it and several other ways and none of the fields were converted. Maybe it would help if you could see what the other fieldcodes actually are. I am attaching a drawing to see if that might help so that you can see in context the other fields.

Thanks again, alot!

Joe

hmsilva · ‎10-16-2015

Joe,

the following quick and dirty 'demo' will search for an MText entity, with a field, having "CustomDP.DwgNum" in the 'FIELDCODE', will remove the fields, search for "REV:", and format the Mtext string with color 6 all characters until "REV:"...

(defun c:demo (/ ssfield hnd i obj pre pos suf ss str)
   ;; http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/convert-field-to-text/td-p/1722015/page/2
   ;; by Ian_Bryant
   (defun del-field (ent / edic elist etype obj val)
      (if
         (and
            (setq edic (cdr (assoc 360 (setq elist (entget ent)))))
            (dictsearch edic "ACAD_FIELD")
         )
           (progn
              (setq obj   (vlax-ename->vla-object ent)
                    etype (cdr (assoc 0 elist))
              )
              (cond
                 ((= etype "MTEXT")
                  (setq val (vla-get-textstring obj))
                  (dictremove edic "ACAD_FIELD")
                  (vla-put-textstring obj val)
                 )
                 (T (dictremove edic "ACAD_FIELD"))
              )
           )
      )
   )
   ;; by me
   (defun ssfield (str / hnd i obj ss ss1)
      (if (setq ss (ssget "_X" '((0 . "MTEXT"))))
         (progn
            (setq ss1 (ssadd))
            (repeat (setq i (sslength ss))
               (setq hnd (ssname ss (setq i (1- i)))
                     obj (vlax-ename->vla-object hnd)
               )
               (if (and (vlax-method-applicable-p obj 'FIELDCODE)
                        (wcmatch (vlax-invoke-method obj 'FIELDCODE) (strcat "*" str "*"))
                   )
                  (ssadd hnd ss1)
               )
            )
            ss1
         )
      )
   )
   (if (setq ss (ssfield "CustomDP.DwgNum"))
      (repeat (setq i (sslength ss))
         (setq hnd (ssname ss (setq i (1- i)))
               obj (vlax-ename->vla-object hnd)
         )
         (if (vlax-write-enabled-p obj)
            (progn
               (del-field hnd)
               (setq str (vla-get-textstring obj))
               (if (and (setq pos (vl-string-search "REV:" str))
                        (setq pre (substr str 1 pos))
                        (setq suf (substr str (1+ pos)))
                   )
                  (vla-put-textstring obj (strcat "{\\C6;" pre "}" suf))
               )
            )
         )
      )
   )
   (vla-regen (vla-get-activedocument (vlax-get-acad-object)) acallviewports)
   (princ)
)

Hope this helps,
Henrique

Anonymous · ‎10-19-2015

Henrique,

This now works as expected!

Thank you so much!

Joe

hmsilva · ‎10-19-2015

@Anonymous wrote:
Henrique,

This now works as expected!

Thank you so much!

Joe

You're welcome, Joe
Glad I could help

Henrique

Community

Mtext Formatting In A Field

Mtext Formatting In A Field

Mtext Formatting In A Field