lisp mirror mutiple text around the center of self.

[mik501_]

HI . i need mirror mutiple text around the center of self  Use the center of each text.With just one mirror .  Is it possible? 

Thank you so much

[EnM4st3r · Accepted solution]

you could use txt2mtxt -> set align to middle left -> set rotation to 0.
With this the text wouldnt be exactly on the same position but also not too far off.

[mik501_]

Thank you so much for solution

[komondormrex]

hey,

with lisp

(defun c:mirror_text_height (/ text_bb point_1)
	(foreach text (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget '((0 . "text"))))))
		(setq text_bb (acet-geom-textbox (entget text) 0))
		(vla-mirror (vlax-ename->vla-object text) 
					(vlax-3d-point (setq point_1 (mapcar '- (car text_bb) 
															(mapcar '* '(0.5 0.5) 
																		(mapcar '- (car text_bb) (caddr text_bb))
															)
												 )
									)
					)
					(vlax-3d-point (polar point_1 (angle (car text_bb) (cadr text_bb)) 1))  
		)
		(entdel text)
	)
	(princ)
)

[mik501_]

sorry  code error: no function definition: ACET-GEOM-TEXTBOX

[komondormrex]

that one is from express tools(

[mik501_]

Thank you very much. Does that mean it is not available on autocad lt 

[komondormrex]

i think so

[komondormrex · Accepted solution]

but here goes another one, which i think should be working in 23lt.

(defun c:mirror_text_height (/ text_bb point_1 point_2 insertion_point)
	(foreach text (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget '((0 . "text"))))))
		(setq text_bb (textbox (entget text))
			  point_1 (mapcar '+ (setq insertion_point (cdr (assoc 10 (entget text)))) 
								 (mapcar '* '(0.5 0.5) (mapcar '- (cadr text_bb) (car text_bb)))
					  )
			  point_1 (polar insertion_point 
			  			     (+ (angle insertion_point point_1) (cdr (assoc 50 (entget text))))
							 (distance insertion_point point_1)
					  )
			  point_2 (polar point_1 (cdr (assoc 50 (entget text))) 1) 
		)
		(vla-mirror (vlax-ename->vla-object text)
					(vlax-3d-point point_1)
					(vlax-3d-point point_2)  
		)
		(entdel text)
	)
	(princ)
)

[mik501_]

I’m so grateful for your help.