linking current dimstyle text size to mtext size
@kenhuse wrote:
I have a lisp routine that draws an arc curved leader.
I have added an mtext command at the end.
To start with I would like to have the mtext size match that of the current dimstyle text size.
I should add that within my style dialog box the text size is currently set to 0.00.
Thanks for your help.
Hello kenhuse and welcome to the Autodesk Community!
Please post your code, It will be easier to advise...
Henrique
@kenhuse wrote:
Hi Henrique,
I have another issue. Our esteemed organization has a policy of exploding dimensions. In order to find the dimstyle I need to make current, I select a bit of text and look to see it's height. I then go to the dimstyle dialog box to select the proper dimstyle.
Do you suppose I could put together a lisp routine that would make current the proper dimstyle after having selected a piece of text?
This would make for a more efficient work session as it is something I commonly have to do.
Thanks Henrique for any help you can provide, Ken
Hi Ken,
I will not comment on the 'Our esteemed organization has a policy of exploding dimensions.'
Quick and dirty...
(defun c:demo (/ dimstyles dimsty ht lst styl txt)
(defun dimstyles (/ dimstyle-lst dimstyle-name dimstyle-text-font dimstyle-text-height dimstyle-text-style lst)
(while (setq dimstyle-lst (tblnext "dimstyle" (null dimstyle-lst)))
(setq dimstyle-name
(cdr (assoc 2 dimstyle-lst))
dimstyle-text-height
(cdr (assoc 140 dimstyle-lst))
dimstyle-text-style
(entget (cdr (assoc 340 dimstyle-lst)))
dimstyle-text-font
(cdr (assoc 3 dimstyle-text-style))
lst (cons (list dimstyle-name dimstyle-text-font dimstyle-text-height) lst)
)
)
lst
)
(if (and (setq lst (dimstyles))
(setq sel (car (entsel "\nSelect dimension text:")))
(setq txt (entget sel))
(wcmatch (cdr (assoc 0 txt)) "TEXT,MTEXT")
(setq styl (cdr (assoc 3 (entget (tblobjname "style" (cdr (assoc 7 txt)))))))
(setq ht (cdr (assoc 40 txt)))
(vl-some '(lambda (x)
(if (and (eq styl (nth 1 x)) (eq ht (nth 2 x)))
(setq dimsty (nth 0 x))
)
)
lst
)
)
(progn
(or adoc (setq adoc (vla-get-ActiveDocument (vlax-get-Acad-Object))))
(vla-put-activedimstyle adoc (vla-item (vla-get-dimstyles adoc) dimsty))
(princ (strcat "\nCurrent dimension style \" " dimsty " \""))
)
(princ "\nIt was not possible to set current a dimension style from the selected text... ")
)
(princ)
)
Hope this helps,
Henrique
@kenhuse wrote:
.... In order to find the dimstyle I need to make current, I select a bit of text and look to see it's height. I then go to the dimstyle dialog box to select the proper dimstyle.
Do you suppose I could put together a lisp routine that would make current the proper dimstyle after having selected a piece of text?
...
I would take a somewhat simpler approach [partly simpler because you mention only Text height as a criterion, not Style, but also in not needing to make a list of all Dimension Styles]:
(defun C:DSTH (/ txt ht done dsdata); = Dimension Style set by selected Text Height
(setq
txt (car (entsel "\nSelect Text for height to find matching Dimension Style: "))
ht (cdr (assoc 40 (entget txt)))
); setq
(while
(and
(not done); haven't found one yet
(setq dsdata (tblnext "dimstyle" (not dsdata))); there's still another Style to check
); and
(if (equal (* (cdr (assoc 140 dsdata)) (getvar 'dimscale)) ht 1e-4); [edit fuzz factor as desired]
;; Dimension text height as used same as that of selected Text
(progn ; then
(command "_.dimstyle" "_restore" (cdr (assoc 2 dsdata))); set that Style current
(setq done T); stop looking
); progn
); if
); while
(if (not done) (prompt "\nNo matching-height Dimension Style found."))
(princ)
); defun
If you have more than one Style with that text height, it will use the first one it finds.
For some reason, it won't let me use (setvar 'dimstyle ...), which is why I used the (command) approach, but if (setvar) works for you, that would be simpler.
It could use the usual enhancements [verification on selecting Text, command-echo suppression, etc.].
Ken,
try this modified 'demo'
(defun c:demo (/ dimstyles dimsty ht lst sd sel styl txt)
(defun dimstyles (/ dimstyle-lst dimstyle-name dimstyle-text-height dimstyle-scale dimstyle-text-final-height lst)
(while (setq dimstyle-lst (tblnext "dimstyle" (null dimstyle-lst)))
(setq dimstyle-name
(cdr (assoc 2 dimstyle-lst))
dimstyle-text-height
(cdr (assoc 140 dimstyle-lst))
dimstyle-scale
(cdr (assoc 40 dimstyle-lst))
dimstyle-text-final-height
(* dimstyle-text-height dimstyle-scale)
lst (cons (list dimstyle-name dimstyle-text-height dimstyle-scale dimstyle-text-final-height) lst)
)
)
lst
)
(if (and (setq lst (dimstyles))
(setq sel (car (entsel "\nSelect dimension text:")))
(setq txt (entget sel))
(wcmatch (cdr (assoc 0 txt)) "TEXT,MTEXT")
(setq ht (cdr (assoc 40 txt)))
(vl-some '(lambda (x)
(if (eq ht (nth 3 x))
(setq dimsty (nth 0 x)
sc (nth 2 x)
)
)
)
lst
)
)
(progn
(or adoc (setq adoc (vla-get-ActiveDocument (vlax-get-Acad-Object))))
(vla-put-activedimstyle adoc (vla-item (vla-get-dimstyles adoc) dimsty))
(setvar 'DIMSCALE sc)
(princ (strcat "\nCurrent dimension style \" " dimsty " \""))
)
(princ "\nIt was not possible to set current a dimension style from the selected text... ")
)
(princ)
)
Hope this helps,
Henrique
@kenhuse wrote:
Hi Henrique,
Thanks for getting in the modification in the midst of your deadline.
For some reason it's not recognizing the command prompt "demo".
The command doesn't activate.
I saved the .lsp document after pasting in your code.
I opened a drawing which will automatically download the .lsp file.
No luck. Thanks so much in any event.
Try the attached one...
Henrique
@kenhuse wrote:
Thanks, it did make a difference and it recognized "demo" but instead of switching to simp1, it went to the standard dimstyle on the drawing. I tried to purge and delete standard but it won't let me.
I tried it on another drawing and it returned the current dimstyle when it should have returned Simp1.
So varying results.
Quite a challenge this. I have faith. Thanks again.
Ken,
in the sample file, the only dimstyle with final text height 0.13, is standard, simp1 has 0.125...
(("SIMP 1-2" 0.13 2.0 0.26)
("SIMP1 1-2" 0.13 0.66667 0.0866671)
("SIMP1-8" 0.125 8.0 1.0)
("SIMP112" 0.13 0.6667 0.086671)
("simp3-8" 0.13 2.6667 0.346671)
("SIMP20" 0.13 20.0 2.6)
("SIMP10" 0.13 10.0 1.3)
("SIMP40" 0.13 40.0 5.2)
("SIMP6" 0.0216667 0.166667 0.00361111)
("SIMP3-4" 0.13 1.333 0.17329)
("SIMP3" 0.13 0.3333 0.043329)
("simp1-16" 0.13 16.0 2.08)
("SIMP1-2" 0.13 2.0 0.26)
("simp1-4" 0.13 4.0 0.52)
("SIMP1" 0.125 1.0 0.125)
("STANDARD" 0.13 1.0 0.13)
)
those texts should return SIMP1
Hope this helps,
Henrique
