Mtext break
There are routines you can Search for on these Forums for subdividing text strings around whatever delimiting character you want, in this case presumably a space. So dividing the string content is achievable. Is your intent to keep the resulting second-half piece visually in the same place? That could be the more challenging part, and may not be doable with great precision, but could probably be done fairly close.
@kzD1219 wrote:
.... I was searching, but nothing caught my eye, just yet, but I will look some more.
Here's a beginning of a routine, for your consideration:
(defun C:SM2 ; = Split Mtext into 2 pieces [around double space delimiter]
(/ ss n mt mto1 txtinit mto2)
(if (setq ss (ssget ":L" '((0 . "MTEXT"))))
(repeat (setq n (sslength ss))
(setq
mt (ssname ss (setq n (1- n)))
mto1 (vlax-ename->vla-object mt)
txtinit (vla-get-TextString mto1)
dsp (vl-string-search " " txtinit); double space position
); setq
(command "_.copy" mt "" '(0 0) "")
(setq mto2 (vlax-ename->vla-object (entlast)))
(vla-put-TextString mto1 (substr txtinit 1 dsp)); string before double space
(vla-put-TextString mto2 (substr txtinit (+ dsp 3))); string after double space
(vla-put-AttachmentPoint mto2 3); top-right justification
); repeat
); if
(princ)
); defun
BUT note certain assumptions, limitations, etc.:
It assumes the original is top-left justified in typical default fashion for Mtext, so if that might not always be the case, something would have to be done to accommodate different possibilities.
Given that justification, it copies it in place, then assigns top-right justification to the copy that gets the second-half text content. That uses the right end of the "defined width" of the Mtext "box," which may be wider [maybe a lot wider] than the actual content. If so, the second-half piece will move more significantly. If that's a meaningful issue, there are routines around that you can apply to pull the "defined width" of Mtext in to just the size of the actual content.
Speaking of defined width of the box, it assumes the initial content doesn't exceed that, i.e. there is no word wrapping based on that. It "works" if there is, but the positioning can result in overlap of the two resulting pieces.
It assumes that there is, in fact, a double space somwhere in the text content, but could be made to check for that first.
And it doesn't have all the usual bells and whistles yet....
I'm playing with some possibilities to overcome some of those things, and may be back with improvements, but see what you think so far.
@kzD1219 wrote:
.... The justification we most use is top, middle and bottom centre. ....
Given that, try this adjustment, which relies on the original being one of those three justifications. I found some good pieces of data to work with to eliminate [or at least minimize] the re-positioning, ignoring the "defined width" of the original's "box."
It results [in minimal testing] in quite-accurately-same-location pieces, and it respects the top/middle/bottom element of the originals' justifications. But it leaves the left-end one from each justified to the left [Bottom Left if the original was Bottom Center, etc.] and the right one justified to the right. With a little more work it could change the justifications to what the original was, and reposition so they don't appear to have moved [much], with some more extraction of character-set widths and calculation of new insertion points after it's done this much. But see what you think of this, so far:
(defun C:SM2 ; = Split Mtext into 2 pieces
(/ ss n mt mto1 txtinit inspt rot wid dsp mto2)
(if (setq ss (ssget ":L" '((0 . "MTEXT"))))
(repeat (setq n (sslength ss))
(setq
mt (ssname ss (setq n (1- n))); entity name [for Copy below]
mto1 (vlax-ename->vla-object mt); as VLA object
txtinit (vla-get-TextString mto1)
inspt (vlax-get mto1 'InsertionPoint)
rot (vla-get-rotation mto1)
wid (cdr (assoc 42 (entget mt))); [not available as VLA property]
dsp (vl-string-search " " txtinit); double space position
); setq
(command "_.copy" mt "" '(0 0) "")
(setq mto2 (vlax-ename->vla-object (entlast)))
(vla-put-AttachmentPoint mto1 (1- (vla-get-AttachmentPoint mto1))); left-end justification
(vla-put-AttachmentPoint mto2 (1+ (vla-get-AttachmentPoint mto2))); right-end justification
(vla-put-TextString mto1 (substr txtinit 1 dsp)); string before double space
(vla-put-TextString mto2 (substr txtinit (+ dsp 3))); string after double space
(vlax-put mto1 'insertionpoint (polar inspt (+ rot pi) (/ wid 2)))
(vlax-put mto2 'insertionpoint (polar inspt rot (/ wid 2)))
); repeat
); if
(princ)
); defun
(vl-load-com); just in case
@kzD1219 wrote:
.... removing any spaces that show up before the second piece of mtext. ....
Does that imply that sometimes the separation is more than two spaces? The routines assume only two, but if it could be more, it wouldn't be hard to eliminate extras.
@Kent1Cooper wrote:
.... With a little more work it could change the justifications to what the original was, and reposition so they don't appear to have moved [much], with some more extraction of character-set widths and calculation of new insertion points after it's done this much. ....
Like this [it doesn't, in the end change the justification and then change it back, but leaves it alone and calculates a new insertion point]:
(defun C:SM2 ; = Split Mtext into 2 pieces ;; starting from top-/middle-/bottom-CENTER justifications, ;; split around two-spaces separators (/ ss n mt mto1 txtinit inspt rot wid dsp mto2 wid1 wid2) (if (setq ss (ssget ":L" '((0 . "MTEXT")))) (repeat (setq n (sslength ss)) (setq mt (ssname ss (setq n (1- n))); entity name [for Copy below] mto1 (vlax-ename->vla-object mt); as VLA object txtinit (vla-get-TextString mto1) inspt (vlax-get mto1 'InsertionPoint) rot (vla-get-rotation mto1) wid (cdr (assoc 42 (entget mt))); [not available as VLA property] dsp (vl-string-search " " txtinit); double space position ); setq (command "_.copy" mt "" '(0 0) "") (setq mto2 (vlax-ename->vla-object (entlast))) (vla-put-TextString mto1 (substr txtinit 1 dsp)); string before double space (vla-put-TextString mto2 (substr txtinit (+ dsp 3))); string after double space (redraw mt); needed to get reduced widths correctly [otherwise uses original] (redraw (entlast)); likewise (setq wid1 (cdr (assoc 42 (entget mt))); reduced width of original wid2 (cdr (assoc 42 (entget (entlast)))); width of after-spaces piece ); setq (vlax-put mto1 'insertionpoint (polar inspt (+ rot pi) (/ (- wid wid1) 2))) (vlax-put mto2 'insertionpoint (polar inspt rot (/ (- wid wid2) 2))) ); repeat ); if (princ) ); defun
Could still use the other typical stuff [*error* handling, command-echo suppression, Undo begin/end, etc.].
