Layers On LISP

[More8927]

Hi, 

I am trying to write a simple lisp that can turn a set of layers on.  I keep running into a nil error.  The set is generated by a seperate program that will generate the lsp and run it as part of a script. That said it would be best if I can leave layer list variable in an easy to generate format, but I am not against changing it if I need to. 

;;; TURNS ON LAYERS LISTED BELOW
(defun c:FADJ ()
(setq stuff '("05" "02" "Named Layer"))
(foreach stuff
(command "-layer" "_on" stuff)
)
)

Thanks,

Michael

[Kent1Cooper · Accepted solution]

You don't have the arguments right in the (foreach) function, if 'stuff' is a list, and you need to complete the Layer command.  Change:

(foreach stuff
  (command "-layer" "_on" stuff)
)

to something like:

(foreach lay stuff
  (command "-layer" "_on" lay "")
)

[Shneuph]

This seems to do what you're asking for.

(defun c:FADJ ()
(setq stuff '("05" "02" "Named Layer"))
(foreach x stuff
(command "-layer" "_on" x "")
)
)

[Shneuph]

http://i.imgur.com/avqILfJ.gif  <---Kent  

[ВeekeeCZ]

I would recommend not to run -layer command multiply - because each layer has its own step while you using _layerp to return to previous layerstate. You would probably expect, that this will be done in one step.

You can achieve that with following approach:
-layer on "05" on "02" on "Named Layer" ""

or convert your list to comma delimited string. Then it would look like this:
-layer on "05,02,Named Layer" ""

You can choose...

Spoiler

(defun c:FADJ ()
  (setq stuff '("05" "02" "Named Layer"))
  (if stuff
    (progn
      (command "_-layer")
      (foreach lay stuff
	(command "_on" lay))
      (command)))
  (princ)
)


(defun c:FADJ2 ( / lays)
  (setq stuff '("05" "02" "Named Layer"))
  (setq lays "")
  (foreach lay stuff
    (setq lays (strcat lay "," lays)))
  (command "_-layer" "_on" lays "")
  (princ)
)

[hmsilva]

---

@ВeekeeCZ wrote:

I would recommend not to run -layer command multiply - because each layer has its own step while you using _layerp to return to previous layerstate. You would probably expect, that this will be done in one step.

You can achieve that with following approach:
-layer on "05" on "02" on "Named Layer" ""

or convert your list to comma delimited string. Then it would look like this:
-layer on "05,02,Named Layer" ""

You can choose... 

---

1+

or

(defun c:FADJ3 nil
    (setq stuff '("05" "02" "Named Layer"))
    (command "_-layer" "_on" (apply 'strcat (mapcar '(lambda (x) (strcat x ",")) stuff)) "")
    (princ)
)

Henrique

[Kent1Cooper]

Yet another way to go about it, which with a large enough number of Layers could be noticeably faster than using a Layer command [especially if separate Layer commands] in one or more (command) functions, would be to substitute the non-negative color number into the entity data for each Layer as an object from the Layer table:

(foreach lay stuff

  (setq ldata (entget (tblobjname "layer" lay)))
  (entmod (subst (cons 62 (abs (cdr (assoc 62 ldata)))) (assoc 62 ldata) ldata))

); foreach