LISP routine for duplicating multiple layers at once

[edrewsSBTV9]

I am looking for a LISP routine that takes all layers in a drawing and duplicates them, while adding a suffix to the layer name.

For example, start with the following layers:

LayerA

LayerB

LayerC

End up with duplicated layers, adding the suffix "- Car":

LayerA

LayerA - Car

LayerB

LayerB - Car

LayerC 

LayerC - Car

[devitg]

Hi   @edrewsSBTV9 For better understanding, and maybe get further help, please upload such sample.dwg

[Kent1Cooper · Accepted solution]

Try this:

(defun C:LDNS ; = Layer Duplicate with Name Suffix [" - Car" built in]
  (/ lay laylist ldata lname)
  (while (setq lay (tblnext "layer" (not lay)))
    (setq lname (cdr (assoc 2 lay)))
    (if (not (wcmatch lname "0,Defpoints"))
      (setq laylist (cons lname laylist)); put in list of names
    ); if
  ); while
  (foreach lname laylist
    (setq ldata (entget (tblobjname "layer" lname)))
    (entmake (subst (cons 2 (strcat lname " - Car")) (assoc 2 ldata) ldata))
  ); foreach
  (princ)
); defun

All the duplicated Layers get the color, linetype, etc. of the source Layers.  If that's not what you want, it could be made to do it in some different way.

It could be made to ask for the suffix, instead of having it built in.

I assumed you would not want to duplicate "0" or "Defpoints", but they could be included.

[ronjonp]

@Kent1Cooper  FWIW I'd also exclude xref layers ( not that entmake is going to error on it ) as well as layers that already have the suffix in the event the user runs the code more than once. Without it you'd have a bunch of stuttering -car -car -car layers. 🍻

(wcmatch lname "0,Defpoints,*|*,* - Car")

[Kent1Cooper]

---

@ronjonp wrote:

....

(wcmatch lname "0,Defpoints,*|*,* - Car")

---

Yes, good idea.

[edrewsSBTV9]

Thank you!

[edrewsSBTV9]

That works, Thank you!

[bguyB9HE7]

Hello! This is an amazing lsp. Is there a way to do it for layers that are selected instead of all? Tried to see if I could edit it myself but was unsuccessful.

Thank you!

Brandon

[Kent1Cooper]

---

@bguyB9HE7 wrote:

... for layers that are selected instead of all? ....

---

Try this:

(defun C:LDNS ; = Layer Duplicate with Name Suffix [" - Car" built in]
  (/ lay laylist ldata lname)
  (prompt "\nTo duplicate Layer(s) of selected object(s) with suffix added to name(s),")
  (if (setq ss (ssget "_:L"))
    (progn ; then
      (repeat (setq n (sslength ss))
        (setq lname (cdr (assoc 8 (entget (ssname ss (setq n (1- n)))))))
        (if
          (and
            (not (member lname laylist)); not already in list
            (not (wcmatch lname "* - Car")); doesn't already have suffix
          ); and
          (setq laylist (cons lname laylist)); then -- put in list of names
        ); if
      ); repeat
      (foreach lname laylist
        (setq ldata (entget (tblobjname "layer" lname)))
        (entmake (subst (cons 2 (strcat lname " - Car")) (assoc 2 ldata) ldata))
      ); foreach
    ); progn
  ); if
  (princ)
); defun

I assume you will similarly replace the suffix with your own,  It could also be made to ask for that each time, rather than have it built in.

[Sea-Haven]

Lee-mac has a double List box function so you could have all your layers in the left side and select which ones you need to change, building a list of layer names in right side. Needs to have the add suffix part added, ran out of time.

[bguyB9HE7]

Wow thank you so much for the help and replying!! Will give this one a go.