Solved: Re: 🙏Load IDs to poles and properties, AutoCAD Map 3D.

arperezinf · ‎08-07-2023

Hello everyone 👋😀

I hope you are well.

Could any of you help me create a lisp command, for AutoCAD Map 3D, that allows loading a unique identifier to the poste and propiedad blocks.

I uploaded an example file, where you can see what I explain and test your commands.

You are going to see several elements in the drawing, the elements that I need to put an ID to are the "POSTE" and "PROPIEDAD", for that I need to take the value of "ID_BLOCK" from the "OD:MANZANA" property, which they will find it when they select an "MANZANA", that field is the unique identifier of each apple.

I need to create an ID_POSTE and ID_PROPIEDAD, as I show you below.

ID for POSTE:
ID_POSTE = ID_BLOCK.P01, ID_BLOCK.P02, ID_BLOCK.P03 .... ID_BLOCK.Pn

ID for PROPIEDAD:
ID_PROPIEDAD = ID_BLOCK.L01, ID_BLOCK.L02, ID_BLOCK.L03 .... ID_BLOCK.Ln

When you're done loading the values to the elements in and around one block, move to the other block and start the counter again, ID_BLOCK.P01, ID_BLOCK.P02, ... ID_BLOCK.L01... ID_BLOCK.02 , ... etc.

Remember the ID_BLOCK is the one that each apple has in the "OD:MANZANA" properties.

I hope you have been able to understand any questions, please ask.

I thank you in advance for your comments and help.
Thank you so much.
Greetings.

CADaSchtroumpf · ‎08-08-2023

Hi,

May be?

