many indvidual txts to one line text within area or distance

[the_ameral]

i want to combine or join many txt to one txt but in area like picture

 

[ronjonp · Accepted solution]

Here's a quick one based on the sample drawing. If the vertical distance between the groups is too close it will give incorrect results.

(defun c:foo (/ d e p s tm x)
  ;; RJP » 2021-06-29
  (cond
    ((setq s (ssget ":L" '((0 . "TEXT"))))
     (or (setq d (getdist "\nEnter distance to search: <1.5>")) (setq d 1.5))
     (setq s (vl-remove-if 'listp (mapcar 'cadr (ssnamex s))))
     (setq
       s (mapcar '(lambda (x) (list (cdr (assoc 10 (setq e (entget x)))) (cdr (assoc 1 e)) x)) s)
     )
     (setq s (vl-sort s '(lambda (r j) (< (caar r) (caar j)))))
     (while (car s)
       (setq p (caar s))
       (setq tm nil)
       (foreach	i s
	 (and (<= (distance p (car i)) d)
	      (setq tm (cons i tm))
	      (setq p (car i))
	      (setq s (vl-remove i s))
	 )
       )
       (if tm
	 (progn
	   (setq tm (reverse tm))
	   (entmod
	     (append (entget (last (car tm)))
		     (list (cons 1
				 (vl-string-right-trim
				   " "
				   (apply 'strcat (mapcar '(lambda (x) (strcat (cadr x) " ")) tm))
				 )
			   )
		     )
	     )
	   )
	   (mapcar 'entdel (mapcar 'last (cdr tm)))
	 )
       )
     )
    )
  )
  (princ)
)

[Anonymous]

Boa tarde.

Converte ou combina objetos de texto de linha única ou multilinha em um ou mais objetos de texto multilinha.

Pesquisa
Os objetos de texto selecionados são substituídos por um ou mais objetos de texto multilinha. Se possível, as diferenças de tamanho do texto, a fonte e a cor entre os objetos de texto são mantidas.

Comando: TXT2MTXT

Selecionar objetos ou [Configurações]: use um método de seleção de objetos para selecionar texto ou especifique a opção Configurações para exibir a caixa de diálogo Opções de texto para TextoM.

[the_ameral]

you are genius thank u

[the_ameral]

@ronjonp  

 can help in this 😁

https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/text-inside-block-border-to-its-attr...

[ronjonp]

---

@the_ameral wrote:
you are genius thank u

---

Glad to help 🍻