Respected Members,
Can anybody guide me to a LISP capable of flipping/mirroring the positions of TEXT/MTEXT objects across a polyline object. The polyline may have multiple segments/vertices and can be either closed or open in various scenarios.
See the following screenshot to demonstrate the outcome. A .dwg file is also attached for reference.
Thank you!
@ВeekeeCZ has made it the way it should be, here is my code created in less than a minute for sequential mirroring with deletion of original text objects
(defun c:mirrortext ( / *error* ss)
(defun *error* (msg)
(if (not (wcmatch (strcase msg) "*BREAK*,*CANCEL*,*EXIT*"))
(princ (strcat "\nOops an Error : ( " msg " ) occurred."))
)
(setvar 'cmdecho 1)
(princ)
)
(setvar 'cmdecho 0)
(princ "\nSelect text to mirror >")
(while (setq ss (ssget '((0 . "*TEXT"))))
(command "_.mirror" ss "" (getpoint "\nFirst mirror point >")(getpoint "\nSecond mirror point >") "y")
)
(setvar 'cmdecho 1)
(princ)
)Miljenko Hatlak
My routine to do that kind of thing [with any kind(s) of objects across any kind of path] is MirrorAcrossObject.lsp with its MAO command, >here<.
Try this,
(defun c:mirror-text (/ ss e eo ent dxf_ent di var_cmdecho var_osmode)
(defun *error* ( msg )
(LM:endundo (LM:acdoc))
(if (not (wcmatch (strcase msg t) "*break,*cancel*,*exit*"))
(princ (strcat "\nError: " msg))
)
(setvar 'cmdecho var_cmdecho)
(setvar 'osmode var_osmode)
(princ)
)
(LM:startundo (LM:acdoc))
(setq var_cmdecho (getvar "cmdecho"))
(setq var_osmode (getvar "osmode"))
(setvar 'cmdecho 0)
(setvar 'osmode 0)
(setq ss (ssget ":L" (list '(0 . "TEXT,MTEXT") )))
(setq e (car (entsel "\nSelect polyline : ")))
(setq eo (vlax-ename->vla-object e))
(if ss (repeat
(setq n (sslength ss))
(setq
ent (ssname ss (setq n (1- n)))
dxf_ent (entget ent)
)
(vla-getboundingbox (vlax-ename->vla-object ent) 'mn 'mx)
(setq llpt (vlax-safearray->list mn))
(setq urpt (vlax-safearray->list mx))
(setq midpt (mapcar '(lambda (x y) (/ (+ x y) 2)) llpt urpt))
(setq di (distance (setq pt (vlax-curve-getclosestpointto eo midpt)) midpt))
(command "_.move" ent "" midpt (polar midpt (angle midpt pt) (* di 2) ))
)
)
(LM:endundo (LM:acdoc))
(setvar 'cmdecho var_cmdecho)
(setvar 'osmode var_osmode)
(princ)
);defun
;; Start Undo - Lee Mac
;; Opens an Undo Group.
(defun LM:startundo ( doc )
(LM:endundo doc)
(vla-startundomark doc)
)
;; End Undo - Lee Mac
;; Closes an Undo Group.
(defun LM:endundo ( doc )
(while (= 8 (logand 8 (getvar 'undoctl)))
(vla-endundomark doc)
)
)
;; Active Document - Lee Mac
;; Returns the VLA Active Document Object
(defun LM:acdoc nil
(eval (list 'defun 'LM:acdoc 'nil (vla-get-activedocument (vlax-get-acad-object))))
(LM:acdoc)
)
(princ "\nmirror-text" )
(princ)
@Yasir.Aman wrote:
@hak_vz I highly appreciate your effort immensely but unfortunately this is not what I need. This is essentially just another replication of AutoCAD's mirror command.
In any case, I thank you for considering my post.
At the time I wanted to paste my solution @ВeekeeCZ has already done it. My code was in general totally similar with his solution so I restrained from doing it. Since one of the goals of this forum is no to continuously provide code solutions but to teach autolisp beginners to start programming I posted this simple solution to show novice learners how they can simply make their code execution faster.
Now, question to other code providers to this post.
@ВeekeeCZ and @kajanthangavel In your code you are extracting text bounding box. To mirror text object is this really necessary?
In @Yasir.Aman demo we have text with different justification, but all of them mirror correctly.
Catch is in system variable MIRRTEXT that controls how MIRROR reflects text ( 0 - Retains text direction 1 - Mirrors the text). Instead of search for vlax-curve-getclosestpointto finding appropriate polyline segment is all what is needed.
Miljenko Hatlak
@hak_vz wrote:
....@ВeekeeCZ and @kajanthangavel In your code you are extracting text bounding box. To mirror text object is this really necessary?
..... Instead of search for vlax-curve-getclosestpointto finding appropriate polyline segment is all what is needed.
Mine also uses the bounding box, and finds the closest point to the middle of that on the Mirror path object. The "appropriate polyline segment" may serve well enough for the Mirror axis when the path is a Polyline made of only line segments, but mine works with Polylines including arc segments and all other kinds of path objects with linearity [(vlax-curve-...)-class objects].
EDIT -- Further elaboration on the difference it makes:
If "finding appropriate polyline segment" means you would use the endpoints of that nearest segment for the Mirror axis, then if that segment is a line segment, it doesn't matter, but if it's an arc segment, here's the difference:
The white "test" Texts are the originals, and the yellow Polyline is the Mirroring path. The red ones are the result of using the endpoints of the nearest segment [the magenta Points] as the Mirror axis. The green ones are the result of using the direction of the path at its closest point to the midpoint of the object's bounding box [here done with my MAO command, but I assume similar results from other routines that take a similar approach].
And if "finding appropriate polyline segment" involves finding the place on the path that is closest to the object, then if it's not using the middle of its bounding box, presumably for Text it would have to use the insertion point. The results from that will vary depending on the justification of the Text, even when using the local direction of the path for the Mirror axis, not just the segment endpoints. Here, the Text is left-justified. Again, if the closest point is on a line segment, it doesn't matter, but with an arc segment, here's the difference:
The magenta Point is the closest point on the path to the Text's insertion point. Using the direction of the path at that point for the Mirror axis, the result is the red one. Using the closest point to the Text's bounding-box midpoint gives the green result [again, here done with MAO].
If the Text were Middle or Middle-Center or Middle-Left of Middle-right justified, and if its rotation were always perpendicular to the path as in these examples, it wouldn't matter [or not much -- there could be slight differences depending on which of those justifications and the specifics of the text content]. Likewise if it were Center or Bottom-Center or Middle-Center or Top-Center justified and its rotation were parallel to the path. But other justifications and/or rotations will have similar differences in results.
The effects are similar with path objects such as Ellipses, Splines, Arcs, and Circles. It wouldn't make a difference when the path is a Line or Ray or Xline, nor a Polyline line segment except for situations where a Text object is close to a bend in the Polyline, where again the justification could make a difference, because the nearest point on the Polyline to the insertion point could be on a different segment than the nearest point to the bounding-box midpoint.
@Kent1Cooper You really take time for detailed explanation. I'm fully aware of it, but in case of OP request where he uses straight segments (a little bit overcrowded what I noticed to late) I thought simple mirror flip over a polygon segment will do the trick. >The other case to consider are when using nearest point algorithm are sharp edges, where depending on text position regarding to flipping polyline, may also produce undesired result.
Miljenko Hatlak
