Lisp error rejected

[kidznok]

Hi
I try with lisp to reset scale list when someone will save file.
I found sth like this

(defun AtSaveCommand (calling-reactor b)
(if
(or
(= (car b) "QSAVE")
(= (car b) "SAVEAS")
(= (car b) "SAVE")
)
(command "-SCALELISTEDIT" "R" "Y" "E")
)
)

(defun loadTheSaveReactor ()
(vl-load-com)
(if *FileOnSave* (vlr-remove *FileOnSave*))
(setq *FileOnSave*
(vlr-command-reactor nil '((:vlr-commandwillStart . AtSaveCommand)))
)
)
(loadTheSaveReactor)

And i have "error no function definition:scalelistedit"

Could someone help me?

[hak_vz · Accepted solution]

Replace command function with vl-cmdf and it should work.

(defun AtSaveCommand (calling-reactor b)
(if
(or
(= (car b) "QSAVE")
(= (car b) "SAVEAS")
(= (car b) "SAVE")
)
(vl-cmdf  "-SCALELISTEDIT" "R" "Y" "E")
)
)

(defun loadTheSaveReactor ()
(vl-load-com)
(if *FileOnSave* (vlr-remove *FileOnSave*))
(setq *FileOnSave*
(vlr-command-reactor nil '((:vlr-commandwillStart . AtSaveCommand)))
)
)
(loadTheSaveReactor)

[kidznok]

Thank you.
Error is gone.
But... when I use qsave or save reset scale is not working.
File is save but I have the same scale list.

When I use save I would like to reset scale and then save my file.

[Moshe-A]

@kidznok  hi,

this will not work cause as far as i know, you can not call (command) function from callback [and that's includes (vl-cmdf) ]

the way to approach this is access the scalelist dictionary data and delete the unwanted scales.

(dictsearch (nameobjdict) "ACAD_SCALELIST")

then dig-in 

note that you can not delete scales that are used (the same as layers, linetypes, textstyles)

Moshe

[kidznok]

Like this?

(defun AtSaveCommand (calling-reactor b)
(if
(or
(= (car b) "_QSAVE")
(= (car b) "SAVEAS")
(= (car b) "_SAVE")
)
(dictsearch (nameobjdict) "ACAD_SCALELIST")
)
)

(defun loadTheSaveReactor ()
(vl-load-com)
(if *FileOnSave* (vlr-remove *FileOnSave*))
(setq *FileOnSave*
(vlr-command-reactor nil '((:vlr-commandwillStart . AtSaveCommand)))
)
)
(loadTheSaveReactor)

Cause it's not working. Sorry, I'm not good in autolisp.

[ronjonp · Accepted solution]

@kidznok 

FWIW

;; This
(defun atsavecommand (calling-reactor b)
  (if (or (= (car b) "QSAVE") (= (car b) "SAVEAS") (= (car b) "SAVE"))
    (vl-cmdf "-SCALELISTEDIT" "R" "Y" "E")
  )
)
;; Could be shortened to this
(defun atsavecommand (calling-reactor b)
  (if (wcmatch (car b) "QSAVE,SAVEAS,SAVE")
    (vl-cmdf "-SCALELISTEDIT" "R" "Y" "E")
  )
)
;; Or this
(defun atsavecommand (calling-reactor b)
  (if (wcmatch (car b) "*SAVE*")
    (vl-cmdf "-SCALELISTEDIT" "R" "Y" "E")
  )
)

[kidznok]

I try and unfortunately it not work at my dwg 😕
But thank you.

[Moshe-A]

@kidznok ,

give this a go 🤣

This is auto delete scales according "measurement" sysvar. if it's 0 - imperial, all metric scale is vanish

if it's 1 - metric, all imperial scale is vanish.

enjoy

Moshe

(vl-load-com)

(defun AtSaveCommand (calling-reactor cmd^ /  ResetScaleList ;| local function |;)

 (defun ResetScaleList (measurement / AcDbScale elist)
  (vlax-for AcDbScale (vla-item (vla-get-dictionaries (vla-get-activedocument (vlax-get-acad-object))) "ACAD_SCALELIST")
   (setq elist (entget (vlax-vla-object->ename AcDbScale)))
    
   (cond
    ((= measurement 0) ; imperial
     (if (member (cdr (assoc '300 elist)) rdata^)
      (vl-catch-all-apply 'vla-delete (list AcDbScale))
     )
    ); case
    ((= measurement 1); metric
     (if (not (member (cdr (assoc '300 elist)) rdata^))
      (vl-catch-all-apply 'vla-delete (list AcDbScale))
     )
    ); case
   ); cond

   (vlax-release-object AcDbScale) 
  ); vlax-for
 ); resetScaleList

   
 (if (wcmatch (car cmd^) "QSAVE,SAVEAS,SAVE")
  (ResetScaleList (getvar "measurement")) ; 0 - imperial, 1 - metric
 )
); AtSaveCommand


(defun loadTheSaveReactor ()
 (setq rdata^ '("1:1" "1:2" "1:4" "1:5" "1:8" "1:10" "1:16" "1:20" "1:30" "1:40" "1:50" "1:100" "2:1" "4:1" "8:1" "10:1" "100:1"))  ; metric scales  
  
 (if (not *FileOnSave*)
  (setq *FileOnSave* (vlr-command-reactor nil '((:vlr-commandwillStart . AtSaveCommand))))
 )
)

(loadTheSaveReactor)

[Sea-Haven]

A possible alternative is the 2 VLR functions, rather than check every command, :vlr-commandwillStart

:VLR-beginSave
:VLR-beginClose

[Moshe-A]

@kidznok ,

a shorter version, use this one 🤣

Moshe

(vl-load-com)

(defun AtSaveCommand (calling-reactor cmd^ / AcDbScale elist)
 (if (wcmatch (car cmd^) "QSAVE,SAVEAS,SAVE")
  (vlax-for AcDbScale (vla-item (vla-get-dictionaries (vla-get-activedocument (vlax-get-acad-object))) "ACAD_SCALELIST")
   (setq elist (entget (vlax-vla-object->ename AcDbScale)))
     
   (cond
    ((= (getvar "measurement") 0) ; imperial
     (if (member (cdr (assoc '300 elist)) (vlr-data calling-reactor))
      (vl-catch-all-apply 'vla-delete (list AcDbScale))
     )
    ); case
    ((= (getvar "measurement") 1); metric
     (if (not (member (cdr (assoc '300 elist)) (vlr-data calling-reactor)))
      (vl-catch-all-apply 'vla-delete (list AcDbScale))
     )
    ); case
   ); cond

   (vlax-release-object AcDbScale) 
  ); vlax-for
 ); if
); AtSaveCommand


(defun loadTheSaveReactor ()
 (if (not *FileOnSave*)
  (setq *FileOnSave* (vlr-command-reactor
		       '("1:1" "1:2" "1:4" "1:5" "1:8" "1:10" "1:16" "1:20" "1:30" "1:40" "1:50" "1:100" "2:1" "4:1" "8:1" "10:1" "100:1") ; vlr-data, metric scales  
		       '((:vlr-commandwillStart . AtSaveCommand))
		     )
  ); setq
 ); if
); loadTheSaveReactor 

(loadTheSaveReactor)

[Moshe-A]

@kidznok hi,

does it work?

[kidznok]

No, unfortunately no.
I created aitostart lisp to reset scale so when I open file it's running.
It's a second way for me.

[Moshe-A]

i use r2022 and it works perfect for me and i am sure you are missing something.

[Moshe-A]

maybe post your dwg and specify the scalelist names you want to delete

[kidznok]

Hi, i would like to reset scale, just delete scales from xrefs in BricsCad.

[kidznok]

It works when I use ctrl+S but not when I use button.
Save as not work too. Is it chance to add reset scale to _close? 
I will click X button then it reset scale, next close and ask to save.
I'm just wondering.

[Moshe-A]

@kidznok  hi,

(if
(or
(= (car b) "QSAVE")
(= (car b) "SAVEAS")
(= (car b) "SAVE")
)

When you run this code to monitor these commands you can not expect AutoCAD to monitor other commands.

picking the X buttom should invokes the close command but on my experience long time ago it won't 😂

instead vlr-command-reactor you should move to:

vlr-dwg-reactor \ vlr-editor-reactor

using these events

vlr-beginClose \ vlr-beginSave  (as @Sea-Haven  recommended)

Moshe