MLEADER DXF Help
Hi Robert,
The code below will determine the 2 points you're looking for which I've called LeaderLanding:P1 and LeaderLanding:P2.
The angle of the leader landing line (dogleg) is stored as a unit vector; DXF code 11 in the Leader section of the MLeader DXF code list.
As examples, I've included 2 methods for calculating the angle of the leader landing line:
(atan (cadr Leader_11) (car Leader_11)) is ok in a 2D plane (in radians).
(leemac:acos (leemac:vxv Leader_11 '(1.0 0.0 0.0)) will calculate the angle (in radians) if the leader was created in 3D.
The method I used to calculate LeaderLanding:P2 does not require an angle; the method uses the leader landing line unit vector and length and some Lee Mac magic 
I've also set ssget to a forced single object selection (:S+.) on unlocked layers only (:L).
I hope this helps.
Regards,
Trevor
;; MLeaderPoints.lsp by Trevor Bird
;;
;; 2018-01-24
;;------------------------------------------------------------------------------
(defun c:mleaderpoints
(
/
->rtd
col_ActiveBlock
LeaderLanding:Angle
LeaderLanding:P1
LeaderLanding:P2
LeaderLanding:vxv
Leader_10
Leader_11
Leader_40
Leader_DXF
MULTILEADER_DXF
MULTILEADER_ename
obj_AD
obj_circle:P1
obj_circle:P2
ssC
ss_Filter
ss_MULTILEADER
sv_cvport
)
(defun ->rtd (x) (* (/ x pi) 180.0))
(setq obj_AD (vlax-get-property (vlax-get-acad-object) 'ActiveDocument)
sv_cvport (getvar 'CVPORT)
);setq
(if (= sv_cvport 1)
(setq col_ActiveBlock (vlax-get-property obj_AD 'PaperSpace))
(setq col_ActiveBlock (vlax-get-property obj_AD 'ModelSpace))
);if (= sv_cvport 1)
(setq ss_Filter '((0 . "MULTILEADER")))
(if (= sv_cvport 1)
(setq ss_Filter (append ss_Filter (list (cons 410 (getvar 'CTAB)))))
(setq ss_Filter (append ss_Filter '((410 . "Model"))))
);if (= sv_cvport 1)
(setq ss_MULTILEADER (ssget ":S+.:L" ss_Filter))
; (setq ss_MULTILEADER (ssget ":L" ss_Filter))
(cond
( (not ss_MULTILEADER)
(princ "\nNo MLeaders selected.")
);(not ss_MULTILEADER)
(ss_MULTILEADER
(setq ssC -1)
(repeat (sslength ss_MULTILEADER)
(setq MULTILEADER_ename (ssname ss_MULTILEADER (setq ssC (1+ ssC)))
MULTILEADER_DXF (entget MULTILEADER_ename)
Leader_DXF (cdr (member '(302 . "LEADER{") MULTILEADER_DXF))
Leader_10 (cdr (assoc 10 Leader_DXF)) ; Last Leader Line Point
Leader_11 (cdr (assoc 11 Leader_DXF)) ; Dogleg Vector
Leader_40 (cdr (assoc 40 Leader_DXF)) ; Dogleg Length
LeaderLanding:Angle (atan (cadr Leader_11) (car Leader_11))
LeaderLanding:vxv (leemac:vxv Leader_11 '(1.0 0.0 0.0))
; LeaderLanding:Angle (leemac:acos LeaderLanding:vxv)
LeaderLanding:P1 Leader_10
LeaderLanding:P2 (mapcar '+ LeaderLanding:P1 (leemac:vxs Leader_11 Leader_40))
);setq
(princ "\nLeader_11 \t") (prin1 Leader_11) (princ "\t\tDogleg Vector")
(princ "\nLeader_40 \t") (prin1 Leader_40) (princ "\t\tDogleg Length")
(princ "\nLeaderLanding:Angle\t") (prin1 (->rtd LeaderLanding:Angle))
(princ "\nLeaderLanding:vxv \t") (prin1 (->rtd (leemac:acos LeaderLanding:vxv)))
(setq obj_circle:P1 (vlax-invoke-method col_ActiveBlock 'AddCircle (vlax-3D-point LeaderLanding:P1) (/ Leader_40 10.0))
obj_circle:P2 (vlax-invoke-method col_ActiveBlock 'AddCircle (vlax-3D-point LeaderLanding:P2) (/ Leader_40 10.0))
);setq
(vlax-put-property obj_circle:P1 'Color acRed)
(vlax-put-property obj_circle:P2 'Color acYellow)
(vlax-release-object obj_circle:P1)
(vlax-release-object obj_circle:P2)
);repeat (sslength ss_MULTILEADER)
);ss_MULTILEADER
);cond
(vlax-release-object col_ActiveBlock)
(vlax-release-object obj_AD)
(princ)
);c:mleaderpoints
;;------------------------------------------------------------------------------
;; Vector x Scalar - Lee Mac
;; Args: v - vector in R^n, s - real scalar
(defun leemac:vxs ( v s )
(mapcar '(lambda ( n ) (* n s)) v)
)
;; Vector Dot Product - Lee Mac
;; Args: u,v - vectors in R^n
(defun leemac:vxv ( u v )
(apply '+ (mapcar '* u v))
)
;; ArcCosine - Lee Mac
;; Args: -1 <= x <= 1
(defun leemac:acos ( x )
(if (<= -1.0 x 1.0)
(atan (sqrt (- 1.0 (* x x))) x)
)
)
;;------------------------------------------------------------------------------
(princ "\nMLeaderPoints loaded. Start command with MLEADERPOINTS.")
(princ)
