Lisp routine to delete 5 blocks (block1name, block2name, block3name, block4name, block5name) from 100 drawings

[frank.cortesWRCXM]

Hi lisp experts, 

I am lisp beginner. and I am looking for a Lisp routine to delete 5 blocks (block1name, block2name, block3name, block4name, block5name) from 100 drawings. 

Can you give me some advice?

Thank you

[pendean]

Like this ask over here perhaps (add and change block names where needed) https://forums.autodesk.com/t5/autocad-architecture/lisp-to-delete-all-blocks-of-various-name/td-p/7...
or this
https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/delete-specific-block/m-p/3780386#M3...

And for when you need a menu to select from http://lee-mac.com/deleteblocks.html

[paullimapa]

And run on multiple dwgs

https://www.cadig.com/products/autocad-script-pro.php

https://www.cad-notes.com/run-a-script-on-multiple-dwg-with-scriptpro/

[frank.cortesWRCXM]

Thank for your response. I have tried those lisp already and they do not work if the blocks are in the layout.

I got this message

If I run the lisp routine in paper space they remove the blocks , but I want to get a lisp to remove the list of blocks with no workspace restrictions (from model space or papers pace). any advice?

[paullimapa]

(setq ss (ssget '((0 . "Insert") (2 . "Block1,block2,block3,block4,block5"))) i 0)


(repeat (sslength ss)
 (entdel (ssname ss i))
)

[komondormrex]

hi,

what do you mean exactly? delete block definitions of afore mentioned blocks and and theirs references or just references of those blocks?

[frank.cortesWRCXM]

Hi

 I need to remove those blocks and their definitions.

Thanks 

[ronjonp]

@frank.cortesWRCXM Give this a try:

(defun c:foo (/ a d)
  (vlax-for l (vla-get-layers (setq d (vla-get-activedocument (vlax-get-acad-object))))
    (cond ((= -1 (vlax-get l 'lock)) (vlax-put l 'lock 0) (setq a (cons l a))))
  )
  (vlax-for b (vla-get-blocks d)
    (if	(= 0 (vlax-get b 'isxref))
      (vlax-for	o b
	(cond ((vlax-write-enabled-p o)
	       (cond ((and (wcmatch (vla-get-objectname o) "AcDbBlockReference")
			   (wcmatch (strcase (vla-get-name o)) "BLOCK1,BLOCK2,BLOCK3,BLOCK4,BLOCK5")
		      )
		      (vl-catch-all-apply 'vla-delete (list o))
		     )
	       )
	      )
	)
      )
    )
  )
  ;; Relock layers
  (foreach l a (vlax-put l 'lock -1))
  ;; Regen to see changes
  (vla-regen d acallviewports)
  ;; Purge
  (repeat 2 (vla-purgeall d))
  (princ)
)

[paullimapa]

and to remove the definitions after the blocks have been deleted use this :

(command"_.Purge""_B""BlockName1,BlockName2,BlockName3,BlockName4,BlockName5""_N")

[frank.cortesWRCXM]

hi @ronjonp ,

Thank you so much for your help. The lisp works well (blocks located in Model or layout). Maybe because the blocks I want to remove are part of an Xref (my title block key map)? when I run the script, it does not do anything. can you help me with it?

Regards,

[ronjonp]

@frank.cortesWRCXM 

If the blocks are nested within an xref they can not be directly erased. You'd need to open your titleblocks and remove the keymaps there.

[paullimapa]

Maybe use Odbx method to open xref grab the blocks and vla-delete 

[frank.cortesWRCXM]

Thank you all for your help. We do not want to open those files..You know that process involves a huge amount of time.

The Lee Mac delete blocks script works perfect as well and  remove them but the idea is not having to select the blocks.

[ronjonp]

@frank.cortesWRCXM ODBX does not take a huge amount of time and with the code provided you don't have to manually select the blocks?

[marko_ribar]

@ronjonp 

Something is wrong on my side while checking with ODBX... I used your function and feeded it to (LM:ODBX 'foo nil t) like you see in *.lsp I attached at the end... I created Block1,Block2,Block3,Block4,Block5,Block6,Block7,Block8,Block9,Block10 in each DWG - DWG copies... It doesn't matter I used BricsCAD for drawing, just ignore pop up when opening from ACAD...

Error is something like too few/ too many arguments during eval...

Can you see where is the problem - I saw that your function satisfies restrictions for ODBX...

[ronjonp]

@marko_ribar Untested but I think you need to change this:

(defun foo (/ a d)
  (vl-load-com)
  (vlax-for l (vla-get-layers (setq d (vla-get-activedocument (vlax-get-acad-object))))
    (cond ((= -1 (vlax-get l 'lock)) (vlax-put l 'lock 0) (setq a (cons l a))))
  )

To this so its argument is the ODBX doc not active.

(defun foo (d / a)
  (vl-load-com)
  (vlax-for l (vla-get-layers d)
    (cond ((= -1 (vlax-get l 'lock)) (vlax-put l 'lock 0) (setq a (cons l a))))
  )

Lee has quite a few examples HERE.

[marko_ribar]

Thanks Ron, it worked on my end...

Cheers...

[ronjonp]

---

@marko_ribar wrote:

Thanks Ron, it worked on my end...

Cheers...

---

Cheers!