list the length of all segments of a polyline
Accepted solution
Ok, my bad.
See code below, but with your example polyline the list gets pretty long 
(defun c:Test (/ T_Entity T_Object T_Start T_End T_SegmentLengths T_Count)
(if
(and
(setq T_Entity (car (entsel "\nSelect polyline: ")))
(= (vla-get-ObjectName (setq T_Object (vlax-ename->vla-object T_Entity))) "AcDbPolyline")
)
(progn
(setq T_Start (vlax-curve-getStartParam T_Object))
(setq T_End (vlax-curve-getEndParam T_Object))
(while (< T_Start T_End)
(setq T_SegmentLengths (append T_SegmentLengths (list (- (vlax-curve-getDistAtParam T_Object (setq T_Start (1+ T_Start))) (vlax-curve-getDistAtParam T_Object (1- T_Start))))))
)
(setq T_Count 0)
(foreach T_Item T_SegmentLengths
(princ (strcat "\nSegment " (itoa (setq T_Count (1+ T_Count))) ": " (rtos T_Item)))
)
(princ (strcat "\n\n ** Total polyline length is " (rtos (vla-get-Length T_Object))))
)
(princ "\n ** Nothing selected or not a polyline.")
)
(princ)
)
Glad I could help
And no problem, only a small addition to the existing code.
(defun c:Test (/ T_Entity T_Object T_Start T_End T_SegmentLengths T_Count)
(if
(and
(setq T_Entity (car (entsel "\nSelect polyline: ")))
(= (vla-get-ObjectName (setq T_Object (vlax-ename->vla-object T_Entity))) "AcDbPolyline")
)
(progn
(setq T_Start (vlax-curve-getStartParam T_Object))
(setq T_End (vlax-curve-getEndParam T_Object))
(while (< T_Start T_End)
(setq T_SegmentLengths (append T_SegmentLengths (list (- (vlax-curve-getDistAtParam T_Object (setq T_Start (1+ T_Start))) (vlax-curve-getDistAtParam T_Object (1- T_Start))))))
)
(setq T_Count 0)
(foreach T_Item T_SegmentLengths
(princ (strcat "\nSegment " (itoa (setq T_Count (1+ T_Count))) ": " (rtos T_Item (getvar "LUNITS") 6)))
)
(princ (strcat "\n\n ** Total polyline length is " (rtos (vla-get-Length T_Object) (getvar "LUNITS") 6)))
)
(princ "\n ** Nothing selected or not a polyline.")
)
(princ)
)
@Anonymous wrote:
.... have all the segment lengths be put into a single column output table so I would be able to export the lengths? I just want the lengths of the individual polyline segments to be input into our spreadsheet. ....
You don't need the middle-man of a Table to then be exported -- you can send them directly to a spreadsheet file:
(defun C:PSLE (/ pl psle n); = Polyline Segment Lengths Export
(setq
pl (car (entsel "\nPolyline for Segment-Length Export: "))
psle (open "C:/PSLE.csv" "w"); replace with your drive:filepath/filename
n 0
); setq
(repeat (fix (vlax-curve-getEndParam pl))
(write-line
(rtos
(abs
(-
(vlax-curve-getDistAtParam pl n)
(vlax-curve-getDistAtParam pl (setq n (1+ n)))
); -
); abs
2 6
); rtos
psle
); write-line
); repeat
(close psle)
); defun
Kent Cooper, AIA 
@Anonymous wrote:
.... modify it to be able to get all of the columns in the attached word document filled? ....
Not without some more information about what those categories need in them. But you can probably work it out from this start. It assumes sequential numbering for the Feeder ID, and uses the cumulative distance along the overall Polyline at the vertices for the "Run Start" and "Run End" for each segment, but that's also just an assumption -- maybe you need a location or something. I had no idea what to assume about the # of Turbines, but maybe you can figure out what to put there instead of my "whatever".
(defun C:PSLE (/ pl psle n); = Polyline Segment Lengths Export
(setq
pl (car (entsel "\nPolyline for Segment-Length Export: "))
psle (open "C:/PSLE.csv" "w")
n 0
); setq
(write-line "Feeder" psle); top line
(write-line "ID,Run Start,Run End,Length,# of Turbines" psle); headings
(repeat (fix (vlax-curve-getEndParam pl))
(write-line
(strcat
(itoa (1+ n)) "," ; ID
(rtos (vlax-curve-getDistAtParam pl n) 2 6) "," ; Run Start
(rtos (vlax-curve-getDistAtParam pl (1+ n)) 2 6) "," ; Run End
(rtos ; Length
(abs
(-
(vlax-curve-getDistAtParam pl n)
(vlax-curve-getDistAtParam pl (setq n (1+ n)))
); -
); abs
2 6
); rtos
","
"whatever" ; # of Turbines
); strcat
psle
); write-line
); repeat
(close psle)
); defun
Kent Cooper, AIA
@Anonymous wrote:
....
How do you use the lisp to export the values into the spreadsheet we have developed?
….
Will using the (open) function with the append option [instead of the write option] do it for you?
Kent Cooper, AIA
@Anonymous wrote:
.... That doesn't seem to allow me to open the table with that.
[Sorry, but I never have a need to deal with relating to external files of other types in AutoCAD. I know enough to write to a .CSV file, and to read from pretty simple files like those and in plain text, but that's about it -- I don't know enough about things like data extraction or tables. I hope someone else with experience doing such things can help.]
Kent Cooper, AIA
@sameerulcdc wrote:
.... please can u update to select multiple line in one time
And what would be the delimiter between the reporting on each Polyline? Simply starting the ID numbers over again at 1? An empty line? Some kind of item header such as the Handle? Something else? A small sample file with the format you would expect [with only a few Polylines' worth] would answer all questions.
Kent Cooper, AIA
@sameerulcdc wrote:
.... like this format please
That looks like you're after a modification of the routine at Message 9, not Message 11. Is that right?
Kent Cooper, AIA