Laying out hole patterns with a lisp
@Moshe-A wrote:....
first, there is no "gcen" osnap option. ....
on the other hand why work so hard? when you can solve this with exploded hatch?
Yes, there is a geometric-center Object Snap mode in newer versions. And an Exploded Hatch pattern cannot result in Circles, but could only be approximations of Circles made up of short Line segments.
Kent Cooper, AIA 
Another way.... It's really not necessary to draw all those Circles independently. All that's needed is to draw one, Copy it in the appropriate direction, and Array the first one and the copy. The tricky parts are calculating the numbers of rows and columns, the position of the first one, and in which direction to Copy it, to get the result to not touch or cross the boundary, and to have the right relationship to the center. Try this, which is done all in metric values, but you can substitute the imperial values if you don't mind the imprecision and all the decimal places [lightly tested]:
(defun C:HOLES (/ rsel rcen rsize rwid rht cols rows set1L set1B)
(setq
rsel (entsel "\nNo-touch perimeter: ")
rcen (osnap (cadr rsel) "_gce")
); setq
(vla-getboundingbox (vlax-ename->vla-object (car rsel)) 'minpt 'maxpt)
(setq
rsize (mapcar '- (vlax-safearray->list maxpt) (vlax-safearray->list minpt))
;; rectangle size as XY[Z] list
rwid (car rsize); width
rht (cadr rsize); height
cols (- (fix (/ rwid 16)) (if (equal (rem rwid 16) 0 1e-4) 1 0))
rows (- (fix (/ rht 16)) (if (equal (rem rht 16) 0 1e-4) 1 0))
set1L (< 0 (rem (- (/ rwid 2) 8) 16) 8); 1st set closer to Left edge [T/nil]
;; "1st set" = Array set incl. Circle down-left from center
set1B (< 0 (rem (- (/ rht 2) 8) 16) 8); 1st set closer to Bottom edge [T/nil]
); setq
(command
"_.circle" "_none"
(list
(- (car rcen) (+ 4 (* 16 (1- (/ cols 2))) (if set1L 16 0))); X coordinate
(- (cadr rcen) (+ 4 (* 16 (1- (/ rows 2))) (if set1B 16 0))); Y coordinate
); list
4 ; radius [use 4.0005 to be exactly as in sample drawing]
"_copy" "_last" "" "_none"
(list (if set1L 8 -8) (if set1B 8 -8)) ""
"_array" "_last" "_previous" "" "_rectangular" rows cols 16 16
); command
(princ)
); defun
Kent Cooper, AIA
Accepted solution
If you need the "highest precision," then 9 decimal places isn't the best you can do. Without digging too deeply into your revision for whatever you may have missed to throw it off-center, I made my own, simply changing the values to variables, in which the 16mm spacing is as precise as AutoCAD can handle. And you could adjust it easily to ask for values, changing only where those variables are set, but leaving their usage in the rest of the code as it is. Minimally tested:
(defun C:HOLES (/ rsel rcen rsize rwid rht cols rows set1L set1B)
(setq
rsel (entsel "\nNo-touch perimeter: ")
rcen (osnap (cadr rsel) "_gce")
crad 0.1575; Circle radius
cspc (cvunit 16 "mm" "inch"); Circle spacing [in orthogonal directions]
); setq
(vla-getboundingbox (vlax-ename->vla-object (car rsel)) 'minpt 'maxpt)
(setq
rsize (mapcar '- (vlax-safearray->list maxpt) (vlax-safearray->list minpt))
;; rectangle size as XY[Z] list
rwid (car rsize); width
rht (cadr rsize); height
cols (- (fix (/ rwid cspc)) (if (equal (rem rwid cspc) 0 1e-4) 1 0))
rows (- (fix (/ rht cspc)) (if (equal (rem rht cspc) 0 1e-4) 1 0))
set1L (< 0 (rem (- (/ rwid 2) (/ cspc 2)) cspc) (/ cspc 2)); 1st set closer to Left edge [T/nil]
;; "1st set" = Array set incl. Circle down-left from center
set1B (< 0 (rem (- (/ rht 2) (/ cspc 2)) cspc) (/ cspc 2)); 1st set closer to Bottom edge [T/nil]
); setq
(command
"_.circle" "_none"
(list
(- (car rcen) (+ (/ cspc 4) (* cspc (1- (/ cols 2))) (if set1L cspc 0))); X coordinate
(- (cadr rcen) (+ (/ cspc 4) (* cspc (1- (/ rows 2))) (if set1B cspc 0))); Y coordinate
); list
crad ; radius
"_copy" "_last" "" "_none"
(list (if set1L (/ cspc 2) (- (/ cspc 2))) (if set1B (/ cspc 2) (- (/ cspc 2)))) ""
"_array" "_last" "_previous" "" "_rectangular" rows cols cspc cspc
); command
(princ)
); defun
EDIT: [I had some instances of crad in there [in the calculating of the first Circle's location] that I've corrected to (/ cspc 4). So if you pulled it before that correction, it'll be off by a hair.
Kent Cooper, AIA