Community
@Anonymous wrote:
....
Can some body let me know if there is a lisp program to draw lines, exactly dividing ( the user should be able to input the number of spaces he/she wants between the lines) the space between 2 polylines /lines ( Parallel or on parallel). ....
As a start, try first drawing Lines between the ends of the 2 you mean, and using Ladder.lsp, available here, to draw Lines as "rungs" across the new ones [using the Select option, and, when it asks for selection, selecting the Lines you drew across the ends of the ones you want divided between]. Yes, so far it draws, and accepts for selection, only Lines, but you get to say how many, and it works in 3D and across non-parallel Lines. If that looks like it's close to what you want, it would be easy enough to convert it to work from a selection of two Lines or Polyline line segments that you want the new ones splitting the distance between, and to draw Polylines if that's what you select.
[I assume you're talking about individual Polyline segments, not splitting the meandering space between multi-segment Polylines. If you want the latter, I think there are some routines that you can find by Searching with terms about intermediate contour lines. Such a routine might do exactly what you want already.]
Kent Cooper, AIA 
@john.uhden wrote:
....
Are you looking to create an exact "tweener?" ....
I think they want to do this -- selecting the red vertical lines that have cut-off arrows pointing to them at the ends [Polylines in their drawing, though I see no advantage to that over ordinary Lines] and having the routine draw in the yellow ones [which I did by drawing temporary horizontal Lines between the ends of the red ones, lying along the cyan perimeter, and using Ladder.lsp asking for four divisions]. @Anonymous, is this correct?
Kent Cooper, AIA
@Anonymous wrote:
.... we still need to figure out why it is not selecting the polylines( in the case of (LADDER) ....
Nothing to figure out there -- it was written specifically to work with Lines [that is, LINE entities specifically] only, because that was the situation for which it was requested. What looks like a "line" visually speaking is not always the same as a Line entity [I always capitalize entity types, so the difference between "line" and "Line" is meaningful in my Posts] in AutoCAD, and the difference matters. It will be easy enough to adjust the code to accept Polylines, as well as for the other things you mention -- I just have to get around to it, but I have it in mind [see your seasonal considerations...].
I would ask a question: Is there some reason that those red [in your sample drawing] "lines" are Polylines, rather than ordinary Lines? I don't see any advantage to doing them that way, but they use more memory than the equivalent Lines would. If they are going to be Polylines, can I assume that they will always and only be single-line-segment Polylines? It could make a difference to how a routine would work with them.
Kent Cooper, AIA
@Kent1Cooper wrote:
.... It will be easy enough to adjust the code to accept Polylines, as well as for the other things you mention -- I just have to get around to it....
Try this out [lightly tested]. Note that you can specify the points without having the Lines/Polylines already there, so in your sample drawing, you don't need those red section boundaries already in place -- this can draw them for you. But when they are already in place, you can choose the Existing-line-selection option.
;|
SplitBetween.lsp, to draw Lines between four selected points, or take
selection of two existing Lines or single-line-segment Polylines, and
draw subdividing Lines between and paralleling them or "splaying"
between them if not parallel. Works in 3D, and in any UCS.
If selecting existing lines, draws subdividing Lines on Layer of second
selected line; if picking four points, draws on current Layer.
Accounts for lines drawn in opposite directions, by reading second line
the other way; if lines are not co-planar, decides that on the basis of 2D
view in current Coordinate System.
Kent Cooper, 20 December 2016
|;
(defun C:SLB ; = Split Lines Between
(/ *error* var ev doc svnames svvals ptA1 ptA2 ptB1
ptB2 linA linB edata parts partno delta1 delta2 inc1 inc2)
(defun *error* (errmsg)
(if (wcmatch errmsg "Function cancelled,quit / exit abort,console break")
(princ (strcat "\nError: " errmsg))
); if
(mapcar 'setvar svnames svvals); reset
(vla-endundomark doc)
(princ)
); defun -- *error*
(defun var (ltr); build variable name
(read (strcat "lin" ltr))
); defun -- var
(defun ev (ltr); get contents of variable name
(eval (var ltr))
); defun -- ev
(vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
(setq ; System Variable saving/resetting without separate variables for each:
svnames '(osmode cmdecho blipmode clayer)
svvals (mapcar 'getvar svnames)
); setq
(mapcar 'setvar svnames '(0 0)); turn off Osnap, command echoing
(initget 1 "Existing")
(setq ptA1 (getpoint "First Line's start point [or select Existing lines]: "))
(if (listp ptA1); if User picked a point
(progn ; then
(initget 1)
(setq ptA2 (getpoint ptA1 "First Line's end point: "))
(initget 1)
(setq ptB1 (getpoint "Second Line's start point: "))
(initget 1)
(setq ptB2 (getpoint ptB1 "Second Line's end point: "))
(command "_.line" ptA1 ptA2 "")
(setq linA (entlast)); [will take points from it later in case in non-World UCS]
(command "_.line" ptB1 ptB2 "")
(setq linB (entlast))
); progn
(progn ; else [if User typed E]
(foreach ind '("A" "B")
(while
(not
(and
(set (var ind) (car (entsel (strcat "\nSelect line " ind ": ")))); linA or linB
(setq edata (entget (ev ind)))
(wcmatch (setq etype (cdr (assoc 0 edata))) "LINE,*POLYLINE")
(if (= etype "LINE") T (= (vlax-curve-getEndParam (ev ind)) 1)); single segment
(cond ; not arc segment
((= (cdr (assoc 100 (reverse edata))) "AcDb3dPolyline"))
((= etype "LWPOLYLINE") (= (cdr (assoc 42 edata)) 0.0))
((= etype "POLYLINE") (= (cdr (assoc 42 (entget (entnext (ev ind))))) 0.0))
(T) ; for Line
); if
); and
); not
(prompt "\nNothing selected, or not a Line or single-line-segment Polyline.")
); while
(redraw (ev ind) 3); highlight
); foreach
(setvar 'clayer (cdr (assoc 8 edata)))
); progn -- else
); if [pick point vs. select Existing lines]
(setq
ptA1 (vlax-curve-getStartPoint linA)
ptA2 (vlax-curve-getEndPoint linA)
ptB1 (vlax-curve-getStartPoint linB)
ptB2 (vlax-curve-getEndPoint linB)
); setq
(if
(inters ; if it would make 'butterfly' lines in 2D view,
(list (car ptA1) (cadr ptA1) 0)
(list (car ptB1) (cadr ptB1) 0)
(list (car ptA2) (cadr ptA2) 0)
(list (car ptB2) (cadr ptB2) 0)
); inters
(setq ptB1 ptB2 ptB2 (vlax-curve-getStartPoint linB)); reverse direction for line B
); if
(initget 7); no Enter, no zero, no negative
(setq
parts (getint "\nDivide intervening space into how many equal segments? ")
partno 1
delta1 (mapcar '- ptB1 ptA1)
delta2 (mapcar '- ptB2 ptA2)
inc1 (mapcar '/ delta1 (list parts parts parts))
inc2 (mapcar '/ delta2 (list parts parts parts))
); setq
(redraw linA 4) (redraw linB 4); un-highlight
(setvar 'blipmode 0)
(setq partno 1)
(while (< partno parts)
(command "_.line"
(trans (mapcar '+ ptA1 (mapcar '* inc1 (list partno partno partno))) 0 1)
(trans (mapcar '+ ptA2 (mapcar '* inc2 (list partno partno partno))) 0 1)
""
); command
(setq partno (1+ partno))
); while
(mapcar 'setvar svnames svvals); reset
(vla-endundomark doc)
(princ)
); defun
(prompt "Type SLB to Split Lines Between lines defined by 4 points or selected.")
Kent Cooper, AIA
@Anonymous wrote:
....
1. all the resulting lines are polylines, irrespective of the original lines - good in my kind of workflow. But in the case of Kent's Lisp (SplitBetween), all the resulting lines were 'Line' not 'Polyline'
I guess Kent assured in previous replies that it is not a big deal and he can fix it easily. If not I can select all the 'Lines' and convert it into a 'Polyline' either using a lisp or PEDIT > select MULTIPLE command or MPEDIT command.
....
Yes, it can easily be "fixed" if it's really worth it. The simple way would be to just add the 'p' into the command names: (command "_.pline" ... in three places.
But then you have to consider that there could sometimes be a current Polyline width other than 0 in effect, in which case those Polyline lines will all have that width, unless you also explicitly build the Width option into the Pline commands and force it to zero, or force it ahead of time with (setvar 'plinewid 0) somewhere before the first Pline command occurs. And then you have to decide whether, if there is a non-0 width set when you start, you would want it to remain in effect after you're done, for other purposes, and therefore need to save its current value and reset it, including in *error* handling.
But unless you want them to have width, I am having a hard time imagining what possible benefit there could be to their being Polylines instead of Lines, which is the main reason I built the code to make Lines. Can you describe what is "good in my kind of workflow" about their being Polylines instead?
Kent Cooper, AIA
@Anonymous wrote:
.... Converting the Line to Polyline is very minor and I can do it in one step ( using another lisp or MPEDIT). So it is not necessary to revise the code, after you explained the other factors to be considered if we are changing the resulting Lines to Polylines instead.
....
Don't bother with that extra step. You can deal with all of my concerns by adding the 'p' into the command names as described before, and doing this:
....
(setq ; System Variable saving/resetting without separate variables for each: svnames '(osmode cmdecho plinewid blipmode clayer) svvals (mapcar 'getvar svnames) ); setq (mapcar 'setvar svnames '(0 0 0)); turn off Osnap, command echoing, set Polyline width to 0 ....
That's one of the nice things about this list-based way of saving and resetting System Variables -- you can just add more into the list, in that one place, without adding any variables, or any additional saving or resetting functions.
Make sure you put it in the list as one of the first three variable names [it could be earlier in it than shown above], because those three 0's in the last code line above are going to set that value into the first three variables in the list -- it will stop mapping when either list ends. The other two variables are changed later [and 0 would be an invalid value for CLAYER anyway].
Kent Cooper, AIA
Forums Links
Can't find what you're looking for? Ask the community or share your knowledge.
Post to forums
