Hello everyone,
i want a lisp to export all selected lines colors and also export texts beside them to excel. You can find below photos of the lines and texts in autocad and the table i want in excel, also DWG file will be attached for reference. If it is hard to get texts beside the lines, i could move texts to be in the line itself.
Thanks in advance
actually this is exactly the case, i have some lines and some texts next to it (this is not a legend or something this is the actual case) as attached in the dwg, but of course they are not 3 lines and 3 texts only they are alot i am just bringing a sample but all of them are in the same format. The excel or csv i want is as attached here
Regards @hythamthelove
To start, here is my proposal, tested in the example file. Please select only the polylines
(vl-load-com)
(defun c:sst (/ f of s sn svn p1 p2 tx tf)
(setq f (getfiled "\nEnter name File:" "" "csv" 1)
of (open f "w")
)
(setq s (ssget '((0 . "lwpolyline"))))
(repeat (setq i (sslength s))
(setq sn (ssname s (setq i (1- i)))
svn (vlax-ename->vla-object sn)
ct (vla-get-truecolor svn)
)
(setq p1 (cdr (assoc 10 (entget sn)))
p2 (polar p1 0 5400)
)
(setq tx (ssget "_f" (list p1 p2) '((0 . "*text")))
tf (substr (cdr (assoc 1 (entget (ssname tx 0)))) 7)
)
(write-line (strcat (col ct) ";" tf) of)
)
(close of)
)
(defun col (c)
(vl-string-right-trim
","
(apply 'strcat
(mapcar '(lambda (x) (strcat (itoa (vlax-get c x)) ","))
'(red green blue)
)
)
)
)
Carlos Calderon G
>Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Dear @hythamthelove
I made some adjustments, you had texts that were not in the selection line and with different configuration.
Tested on the new file provided. Please select only the polylines by 2 points (Fence) from top to bottom.
(vl-load-com)
(defun c:sst (/ f of s ps1 i sn svn ct p1 p1b p2 p2b tx tt ltx tf)
(princ "\nSelect polylines by FENCE:")
(setq f (getfiled "\nEnter name File:" "" "csv" 1)
of (open f "w")
)
(setq osm (getvar 'osmode))
(setvar 'osmode 0)
(if
(setq s (ssget "_f"
(list (setq ps1 (getpoint "\nPick Point 1:"))
(getpoint "\nPick Point 2:" ps1)
)
'((0 . "lwpolyline"))
)
)
(progn
(setq i 0)
(repeat (sslength s)
(setq sn (ssname s i)
svn (vlax-ename->vla-object sn)
ct (vla-get-truecolor svn)
)
(setq p1 (cdr (assoc 10 (entget sn)))
p1b (list (car p1) (- (cadr p1) 250))
p2 (polar p1 0 5400)
p2b (list (car p2) (+ (cadr p2) 250))
)
(setq tx (ssget "_c" p1b p2b '((0 . "*text")))
tt (cdr (assoc 1 (entget (ssname tx 0))))
ltx (vl-string->list tt)
)
(setq i (1+ i))
(if (= (nth 0 ltx) 92)
(setq tf (substr tt 7))
(setq tf tt)
)
(write-line (strcat (col ct) ";" tf) of)
)
(close of)
)
)
(setvar 'osmode osm)
(princ)
)
(defun col (c)
(vl-string-right-trim
","
(apply 'strcat
(mapcar '(lambda (x) (strcat (itoa (vlax-get c x)) ","))
'(red green blue)
)
)
)
)
Carlos Calderon G
>Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
