It looks like you are using Lee Mac's routine to insert the block at a particular state.
Your code is treating it like a macro an not a function.
Your command is ok to start with
(DEFUN C:pbox ()
(prong ; This is not needed
(setq cAnno (/ 1 (getvar "cannoscalevalue"))) ; You need to finish off your setq
(command "layer" "m" "TF-ILLUM-PROP-SYM" "c" "g" "" "") ; This does good for setting the layer
(lm:insertwithstate "jb-p" "P - Pull Box") ;this will insert the block and set the state to the specified state
) ; Closing Progn and not needed
) ; Close defun
;; "NEA;\(GETVAR 'cAnno)""""\)) ;;; This code is not doing anything for you
Based on what I can tell Lee's function defaults to inserting at 0,0,0 and with a scale of 1.0 and a rotation of 0.0
You could update his routine to take another arguments scale or you could simply add in a returned entity and place it where you want it to go. with the new scale. I would go ahead and add the functionality you want into Lee Mac's routine, but update the name so it does not confuse the situation or create a duplicate definition.
Then the above call would look like this instead. (using the new function listed below)
(lm:insertwithstateandscale "jb-p" "P - Pull Box" cAnno) ;this will insert the block and set the state to the specified state
Give this a try. Please note this is Lee Mac's routine, with the suggested updates.
;; Insert With Visibility State - Lee Mac
;;;Modified VErsion to accept scale factor
;; Provides an interface through which the user can insert a dynamic block
;; with a preselected visibility state.
;; blk - [str] Block name, filename or full filepath
;; vis - [str] Visibility State to set on insertion
;;;scl - [real] Scale Value
;; Returns: [vla] Inserted VLA block reference object, else nil if unsuccessful
(defun LM:insertwithstateandscale ( blk vis scl / bse cmd def ent ext new obj pth rtn tmp )
(setq pth (vl-string-translate "/" "\\" (vl-filename-directory blk))
ext (cond ((vl-filename-extension blk)) (".dwg"))
bse (vl-filename-base blk)
)
(if (/= "" pth)
(setq pth (strcat pth "\\"))
)
(cond
( (not
(or
(and
(tblsearch "block" bse)
(setq blk bse)
)
(setq blk (findfile (strcat pth bse ext)))
)
)
(prompt (strcat "\nBlock \"" bse "\" not found."))
)
( (progn
(setq obj
(vlax-invoke
(vlax-get-property (LM:acdoc)
(if (= 1 (getvar 'cvport))
'paperspace
'modelspace
)
)
'insertblock
'(0.0 0.0 0.0)
blk
1.0 1.0 1.0 0.0
)
)
(vla-put-visible obj :vlax-false)
(= :vlax-false (vla-get-isdynamicblock obj))
)
(vla-delete obj)
(prompt (strcat "\nBlock \"" bse "\" is not dynamic."))
)
( (null (LM:setvisibilitystate obj vis))
(vla-delete obj)
(prompt
(strcat
"\nUnable to set visibility state of block \""
bse
"\" to \""
vis
"\"."
)
)
)
( (setq tmp 0)
(while
(tblsearch "block"
(setq blk
(strcat "tmp" (itoa (setq tmp (1+ tmp))))
)
)
)
(vla-put-visible
(car
(vlax-invoke (LM:acdoc) 'copyobjects (list obj)
(setq def
(vlax-invoke
(vla-get-blocks (LM:acdoc))
'add
'(0.0 0.0 0.0)
blk
)
)
)
)
:vlax-true
)
(vla-delete obj)
(setq ent (entlast)
cmd (getvar 'cmdecho)
)
(setvar 'cmdecho 0)
(princ "\nSpecify insertion point: ")
(if
(and
(vl-cmdf "_.-insert" blk "_S" scl "_R" 0.0 "\\")
(not (eq ent (setq ent (entlast))))
(setq new (vlax-ename->vla-object ent))
(= "AcDbBlockReference" (vla-get-objectname new))
)
(progn
(setq rtn (car (vlax-invoke new 'explode)))
(vla-delete new)
)
)
(setvar 'cmdecho cmd)
(vl-catch-all-apply 'vla-delete (list def))
)
)
rtn
)
Good luck
