insert specified block at the end of polyline
@eng_mohamedmustafa wrote:
.... but insertion done for both ends of polyline >>> i want to insert block for one side only ...
....
( (not (setq ss (ssget '((0 . "*POLYLINE")))))....
(foreach param (list (vlax-curve-getStartParam e) (vlax-curve-getEndParam e))
....
That operates with a selection set, so that it can put them on the ends of any number of Polylines selected at once, and it just finds the start and endpoints of every Polyline. May I assume that if you want the Block on only one end, you do not necessarily want them at the same end of all Polylines, i.e. not all at the start or all at the end? If that's a valid assumption, I assume you would need to pick each Polyline, individually, presumably closer to the end where you want the Block placed. Is that correct?
@eng_mohamedmustafa wrote:
I want to select more than polyline at the same time but insert this block on the chosen ends not both ends of polylines
That implies that while you select more than one, you still need to pick on each one so that there will be a "chosen end" for each one. That would mean you can't select them in a window or lasso selection, or if you could, you would then need to go around and pick on a chosen end for each one after the group selection.
If that's the case, it doesn't seem to me that there's any benefit to selection-set multiple-object selection, but instead you may as well pick one and have the Block put on its closer end immediately, then pick the next and its Block would be added, and so on. If you don't agree, can you describe in detail the steps you expect the User to go through?
i want to select polylines seen in the attached photo ... and insert the block that appeared in the photo
I think that could be done IF you are willing to restrict your selection method(s) to only either picking individually or with Fence selection [not, for example, with a Crossing window], in both cases closer to the end where you want the Block. You could combine those methods, for example using two Fence selections, one on either side, or selecting some by Fence and some by individual pick, in the same command.
With those selection methods, AutoLisp is capable of knowing at what point each object was selected, either the individual pick point or where the Fence crossed it, and therefore would be able to decide at which end of it to put the Block. It can't do that with Crossing-window selection, or regular Window, or CP or CW or Lasso or Last or Previous.
@Kent1Cooper wrote:
I think that could be done IF you are willing to restrict your selection method(s) to only either picking individually or with Fence selection [not, for example, with a Crossing window], in both cases closer to the end where you want the Block. You could combine those methods, for example using two Fence selections, one on either side, or selecting some by Fence and some by individual pick, in the same command.
....
Try this [lightly tested, and without the usual enhancements yet]:
(defun C:IBNE ; = Insert Block at Near End
(/ ss ent nogo)
(prompt "\nUsing only individual-pick or Fence selection option(s),")
(if (setq ss (ssget '((0 . "LINE,*POLYLINE,ARC")))) ;; include Spline/Ellipse if open? Ray?
(foreach item (ssnamex ss)
(if (member (car item) '(1 4)); individual-pick or Fence selection used
(progn ; then
(setq ent (cadr item)); entity name
(command "_.insert" "YourBlockName" "_scale" 1 "_none"
(if
(<
(vlax-curve-getDistAtPoint ent (vlax-curve-getClosestPointTo ent (last (last item))))
(/ (vlax-curve-getDistAtParam ent (vlax-curve-getEndParam ent)) 2); half length
); <
(vlax-curve-getStartPoint ent); then -- closer to start
(vlax-curve-getEndPoint ent); else
); if
(* ; rotation
(/
(angle
'(0 0 0)
(vlax-curve-getFirstDeriv ent (vlax-curve-getParamAtPoint ent (getvar 'lastpoint)))
); angle
pi
); /
180
); *
); command
); progn
(setq nogo T); else -- selected by wrong method
); if
); foreach
); if
(if nogo (prompt "\nSome object(s) selected by incorrect method(s)."))
(princ)
); defun
Here's another grread version based off of code HERE.
(defun c:foo (/ a ang e l p s x)
;; RJP » 2019-05-01
;; Place block on closest end of polyline using grread
(cond ((null (tblobjname "block" "sample"))
(entmake '((0 . "BLOCK")
(100 . "AcDbEntity")
(67 . 0)
(8 . "0")
(100 . "AcDbBlockReference")
(2 . "sample")
(10 0. 0. 0.)
(70 . 0)
)
)
(entmake '((0 . "LWPOLYLINE")
(100 . "AcDbEntity")
(67 . 0)
(8 . "0")
(100 . "AcDbPolyline")
(90 . 2)
(70 . 128)
(10 -0.5 0.)
(10 0.5 0.)
)
)
(entmake '((0 . "ENDBLK") (100 . "AcDbBlockEnd") (8 . "0")))
)
)
;; Create a list of points to check against so we're not duplicating blocks
(and (setq s (ssget "_X" '((0 . "insert") (2 . "sample"))))
(setq s (mapcar '(lambda (x) (cdr (assoc 10 (entget x)))) (mapcar 'cadr (ssnamex s))))
)
(while (and (setq a (grread t 15 0)) (not (member (cadr a) '(13 32))))
(cond
((and (= 5 (car a))
(setq e (car (nentselp (setq p (cadr a)))))
(= 'list (type (setq l (vl-catch-all-apply 'vlax-curve-getstartpoint (list e)))))
(setq l (list l (vlax-curve-getendpoint e)))
(setq p (car (vl-sort l '(lambda (a b) (< (distance p a) (distance p b))))))
(null (vl-some '(lambda (x) (equal p x 1e-4)) s))
)
(setq ang (+ (/ pi 2)
(angle '(0 0 0) (vlax-curve-getfirstderiv e (vlax-curve-getparamatpoint e p)))
)
)
(entmakex (list '(0 . "insert") '(2 . "sample") '(8 . "sample") (cons 10 p) (cons 50 ang)))
(setq s (cons p s))
)
)
)
(princ)
)
(vl-load-com)
