Macro to find out the lowest point of selected objects and align it to z=0
Try this:
(defun C:LZ0 (/ ss n zobj zmin); = move objects so Lowest Z coordinate is at 0
(command "_.ucs" ""); force to World Coordinate System
(setq ss (ssget "_X" (list (cons 410 (getvar 'ctab))))); everything in current space
(repeat (setq n (sslength ss))
(vla-getBoundingBox
(vlax-ename->vla-object (ssname ss (setq n (1- n))))
'minpt 'maxpt
); ...getBoundingBox
(setq
zobj (caddr (vlax-safearray->list minpt))
zmin (if zmin (min zmin zobj) zobj); lowest Z coordinate of anything so far
); setq
); repeat
(command "_.move" ss "" (list 0 0 (- zmin)) "")
(princ)
); defun
If the lowest initial point on anything is above Z=0, it Moves them all down; if it's below, it Moves them all up.
It can be changed to have the User select things instead of doing everything in the current space, to reset the UCS if it wasn't already in World Coordinates [or to do it differently and not change the UCS at all], and the usual other enhancements.
If anything is on a locked Layer, it won't be Moved, but the code could include unlocking all Layers if that's appropriate.
Kent Cooper, AIA 
@Anonymous wrote:
.... Could this be done solely with macro commands?....
I don't know of a way to do that solely with macro-command [or Script] operations. The Moving part is easy enough, but I can't picture a way of the finding of the lowest point on anything that doesn't require either:
A. stepping though a selection set and looking at each object, and AutoLisp functions are the only way I know to do that; or
B. if you want everything in the drawing [not a limited selection], the Z coordinate of the EXTMIN System Variable will give you that lowest elevation, but that also requires AutoLisp to extract, with (caddr (getvar 'extmin)). I realize you can't use the following either, but for any who can use AutoLisp and who are looking for such a routine, what my earlier routine does could actually be done with just this:
(defun C:LZ0 (); = move objects so Lowest Z coordinate is at 0
(command
"_.ucs" "" ; force to World Coordinate System
"_.zoom" "_extents" ; to update EXTMIN System Variable, just in case
"_.move" "_all" "" (list 0 0 (- (caddr (getvar 'extmin)))) ""
"_.zoom" "_previous"
"_.ucs" "_previous"
); command
(princ)
); defun
[The Zoom Extents is in there because the EXTMIN & EXTMAX System Variables are reset farther outboard whenever something beyond their former values is added/Moved/Copied/etc., but when something is Erased/Moved/Trimmed etc. to make the Extents smaller, the System Variables do not reflect that pulling in until a Zoom All or Zoom Extents happens. The routine also sets the UCS back, in case it wasn't already in the WCS, which should be added into the previous version, too.]
But something like the earlier routine with modification on the selection set would still be needed if a User selection is desired, rather than everything in the current space.
Kent Cooper, AIA
@Anonymous wrote:
Those EXTMIN and EXTMAX are very good return values, but read only. That's a pitty for Macro use.
I read you can compile lisp programs and that you can run every compiled lisp program on any version.
How can I do that exactly?
The pity isn't that EXTMIN/EXTMAX are read-only, but that there doesn't seem to be a way to read them in a command macro [or in a Script] without the use of the AutoLisp (getvar) function.
I haven't done compiling [I just use things in their .lsp file formats], but I had the impression it was a way of protecting distributed routines from alteration or extraction of their code content by the unauthorized, rather than a way to get AutoLisp routines to work in OEM or LT versions that can't otherwise use AutoLisp. Others with more experience in such things may chime in....
Kent Cooper, AIA
@Anonymous wrote:
The 2 in index. Does it mean 2 digits after the comma?
Can somebody point me out to a good site were I can learn to use DIESEL expressions?
Thank you!
I assume it's like AutoLisp's (nth) function, in which the first item in a list is item 0, and item 2 in an XYZ point list is the third item, i.e. the Z coordinate.
>Here< is the Diesel Functions Reference. In addition to the links at the bottom to related topics, in the broader Customization Guide Reference, there are additional Diesel entries about halfway down.
Kent Cooper, AIA
