Lisp to Change Color of all layers a little lighter

[Anonymous]

Mornin' all!!!

I'm looking for a lisp that will change all my layer colors by 1, basically change the shade of every layer a little lighter.

Any assistance would be grand!

[Edwin.Saez]

here!

https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/a-lisp-to-make-all-entities-color-qu...

[Anonymous]

this lisp changed all entities to the same color, i'm looking tfor each entity to go one shade lighter or one number lighter than the existing color ie.. 132 to 131. id like the layer to change not the entity also

[Ranjit_Singh]

Try below. This changes all the layers by dropping one unit from R,G and B colors.

;:Ranjit Singh
;;8/16/17
(defun c:somefunc  (/ colobj)
 (setq colobj (vla-getinterfaceobject (vlax-get-acad-object)
                                      (strcat "autocad.accmcolor." (itoa (atoi (getvar 'acadver))))))
 (vlax-for lay  (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
  (apply 'vla-setrgb
         (cons colobj
               (mapcar '(lambda (x)
                         (if (zerop x)
                          x
                          (1- x)))
                       (mapcar '(lambda (x) (vlax-get (vla-get-truecolor lay) x)) '(red green blue)))))
  (vla-put-truecolor lay colobj)))

[Anonymous]

is here any way i can just change the ACI color up or down 1

[Ranjit_Singh · Accepted solution]

Maybe like this

;;Ranjit Singh
;; 8/16/17
(defun c:somefunc  (/ latcol newind)
 (vlax-for lay  (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
  (setq latcol (vla-get-truecolor lay))
  (if (= 195 (vla-get-colormethod latcol))
   (vl-catch-all-apply 'vla-put-color
                       (list lay
                             (if (zerop (setq newind (1- (vla-get-colorindex latcol))))
                              0
                              newind))))))

[Anonymous]

Thank you so much this is perfect!!!! Have a grand day!