Join all by layer for every layer
Accepted solution
(defun c:JBL( / layers)
(setq layers (vla-get-layers(vla-get-activedocument(vlax-get-acad-object))))
(vlax-for lay layers (command "_.join" (ssget "X" (list (cons 8 (vlax-get lay 'Name)))) ""))
)Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
[ @ВeekeeCZ beat me to it....] I think you may simply need to complete the selection:
....
(command "_join" ss "")
....
Kent Cooper, AIA 
@eng_minamaged wrote:
.... If I have error can't join closed polyline If I want to select only line arc and opened polylines for every layer
Explain in more detail -- how are you getting an error? When using the JOIN command [which I assume because you mentioned me, and my only Message here is related to JOIN], I can include closed Polylines in the selection without any error resulting. It reports that it didn't Join everything [discarded some object(s) from the operation], but there's no error. Similarly, when using PEDIT's Join option, if the selected Polyline is closed, it merely reports that I can't Join to it, but just goes back to the prompt, without error.
Kent Cooper, AIA
@eng_minamaged wrote:
When I use PEDIT if polyline is closed it give me error and the lisp stop
That must mean you are using the code in Message 4, the only entry that uses PEDIT. Studying that, one thing doesn't make sense to me: If there is only one object on a given Layer, why does it [try to] Join everything [without distinction of Layer] to it? Shouldn't it just be left alone? It must be in that attempt that you are getting the error, when that one thing is closed, because then it goes back to the initial prompt, and what it is given is not appropriate for that. I would think you would only Join things when there are more than one on a given Layer. Something like this modification [untested]:
(defun c:joinAllByLayer (/ lyr lst sel)
(setq lyr
(vlax-for
lay (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
(setq lst (cons (vla-get-Name lay) lst))
)
)
(mapcar
'(lambda (x)
(if (setq sel (ssget "_X" (list (cons 8 x))))
(if (> (sslength sel) 1)
(command "_.pedit" "_multiple" sel "" "_join" "0.0" "")
)
)
)
lyr
)
(princ)
)
[That would have trouble, too, if the only things on a given Layer are not in the current space, because they will not be "seen" by the PEDIT object selection.]
Or, a little more simply [lightly tested]:
(defun c:JoinAllByLayer (/ lay ss)
(while (setq lay (tblnext "layer" (not lay)))
(if (setq ss (ssget "_X" (list (cons 8 (cdr (assoc 2 lay))) (cons 410 (getvar 'ctab)))))
(if (> (sslength ss) 1)
(command "_.pedit" "_multiple" ss "" "_join" "0.0" "")
)
)
)
(princ)
)
Kent Cooper, AIA
Open Polylines will simply be ignored by PEDIT/Join under the Multiple option [unlike under the pick-something approach and then the Join option], so I don't think there's any harm in allowing them. But it is possible to prevent selection of them:
(defun c:JoinAllByLayer (/ lay ss)
(while (setq lay (tblnext "layer" (not lay)))
(if
(setq ss
(ssget "_X"
(list
'(-4 . "<AND")
(cons 8 (cdr (assoc 2 lay))); on the given Layer
(cons 410 (getvar 'ctab)); in the current space
'(-4 . "<OR")
'(0 . "LINE,ARC"); any
'(-4 . "<AND")
'(0 . "LWPOLYLINE")
'(-4 . "<NOT") '(-4 . "&") '(70 . 1) '(-4 . "NOT>"); open only
'(-4 . "AND>")
'(-4 . "OR>")
'(-4 . "AND>")
); list
); ssget
); setq
(if (> (sslength ss) 1)
(command "_.pedit" "_multiple" ss "" "_join" "0.0" "")
)
)
)
(princ)
)
Be sure PEDITACCEPT is set to 1 [that can be built in if desired]. And consider whether you want to account for the possibility of locked Layers, one way or the other.
By the way, any Lines or Arcs that do not meet something else eligible at an end, and are therefore not Joined to anything, will be turned into single-segment Polylines, i.e. they will not be left as Lines/Arcs. If you'd rather they be left alone, that's possible [though it actually involves Exploding them back to Lines/Arcs after PEDITing] -- see PolylineJoin.lsp >here<.
Kent Cooper, AIA
