LISP TO CHANGE VERTICAL ALIGNMENT TO HORIZONTAL ALIGNMENT
Impossible, you or better a program need some objects as reference.. and i can not see such an objects.
For example: For each object heap (i am not sure if you can understand this how i mean that, lol), one closed polyline.
And YES, many users in the world use a program that can do that.
If each set of objects were a Block, I could come up with something, with a fairly simple modification of BlockChart.lsp [see >here< -- it's about Inserting drawings from a folder, but could be adjusted easily enough for selected Blocks]. But with all of the sets made up of individual pieces, it's hard to imagine how a routine could figure out which ones belong in each set, i.e. which to Move together.
Kent Cooper, AIA 
@Anonymous wrote:
.... if each heap of object is enclosed with rectangle....
Is the idea that you would go around and draw that rectangle around each set of objects, and then select all the rectangles for the relocating? Would it place them horizontally in the same sequence as the vertical sequence, even if the drawing order of the rectangles did not match that? And then would you want to Erase all the rectangles?
If so, how about if a routine were to just ask you to select each set [by whatever means you choose], and [the one thing that would require a little bit more care on the part of the User] to select the sets in the order you want them to have in the horizontal arrangement? It's possible to find the effective overall bounding box of a set of objects, and it could use those for positioning each set with a gap from the previous one. Then there would be no need to draw, nor to Erase, the rectangles. And if you had reason to, it would be easy to have the horizontal sequence vary from the vertical sequence. And the original objects wouldn't need to be in anything like a vertical sequence -- they could be scatter-shot all over the place.
Kent Cooper, AIA
@Kent1Cooper wrote:
.... how about if a routine were to just ask you to select each set ..., and ... to select the sets in the order you want them to have in the horizontal arrangement? .... no need to draw, nor to Erase, the rectangles. ....
Like this [very lightly tested]:
;| SetsInRow.lsp [command name: SIR]
To position any number of User-selected sets of objects in a horizontal row,
spaced apart by a User-specified gap size.
Places first set with the bottom of its overall extents aligned with the bottom
of the drawing's overall extents, and its left side to the right of the drawing's
overall right side by the gap size. Successive sets are placed to the right of
what comes before, aligned at the bottom.
Zooms to Extents initially, but User can Pan and/or Zoom around in process
without affecting results.
Remembers gap size and offers as default on subsequent use.
Kent Cooper, 25 September 2018
|;
(defun C:SIR (/ LR ss n eLL eUR sLL sUR swid); = Sets In Row
(command "_.zoom" "_extents"); make all visible, reset EXTMIN/EXTMAX
(initget (if *SIRgap 6 7)); no zero, no negative, no Enter on first use
(setq
LR (list (car (getvar 'extmax)) (cadr (getvar 'extmin)))
*SIRgap
(cond
( (getdist
(strcat
"\nGap size between sets"
(if *SIRgap (strcat " <" (rtos *SIRgap) ">") "")
": "
); strcat
); getdist
); User-input condition
(*SIRgap); prior value on Enter when permitted
); cond & *SIRgap
); setq
(while (setq ss (ssget "_:L"))
(setq sLL nil sUR nil)
(repeat (setq n (sslength ss))
(vla-getboundingbox (vlax-ename->vla-object (ssname ss (setq n (1- n)))) 'minpt 'maxpt)
(setq
eLL (vlax-safearray->list minpt); entity's Lower Left
eUR (vlax-safearray->list maxpt)
sLL (if sLL (mapcar 'min eLL sLL) eLL); set's Lower Left
sUR (if sUR (mapcar 'max eUR sUR) eUR)
swid (- (car sUR) (car sLL)); set's width
); setq
); repeat
(command "_.move" ss "" "_none" sLL "_none" (polar LR 0 *SIRgap))
(setq LR (polar LR 0 (+ swid *SIRgap)))
); while
(princ)
); defun
(vl-load-com)
(prompt "\nType SIR to put Sets In a Row.")
Kent Cooper, AIA
@dbhunia wrote:
....
2. In LISP the Input of "Offset Distance" has considered in "mm" (because internally AutoCAD calculate everything in "mm"), so if you want to get Input of "Offset Distance" in "Feet-Inch" then you make the necessary changes in LISP.
AutoCAD does not calculate everything in millimeters. It calculates everything in drawing units, and the drawing unit can be whatever you want it to be. Change your Offset Distance to use (getdist) instead of going to the trouble of converting a text string into a number, it will return it in whatever your drawing units are. That is, change this:
(setq Off_Dist (atof (getstring "\nSpecify Offset Distance (In mm) : ")))
to something like this:
(setq Off_Dist (getdist "\nSpecify Offset Distance: "))
Another advantage of using (getdist) is that if you're in feet-&-inches units, you can type in the distance in that kind of format, i.e. something like 12'6 or 9-1/2, and it will return 150.0 or 9.5 drawing units, whereas (atof) applied to those as text strings would give the wrong result. And another advantage is that you can specify the distance by picking two points on-screen, if you prefer that over typing in a value.
Kent Cooper, AIA
Accepted solution
@Kent1Cooper wrote:
@dbhunia wrote:....
2. In LISP the Input of "Offset Distance" has considered in "mm" (because internally AutoCAD calculate everything in "mm"), so if you want to get Input of "Offset Distance" in "Feet-Inch" then you make the necessary changes in LISP.
AutoCAD does not calculate everything in millimeters. It calculates everything in drawing units, and the drawing unit can be whatever you want it to be.
Dear Kent,
If internally AutoCAD does not calculate every thing in millimeters, then why the extracted properties gives all values in millimeters all time even the "Drawing Units" are set in "Architectural"?
Dear Karat,
I am attaching modified lisp go through with this one...
with this LISP-
1. No need to follow Bounding rectangles draw order i.e. from "Left Bottom corner" to "Right Top corner" in the Drawing.
2. There is no boundation in Input of "Offset Distance" unit.
Only advise -
1. To keep All Bounding rectangles in a single Layer.
@dbhunia wrote
They're not millimeters just because they don't show feet-and-inches marks. They're just real numbers, representing drawing units. In Architectural format, a drawing unit is an inch. If you draw a Line whose start point is at an X coordinate of 3'-6" and a Y coordinate of 2'-1 1/2" [at an elevation of 0], its entity data list will include its start point as (10 42.0 25.5 0.0), which represent the number of inches of those values, expressed in a "raw" real number without feet-and-inches markings, but they are still in inches. If it were storing things in millimeters, it would say something like (10 1066.8 647.4 0.0) instead.
[By the way, the values in your entity data list image show that you're working a very long way from the drawing origin -- the X coordinate of the first Circle's center is about 4-2/3 miles away. Just be aware that certain problems can sometimes result from working that far from the origin.]
Kent Cooper, AIA