Match direction of all polylines
Accepted solution
If it's a matter of inward vs. outward, on things with area [not, for example, a single-line-segment Polyline], you could use OffsetInOrOut.lsp, with its OffIn and OffOut commands, >here<. It doesn't reverse things, but tries Offsetting in one direction on each selected object, and if the result is to the wrong side [e.g. if it's bigger than the original if you wanted to Offset inward], eliminates that and goes the other way. See comments in that thread and in the file. [Message 28 on the same thread has a version that puts the results on the Current Layer.]
If that doesn't suit you, and you do need to reverse the direction of some objects, there are lots of threads here involving the question of whether something runs clockwise or counterclockwise -- do some Searching, and very likely you'll find something you can use.
Kent Cooper, AIA 
Here you have a quick solution that converts all lwpolylines to counterclockwise direction. If you find this applicable select this as a solution.
(defun revlwpline (e / footer done vertices header flag)
;reverse lightweight polyline
;http://www.metzgerwillard.us/tdavis/lisp/reverse.html
(foreach item (reverse (entget e))
(cond
((not done)
(cond
((= (car item) 40)
(setq footer (cons (cons 41 (cdr item)) footer) ;swap width
done t
)
)
((= (car item) 41)
(setq footer (cons (cons 40 (cdr item)) footer)) ;swap width
)
((= (car item) 42)
(setq footer (cons (cons 42 (- (cdr item))) footer)) ;negate bulge
)
((= (car item) 210)
(setq footer (cons item footer))
)
)
)
((= (car item) 10)
(setq vertices (cons item vertices))
)
((= (car item) 40)
(setq vertices (cons (cons 41 (cdr item)) vertices)) ;swap width
)
((= (car item) 41)
(setq vertices (cons (cons 40 (cdr item)) vertices)) ;swap width
)
((= (car item) 42)
(setq vertices (cons (cons 42 (- (cdr item))) vertices)) ;negate bulge
)
(t (setq header (cons item header)))
)
)
(setq flag (assoc 70 header))
(if (< (cdr flag) 128) ;turn on linetype generation
(setq header (subst (cons 70 (+ (cdr flag) 128)) flag header))
)
(entmod (append header (reverse vertices) footer))
(princ)
)
(defun to_counter_clockwise ( e / LW LST MAXP MINP)
; Writer Evgeniy Elpanov.
; modified by hak_vz
(setq lw (vlax-ename->vla-object e))
(vla-GetBoundingBox lw 'MinP 'MaxP)
(setq
minp (vlax-safearray->list minp)
MaxP (vlax-safearray->list MaxP)
lst
(mapcar
(function
(lambda (x)
(vlax-curve-getParamAtPoint
lw
(vlax-curve-getClosestPointTo lw x)
) ;_ vlax-curve-getParamAtPoint
) ;_ lambda
) ;_ function
(list minp
(list (car minp) (cadr MaxP))
MaxP
(list (car MaxP) (cadr minp))
) ;_ list
) ;_ mapcar
) ;_ setq
(if
(or
(<= (car lst) (cadr lst) (caddr lst) (cadddr lst))
(<= (cadr lst) (caddr lst) (cadddr lst) (car lst))
(<= (caddr lst) (cadddr lst) (car lst) (cadr lst))
(<= (cadddr lst) (car lst) (cadr lst) (caddr lst))
) ;_ or
(revlwpline e)
) ;_ if
) ;_ defun
(defun c:all_lwpolcw ( / ss i )
(setq ss (ssget "X" '((0 . "lwpolyline"))) i 0)
(while (< i (sslength ss))
(to_counter_clockwise (ssname ss i))
(setq i (+ i 1))
)
(princ)
)
(princ "\nCommand all_lwpolcw converts all lwpolylines to counterclockwise direction")
(princ)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@hak_vz wrote:
Here you have a quick solution that converts all lwpolylines to counterclockwise direction. ....
It seems to me that it should not be necessary to have that revlwpline routine now that the REVERSE command exists [the routine was likely written before it did]. It should only be necessary to determine the drawn direction of a Polyline, and if it's not drawn in the desired direction, apply REVERSE to it.
Kent Cooper, AIA
I agree, it can be changed with command REVERSE.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@Sea-Haven wrote:
.... check area of pline if -ve then you would use the reverse command, very simple.
... and, unfortunately, very wrong if the Polyline in question contains any arc segment(s). Not only can it be wrong about the area, but also about the sign of the area, i.e. the drawn direction. Here are two Polylines of exactly the same shape, both drawn in the clockwise direction starting at point A. The red one on the left has a single arc segment from A around to B; the green one on the right does that curve with two arc segments from A to C, with B as a vertex midway.
The "areas" reported by (ss-pts2area co-ord) are indicated below. They are actually the areas of the line-segment-only shapes shown in dashed white with hatching inside. Notice not only that they differ from the real area of the Polylines [both 2.202322] and from each other, but also that one is positive and one negative, though the Polylines were drawn in the same direction. That's because on the left, it looks from A to B directly, without accounting for the Polyline's actual route swinging around the far side. So something that decides whether to REVERSE a Polyline based on that routine's result would do it to one of these but not the other, and (vla-offset) with the same sign on its offset distance would go the wrong way from one of them.
The OffIn and OffOut commands work correctly with situations like these, because their area comparison accounts for arc segments. They also work with open Polylines, as well as with other kinds of objects with area [Arc, Circle, Ellipse, Spline].
Kent Cooper, AIA
@Sea-Haven wrote:
.... Like everything need some time to have a go.
I wouldn't bother -- spend the time Searching this Forum, where this has come up many times before, and you'll find a whole variety of approaches to the problem.
Kent Cooper, AIA
