[LISP] Replace an item

[iBlachu]

Hi,

How to replace 1 with 7 in the list below with sublists?

(setq A
(list
(list 0 0 0)
(list 0 1 0)
(list 0 0 0)
)
)

[hak_vz]

Is this a matrix representation or just a sample?

Here you have some helper functions

(defun plusp (num) (cond ((numberp num) (>= num 0.0))))

;Sets n-th element of a list to new value
;(set_nth '(1 2 3 4) 2 5) -> (1 2 5 4)
(defun set_nth (lst n value)
  (cond 
    ((and (plusp n) (<= n (length lst)))
      (cond
       ((zerop n)
         (cons value (cdr lst))
        )
        (t (cons (car lst) (set_nth  (cdr lst) (1- n) value)))
      )
    )
  )
)
(defun set_m_n (mat m n val / row el)
  (setq 
    row (nth m mat)
    row (set_nth row n val)
    mat (set_nth mat m row)
  )
)

Command: (setq A '((0 0 0)(0 1 0)(0 0 0)))
((0 0 0) (0 1 0) (0 0 0))
Command: (setq A (set_m_n A 1 1 7))
((0 0 0) (0 7 0) (0 0 0))

Elements are counted as (row, column) starting from 0. You can  change only existing rows and columns.

[ВeekeeCZ]

How would identify that it's 1 to be replaced? By its position? Or by its value? Or both?

[iBlachu]

I wanted to simplify the example. It is not a matrix, it can be any list with different elements, even text elements.

I need to replace eg 2 element in 8 sublist with eg "NEW".

[hak_vz]

You can use this code to make changes to i-j element of a list with what ever data type

Command: (setq a (set_m_n A 1 1 (list 2222 3333)))
((0 0 0) (0 (2222 3333) 0) (0 0 0))
Command: (setq a (set_m_n A 1 1 "Some text"))
((0 0 0) (0 "Some text" 0) (0 0 0))

If you need to change whole i-th sublist you can use function set_nth

[ВeekeeCZ]

---

@iBlachu wrote:

I need to replace eg 2 element in 8 sublist with eg "NEW".

---

What do you mean by that.... like changing 2nd item in 8th line of list?

Make an example...

[iBlachu]

(setq A
(list
(list 0 0 0);0
(list 0 0 0);1
(list 0 0 0);2
(list 0 0 0);3
(list 0 0 0);4
(list 0 0 0);5
(list 0 0 0);6
(list 0 0 0);7
(list 0 0 0);8
(list 0 0 0);9
(list 0 0 0);10
)
)

(setq A
(list
(list 0 0 0);0
(list 0 0 0);1
(list 0 0 0);2
(list 0 0 0);3
(list 0 0 0);4
(list 0 0 0);5
(list 0 0 0);6
(list 0 0 0);7
(list 0 0 "NEW");8
(list 0 0 0);9
(list 0 0 0);10
)
)

[hak_vz · Accepted solution]

(setq a (set_m_n A 8 2 "NEW")) 

Is this so complicated?

(set_m_n A row col val)

[hak_vz]

Here is my code used for matrix calculus, and you can find there how used this two functions for different algorithms

[calderg1000 · Accepted solution]

Regards @iBlachu 

Here you have two examples to do it

(setq A
(list
(list 0 0 0)
(list 0 1 0)
(list 0 0 0)
)
)
;First form
(setq a(subst '(0 7 0) (cadr a) a))
;Second way
(subst (subst 7 (nth 1 (cadr a)) (cadr a)) (nth 1 a) a)

[ВeekeeCZ]

One more func - with unlimited list depth. 

;; list - list of positions from top to sub, 0 idx as first '(0 1 1) to get '((0 (0 "target"))) - new item
(defun lth-rep (lst lev new)
  (mapcar '(lambda (itm) (if (= (car lev) (vl-position itm lst))
			   (if (and (cdr lev) (listp itm))
			     (lth-rep itm (cdr lev) new)
			     new)
			   itm))
	  lst))

Example for your case: (lth-rep A '(7 2) "new")

Or if you prefer 1 based indexing:

;; list - list of positions from top to sub, 1 idx as first '(1 2 2) to get '((0 (0 "target"))) - new item
(defun lth-rep1 (lst lev new)
  (mapcar '(lambda (itm) (if (= (car lev) (1+ (vl-position itm lst)))
			   (if (and (cdr lev) (listp itm))
			     (lth-rep1 itm (cdr lev) new)
			     new)
			   itm))
	  lst))

(lth-rep1 A '(8 3) "new")