lisp or defun command for changing color of selected object
@vandenoosterkamp wrote:
I'd like to be able to slect an object, [then] type q1 for changing the color ....
.... when typing it all out in commandline after selecting ....
Those command definitions in Messages 2 & 5 require you to invoke the command before selecting. But you can have it accept pre-selection of objects, i.e. you can invoke the command after selecting [or before, as desired].
(defun C:Q1 ()
(command "_.chprop"
(cond
((ssget "_:L-I")); pre-selection
((ssget "_:L")); prompt to select
); cond
"" "_color" 1 ""
); command
(prin1)
)If you already have anything pre-selected when you call the command, it will just go ahead and change the color [except of anything among the selection on locked Layers, since pre-selection might include locked things], the same as with other editing commands that accept pre-selection. If you don't have anything selected, it will ask you to select, and then change the color [again, as with other editing commands]. No variable is needed to hold the selection.
And similarly with the ByLayer reset version, though the SETBYLAYER command can do that for you [you could have a QS command that basically just calls SETBYLAYER with SETBYLAYERMODE setting and prompt responses built in].
Come to think of it, a function that takes an argument, with command names defined to call that function and supply the argument, will save a lot of code duplication, especially if you need a large number of different colors.
(defun QC (col); function with argument
(command "_.chprop"
(cond
((ssget "_:L-I")); pre-selection
((ssget "_:L")); prompt to select
); cond
"" "_color" col ""
); command
(prin1)
)
(defun C:Q1 () (QC 1)) ; red
(defun C:Q2 () (QC 2)) ; yellow
(defun C:QS () (QC "Bylayer"))That just contains commands for red, yellow and ByLayer, but make as many commands as you want. The "working" code is needed only once.
Put that into a file called, for example, ColorChanger.lsp, and an (autoload) function in something like acaddoc.lsp can make all the commands available in any drawing, without actually loading the file until one of them is called for:
(autoload "ColorChanger" '("Q1" "Q2" "QS"))
@paullimapa wrote:
Curious, with pickfirst set to 1, I don't need to use:
(ssget "_:L-I")This works just fine:
(ssget "_:L")
That is curious. The I is for Implied selection [i.e. whether there is/are any pre-selected object(s)], so it would not have occurred to me to not check for that [the first condition in the (cond) function].
But sure enough, it's not necessary [if PICKFIRST = 1] to evaluate whether or not anything is pre-selected. So your version would not prompt for selection every time, as I assumed. But that also means no selection set variable is required, and this is all that's needed [lightly tested]:
(defun C:Q1 ()
(command "_.chprop" (ssget "_:L") "" "_color" 1 "")
(prin1)
)
