LISP TO PLACE A group of blocks on a similar axis
Hey Guys,
I appreciate the help. Thank you.
Let me explain my question a little more. I do fire alarm design right now. fairly new. I have 10 blocks. each one is a smoke detector and they are scattered around a floor plan in their designated positions. I would like to select them all and somehow get them to all line up. Let me show you in pictures.
I would like to get the objects in picture one to line up like in picture two. Without having to do it one at a time as some projects have multiple tens of devices.
Looks easy enough to do, but:
Do you need the Lines drawn between them, or just the alignment?
Would you want the routine to ask you for a spacing between them, or should it calculate it on the basis of something like the Block's size, or could it always be the same amount and be hard-coded in?
Would you want them Moved from their positions around the plan, or Copied so that they also remain in place in the plan?
How would you want to designate where to put that row of them?
Kent Cooper, AIA 
Hi,
May be you are looking for the measure command. If you want to draw the schematic diagram for fire alarm this command could be handy.
Cheers,
Vinay Vijayakumaran 
@Anonymous wrote:
... lines to be drawn between them and it could be a set length for the lines.so it's the same length every time.
....
I would like them copied, so the originals remain and placed where I designate it with a mouse click.
....
Finally got around to working something out [in simplest terms, lightly tested]:
(defun C:BAL (/ osm bss pt rad len blk n); = Block Align with Lines between
;; for Blocks with primary Circle, with insertion point at its center
(setq osm (getvar 'osmode))
(prompt "\nTo Align Blocks with connecting Lines,")
(if
(and
(setq bss (ssget '((0 . "INSERT"))))
(setq pt (getpoint "\nPosition of left-most copy: "))
(setq rad (getdist "\nRadius of circle part of Blocks: "))
(setq len (getdist "\nLength of Lines between copies: "))
); and
(progn ; then
(setvar 'osmode 0)
(command
"_.copy" (setq blk (ssname bss (setq n (1- (sslength bss))))) ""
(cdr (assoc 10 (entget blk))) pt
); command
(repeat n
(command
"_.line" (setq pt (polar pt 0 rad)) (setq pt (polar pt 0 len)) ""
"_.copy" (setq blk (ssname bss (setq n (1- n)))) ""
(cdr (assoc 10 (entget blk))) (setq pt (polar pt 0 rad))
); command
); repeat
(setvar 'osmode osm)
); progn
); if
); defun
If you have a fixed and constant value for 'rad' and 'len', you can pull those out of the User-input area and the localized variables list, and just put those values into the code in place of those variable names.
EDIT:
Now that I look back at the lower image in Post 5, with a Line also to the right of the last one, that's also possible [in fact, a little simpler]:
(defun C:BAL (/ osm bss pt rad len blk n); = Block Align with Lines between
;; for Blocks with primary Circle, with insertion point at its center
(setq osm (getvar 'osmode))
(prompt "\nTo Align Blocks with connecting Lines,")
(if
(and
(setq bss (ssget '((0 . "INSERT"))))
(setq pt (getpoint "\nPosition of left-most copy: "))
(setq rad (getdist "\nRadius of circle part of Blocks: "))
(setq len (getdist "\nLength of Lines between copies: "))
); and
(progn ; then
(setvar 'osmode 0)
(repeat (setq n (sslength bss))
(command
"_.copy" (setq blk (ssname bss (setq n (1- n)))) ""
(cdr (assoc 10 (entget blk))) pt
"_.line" (setq pt (polar pt 0 rad)) (setq pt (polar pt 0 len)) ""
); command
(setq pt (polar pt 0 rad))
); repeat
(setvar 'osmode osm)
); progn
); if
); defun
It could also restrict selection to only a specific Block name, so you could select an area with a window and any other Blocks would be ignored. And it could put the Lines on a designated Layer, and it could .... . . . . . . . .
Kent Cooper, AIA
@Ranjit_Singh wrote:
....
.... (setq endpoint (mapcar '+ startpoint (list (* ctr bldist) 0 0))) .... (command-s "._line" startpoint endpoint "")
....
Not a single Line through the entire string of copies of the Blocks -- look again at the lower image in Post 5, and the first answer in Post 7 [lines (plural) between them].
Kent Cooper, AIA