; checking if pline drawn CW or CCW
; Writer Evgeniy Elpanov.
; Selection prompt and "clockwise/counter-clockwise" results added
; by Bill Gilliss
(defun lwcl (lw / LST MAXP MINP)
  (vla-GetBoundingBox lw 'MinP 'MaxP)
  (setq
    minp (vlax-safearray->list minp)
    MaxP (vlax-safearray->list MaxP)
    lst 
    (mapcar
      (function
        (lambda (x)
          (vlax-curve-getParamAtPoint
            lw
            (vlax-curve-getClosestPointTo lw x)
          )
        )
      )
      (list minp
        (list (car minp) (cadr MaxP))
        MaxP
        (list (car MaxP) (cadr minp))
        )
    )
  )
  (if 
    (or
      (<= (car lst) (cadr lst) (caddr lst) (cadddr lst))
      (<= (cadr lst) (caddr lst) (cadddr lst) (car lst))
      (<= (caddr lst) (cadddr lst) (car lst) (cadr lst))
      (<= (cadddr lst) (car lst) (cadr lst) (caddr lst))
    )
    -1
    1
  )
)
(defun c:test ( / ss old_offset n ent data obj dxf_ent lst ss1 i e_sel tbl)
  (setq ss (ssget "_X" '((0 . "LWPOLYLINE") (8 . "MANZANA"))))
  (cond
    (ss
      (command "_.zoom" "_object" ss "")
      (setq old_offset (getvar "OFFSETDIST"))
      (setvar "OFFSETDIST" 7.0)
      (repeat (setq n (sslength ss))
        (setq
          ent (ssname ss (setq n (1- n)))
          data (ade_odgetfield ent "MANZANA" "ID_BLOCK" 0)
          obj (vlax-ename->vla-object ent)
        )
        (cond
          (data
            (vla-Offset (vlax-ename->vla-object ent) (* (lwcl obj) (getvar "OFFSETDIST")))
            (setq
              dxf_ent (entget (entlast))
              lst (mapcar 'cdr (vl-remove-if '(lambda (x) (/= (car x) 10)) dxf_ent))
            )
            (entdel (entlast))
            (cond
              (lst
                (setq ss1 (ssget "_WP" lst '((0 . "INSERT"))))
                (cond
                  (ss1
                    (repeat (setq i (sslength ss1))
                      (setq e_sel (ssname ss1 (setq i (1- i))))
                      (if (member (setq tbl (ade_odgettables e_sel)) '(("POSTES") ("PROPIEDAD")))
                        (if (eq (car tbl) "POSTES")
                          (ade_odsetfield e_sel (car tbl) "ID_POSTE" 0 data)
                          (ade_odsetfield e_sel (car tbl) "ID_PROPIEDAD" 0 data)
                        )
                      )
                    )
                  )
                )
              )
            )
          )
        )
      )
      (setvar "OFFSETDIST" old_offset)
    )
  )
  (prin1)
)

arperezinf · ‎08-08-2023

Hello @CADaSchtroumpf 👋

I tried the code that you posted, I saw that the id_block was loaded in all the posts and properties. 👏

I don't know how to make it with the following format:

POST_ID = ID_BLOCK.P01, ID_BLOCK.P02,... to ID_BLOCK.Pn.

PROPERTY_ID = ID_BLOCK.L01, ID_BLOCK.L02,... to ID_BLOCK.Ln.

For example, if there are 5 POSTS around a block, each post would have to have a POST_ID as follows:

ID_BLOCK.P01
ID_BLOCK.P02
ID_BLOCK.P03
ID_BLOCK.P04
ID_BLOCK.P05

Now, if there are 5 PROPERTIES within a block, each property would have to have a PROPERTY_ID as follows:

ID_BLOCK.L01
ID_BLOCK.L02
ID_BLOCK.L03
ID_BLOCK.L04
ID_BLOCK.L05

But, when the command finishes with that apple, it goes to the other apple and starts the count again 01, 02, 03... until the last element of each group.

I hope you can understand me.

Thank you so much.
Greetings.

CADaSchtroumpf · ‎08-08-2023

If I have understand, this?

; checking if pline drawn CW or CCW
; Writer Evgeniy Elpanov.
; Selection prompt and "clockwise/counter-clockwise" results added
; by Bill Gilliss
(defun lwcl (lw / LST MAXP MINP)
  (vla-GetBoundingBox lw 'MinP 'MaxP)
  (setq
    minp (vlax-safearray->list minp)
    MaxP (vlax-safearray->list MaxP)
    lst 
    (mapcar
      (function
        (lambda (x)
          (vlax-curve-getParamAtPoint
            lw
            (vlax-curve-getClosestPointTo lw x)
          )
        )
      )
      (list minp
        (list (car minp) (cadr MaxP))
        MaxP
        (list (car MaxP) (cadr minp))
        )
    )
  )
  (if 
    (or
      (<= (car lst) (cadr lst) (caddr lst) (cadddr lst))
      (<= (cadr lst) (caddr lst) (cadddr lst) (car lst))
      (<= (caddr lst) (cadddr lst) (car lst) (cadr lst))
      (<= (cadddr lst) (car lst) (cadr lst) (caddr lst))
    )
    -1
    1
  )
)
(defun c:test ( / ss old_offset n ent obj dxf_ent lst ss1 count_p count_l i e_sel tbl)
  (setq ss (ssget "_X" '((0 . "LWPOLYLINE") (8 . "MANZANA"))))
  (cond
    (ss
      (command "_.zoom" "_object" ss "")
      (setq old_offset (getvar "OFFSETDIST"))
      (setvar "OFFSETDIST" 7.0)
      (repeat (setq n (sslength ss))
        (setq
          ent (ssname ss (setq n (1- n)))
          data (ade_odgetfield ent "MANZANA" "ID_BLOCK" 0)
          obj (vlax-ename->vla-object ent)
        )
        (vla-Offset (vlax-ename->vla-object ent) (* (lwcl obj) (getvar "OFFSETDIST")))
        (setq
          dxf_ent (entget (entlast))
          lst (mapcar 'cdr (vl-remove-if '(lambda (x) (/= (car x) 10)) dxf_ent))
        )
        (entdel (entlast))
        (cond
          (lst
            (setq ss1 (ssget "_WP" lst '((0 . "INSERT"))))
            (cond
              (ss1
                (setq count_p 0.0 count_l 0.0)
                (repeat (setq i (sslength ss1))
                  (setq e_sel (ssname ss1 (setq i (1- i))))
                  (if (member (setq tbl (ade_odgettables e_sel)) '(("POSTES") ("PROPIEDAD")))
                    (if (eq (car tbl) "POSTES")
                      (ade_odsetfield
                        e_sel
                        (car tbl)
                        "ID_POSTE"
                        0
                        (strcat "ID_BLOCK.P" (substr (rtos (setq count_p (+ 0.01 count_p)) 2 2) 3))
                      )
                      (ade_odsetfield
                        e_sel
                        (car tbl)
                        "ID_PROPIEDAD"
                        0
                        (strcat "ID_BLOCK.L" (substr (rtos (setq count_l (+ 0.01 count_l)) 2 2) 3))
                      )
                    )
                  )
                )
              )
            )
          )
        )
      )
      (setvar "OFFSETDIST" old_offset)
    )
  )
  (prin1)
)

arperezinf · ‎08-08-2023

Hello @CADaSchtroumpf 👋

I just tried the command. I see that you managed to put the letters ID_BLOCK.P for posts and ID_BLOCK.L for properties, you understood me, but I didn't know how to explain myself, now I'll explain it in more detail.

Look at the ID_BLOCK, it has to be the number that each block has.

Important: I would need the numbers to go in a clockwise or counterclockwise direction, but continuous, that they don't jump.

For example, this number 452800072244 is the ID_BLOCK of the first block on the top left, which is between the streets ITALIA, MATHEU, GENOVA and AVENIDA HIPOLITO YRIGOYEN. This block has 12 posts around it and 18 properties inside.

So, the post ID for this block, I need it to be like this:

POST_ID = 452800072244.P01, 452800072244.P02, up to 452800072244.P12

So the ID for properties of this apple, I need it to be like this:

PROPERTY_ID = 452800072244.L01, 452800072244.L02, up to 452800072244.L18

Now when the code goes to another block, for example to the block that is next to the right, which is between the streets GENOVA, HIPLOLITO YRIGOYEN, MATHEU AND ALVEAR, which has the following ID_BLOCK number = 452800072245, the posts and properties It's going to take the ID_BLOCK of this block and start over at 01.

POST_ID = 452800072245.P01, 452800072245.P02, up to 452800072245.P08

PROPERTY_ID = 452800072245.P01, 452800072245.P02, up to 452800072245.P19.

So where you put in this last code the text ID_BLOCK, I need the numbers of the blocks, for example 452800072244 followed by a point plus the letter P (for posts) or L (for PROPERTY) in this case it would be something like this for the POSTS 452800072244 .P01, 452800072244.P02, up to 452800072244.Pn last post. and serious property 452800072244.L01, 452800072244.L02, up to 452800072244.Ln last property.

I upload an image so that you understand what I am explaining, the large red arrows are to explain the meaning of the numbers 01, 02, 03, they can go clockwise or counterclockwise and the small arrows are pointing to the poles.

Any questions please contact me.
Thank you so much.
Greetings.

CADaSchtroumpf · ‎08-08-2023

Ok,

The order will be made in relation to the polyline located on the "MANZANA" layer, the first vertex will be the origin of the sorting and will be done in the direction of the course of this one (it is she who decides the clockwise direction or anti-clockwise)

I have good?

(defun c:test ( / ss old_offset n ent data obj dxf_ent lst ss1 count_p count_l i e_sel pos tbl p_list lst_sort_p l_list lst_sort_l)
  (setq ss (ssget "_X" '((0 . "LWPOLYLINE") (8 . "MANZANA"))))
  (cond
    (ss
      (command "_.zoom" "_object" ss "")
      (setq old_offset (getvar "OFFSETDIST"))
      (setvar "OFFSETDIST" 7.0)
      (repeat (setq n (sslength ss))
        (setq
          ent (ssname ss (setq n (1- n)))
          data (ade_odgetfield ent "MANZANA" "ID_BLOCK" 0)
          obj (vlax-ename->vla-object ent)
        )
        (cond
          (data
            (vla-Offset (vlax-ename->vla-object ent) (* (lwcl obj) (getvar "OFFSETDIST")))
            (setq
              dxf_ent (entget (entlast))
              lst (mapcar 'cdr (vl-remove-if '(lambda (x) (/= (car x) 10)) dxf_ent))
            )
            (entdel (entlast))
            (cond
              (lst
                (setq ss1 (ssget "_WP" lst '((0 . "INSERT"))))
                (cond
                  (ss1
                    (setq p_list nil l_list nil lst_sort_p nil lst_sort_l nil)
                    (repeat (setq i (sslength ss1))
                      (setq
                        e_sel (ssname ss1 (setq i (1- i)))
                        pos (cdr (assoc 10 (entget e_sel)))
                      )
                      (if (member (setq tbl (ade_odgettables e_sel)) '(("POSTES") ("PROPIEDAD")))
                        (if (eq (car tbl) "POSTES")
                          (setq
                            p_list (cons (cons (vlax-curve-getDistAtPoint ent (vlax-curve-getClosestPointTo ent pos)) e_sel) p_list)
                            lst_sort_p (vl-sort p_list '(lambda (e1 e2) (< (car e1) (car e2))))
                          )
                          (setq
                            l_list (cons (cons (vlax-curve-getDistAtPoint ent (vlax-curve-getClosestPointTo ent pos)) e_sel) l_list)
                            lst_sort_l (vl-sort l_list '(lambda (e1 e2) (< (car e1) (car e2))))
                          )
                        )
                      )
                      (setq count_p 0.0 count_l 0.0)
                      (if lst_sort_p
                        (mapcar
                          '(lambda (x)
                            (ade_odsetfield
                              x
                              "POSTES"
                              "ID_POSTE"
                              0
                              (strcat data ".P" (substr (rtos (setq count_p (+ 0.01 count_p)) 2 2) 3))
                            )
                          )
                          (mapcar 'cdr lst_sort_p)
                        )
                      )
                      (if lst_sort_l
                        (mapcar
                          '(lambda (x)
                            (ade_odsetfield
                              x
                              "PROPIEDAD"
                              "ID_PROPIEDAD"
                              0
                              (strcat data ".L" (substr (rtos (setq count_l (+ 0.01 count_l)) 2 2) 3))
                            )
                          )
                          (mapcar 'cdr lst_sort_l)
                        )
                      )
                    )
                  )
                )
              )
            )
          )
        )
      )
      (setvar "OFFSETDIST" old_offset)
    )
  )
  (prin1)
)

arperezinf · ‎08-08-2023

Hello @CADaSchtroumpf 👋

I just tried the code and it gave this error:

"Command: ; error: no function definition: LWCL"

The IDs, of the posts and properties, can be placed in a clockwise or counterclockwise direction, what cannot happen is that they jump from one street to another.

For example:

Looking at the image that I uploaded, the codes 452800072244.P01... and 452800072244.L01... go in a consecutive clockwise direction, as seen in the image, but it cannot happen that it jumps from 452800072244.P05 on GENOVA street, to put 452800072244.P06... on ITALIA street, the codes have to rotate in only one direction, as seen in the image.

I hope you understand me.

If you don't understand me, ask again, no problem and I'll see how to explain.

Thank you so much.
Greetings.

arperezinf · ‎08-08-2023

Hello @CADaSchtroumpf

I saw what the problem was, I think I can solve it.
Now I try it.

I think this is missing from the code.

; checking if pline drawn CW or CCW
; Writer Evgeniy Elpanov.
; Selection prompt and "clockwise/counter-clockwise" results added
; by Bill Gilliss
(defun lwcl (lw / LST MAXP MINP)
  (vla-GetBoundingBox lw 'MinP 'MaxP)
  (setq
    minp (vlax-safearray->list minp)
    MaxP (vlax-safearray->list MaxP)
    lst 
    (mapcar
      (function
        (lambda (x)
          (vlax-curve-getParamAtPoint
            lw
            (vlax-curve-getClosestPointTo lw x)
          )
        )
      )
      (list minp
        (list (car minp) (cadr MaxP))
        MaxP
        (list (car MaxP) (cadr minp))
        )
    )
  )
  (if 
    (or
      (<= (car lst) (cadr lst) (caddr lst) (cadddr lst))
      (<= (cadr lst) (caddr lst) (cadddr lst) (car lst))
      (<= (caddr lst) (cadddr lst) (car lst) (cadr lst))
      (<= (cadddr lst) (car lst) (cadr lst) (caddr lst))
    )
    -1
    1
  )
)

I think that this is how the code should go, right?

; checking if pline drawn CW or CCW
; Writer Evgeniy Elpanov.
; Selection prompt and "clockwise/counter-clockwise" results added
; by Bill Gilliss
(defun lwcl (lw / LST MAXP MINP)
  (vla-GetBoundingBox lw 'MinP 'MaxP)
  (setq
    minp (vlax-safearray->list minp)
    MaxP (vlax-safearray->list MaxP)
    lst 
    (mapcar
      (function
        (lambda (x)
          (vlax-curve-getParamAtPoint
            lw
            (vlax-curve-getClosestPointTo lw x)
          )
        )
      )
      (list minp
        (list (car minp) (cadr MaxP))
        MaxP
        (list (car MaxP) (cadr minp))
        )
    )
  )
  (if 
    (or
      (<= (car lst) (cadr lst) (caddr lst) (cadddr lst))
      (<= (cadr lst) (caddr lst) (cadddr lst) (car lst))
      (<= (caddr lst) (cadddr lst) (car lst) (cadr lst))
      (<= (cadddr lst) (car lst) (cadr lst) (caddr lst))
    )
    -1
    1
  )
)
(defun c:test ( / ss old_offset n ent data obj dxf_ent lst ss1 count_p count_l i e_sel pos tbl p_list lst_sort_p l_list lst_sort_l)
  (setq ss (ssget "_X" '((0 . "LWPOLYLINE") (8 . "MANZANA"))))
  (cond
    (ss
      (command "_.zoom" "_object" ss "")
      (setq old_offset (getvar "OFFSETDIST"))
      (setvar "OFFSETDIST" 7.0)
      (repeat (setq n (sslength ss))
        (setq
          ent (ssname ss (setq n (1- n)))
          data (ade_odgetfield ent "MANZANA" "ID_BLOCK" 0)
          obj (vlax-ename->vla-object ent)
        )
        (cond
          (data
            (vla-Offset (vlax-ename->vla-object ent) (* (lwcl obj) (getvar "OFFSETDIST")))
            (setq
              dxf_ent (entget (entlast))
              lst (mapcar 'cdr (vl-remove-if '(lambda (x) (/= (car x) 10)) dxf_ent))
            )
            (entdel (entlast))
            (cond
              (lst
                (setq ss1 (ssget "_WP" lst '((0 . "INSERT"))))
                (cond
                  (ss1
                    (setq p_list nil l_list nil lst_sort_p nil lst_sort_l nil)
                    (repeat (setq i (sslength ss1))
                      (setq
                        e_sel (ssname ss1 (setq i (1- i)))
                        pos (cdr (assoc 10 (entget e_sel)))
                      )
                      (if (member (setq tbl (ade_odgettables e_sel)) '(("POSTES") ("PROPIEDAD")))
                        (if (eq (car tbl) "POSTES")
                          (setq
                            p_list (cons (cons (vlax-curve-getDistAtPoint ent (vlax-curve-getClosestPointTo ent pos)) e_sel) p_list)
                            lst_sort_p (vl-sort p_list '(lambda (e1 e2) (< (car e1) (car e2))))
                          )
                          (setq
                            l_list (cons (cons (vlax-curve-getDistAtPoint ent (vlax-curve-getClosestPointTo ent pos)) e_sel) l_list)
                            lst_sort_l (vl-sort l_list '(lambda (e1 e2) (< (car e1) (car e2))))
                          )
                        )
                      )
                      (setq count_p 0.0 count_l 0.0)
                      (if lst_sort_p
                        (mapcar
                          '(lambda (x)
                            (ade_odsetfield
                              x
                              "POSTES"
                              "ID_POSTE"
                              0
                              (strcat data ".P" (substr (rtos (setq count_p (+ 0.01 count_p)) 2 2) 3))
                            )
                          )
                          (mapcar 'cdr lst_sort_p)
                        )
                      )
                      (if lst_sort_l
                        (mapcar
                          '(lambda (x)
                            (ade_odsetfield
                              x
                              "PROPIEDAD"
                              "ID_PROPIEDAD"
                              0
                              (strcat data ".L" (substr (rtos (setq count_l (+ 0.01 count_l)) 2 2) 3))
                            )
                          )
                          (mapcar 'cdr lst_sort_l)
                        )
                      )
                    )
                  )
                )
              )
            )
          )
        )
      )
      (setvar "OFFSETDIST" old_offset)
    )
  )
  (prin1)
)

arperezinf · ‎08-08-2023

Hello @CADaSchtroumpf 👋😁

You are a genius!!! Now it works!!!

I am going to test it a little more, to verify that all the ids are loaded correctly, but in principle I see that it does everything correctly.

I ask, can I put this information to the command:

; Load ids to poles and properties.
; written by Bruno Valsecchi
; date 08-08-23
; command name: bvid

One more detail that I missed, I apologize for not commenting before.

You saw that there is a magenta or pink line around the layer name "POLIGONO_RELEVAMIENTO".

You could add some instruction to the code so that it only adds the IDs to the "POSTS" and "PROPERTY", which are inside the "POLIGONO_RELEVAMIENTO".

Thank you so much.

CADaSchtroumpf · ‎08-10-2023

@arperezinf

Here is the final version
This code is specific to your drawing data, it will not work on other data; it would take too much work to make it more generic..., it is only useful for you.
Only processes the blocks contained in the polyline(s) located on the "POLIGONO_RELEVAMIENTO" layer
I added the command line display of the results that the code does.
I'll leave it up to you in the code to enter the offset distance I set with your example at 7.0: this is roughly half the street distance.

arperezinf · ‎08-11-2023

Hola @CADaSchtroumpf

How are you?
Sorry for the delay in responding, I was testing the final version, but now there are some messages that did not appear in the previous version.

These are the messages:

Comando: BVID
_.setvar Indique nombre de variable o [?]: OFFSETDIST
Indique nuevo valor para OFFSETDIST <7.0000>:
Comando:
02 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000820
16 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000820
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
07 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000162
25 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000162
01 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000705
17 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000705
06 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000709
19 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000709
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
06 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000710
31 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000710
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
10 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000713
17 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000713
04 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000714
17 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000714
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
11 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000241
32 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000241
09 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000242
28 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000242
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
10 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000715
19 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000715
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
16 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000716
23 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000716
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
07 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000717
19 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000717
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
16 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000286
34 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000286
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
12 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000703
30 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000703
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
08 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000704
19 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000704
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
11 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 1496000767
22 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 1496000767
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
12 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 452800072244
18 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 452800072244
08 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 452800072245
19 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 452800072245
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
Block DOT have not Object Data attached for "POSTES" or "PROPIEDAD"
12 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 452800072246
24 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 452800072246
07 Blocks have Object Data attached for "POSTES" with data "ID_BLOCK" 452800072247
02 Blocks have Object Data attached for "ID_PROPIEDAD" with data "ID_BLOCK" 452800072247

It's rare that these messages appear now.

Please, could you check those messages because they will be coming out now.

Thank you so much.
Greetings.

CADaSchtroumpf · ‎08-12-2023

@arperezinf a écrit :
Hola @CADaSchtroumpf

It's rare that these messages appear now.
Please, could you check those messages because they will be coming out now.
Thank you so much.
Greetings.

@arperezinf

This is purely informational, like a run log.
If you want the code to be less verbose, comment out (with a semi-colon ";" at the beginning of the line) the following lines:
- 105
- 137
- 138
- 157

arperezinf · ‎08-14-2023

Hello @CADaSchtroumpf

Sorry about the delay in responding.
I thought they were errors.
Ah great, thanks for that last information.
Excellent job.
Thank you so much.
Greetings.

🙏Load IDs to poles and properties, AutoCAD Map 3D.

🙏Load IDs to poles and properties, AutoCAD Map 3D.

Forums Links

Post to forums