Insert image
@Anonymous wrote:
Hi,
Can anyone help me create a lisp to insert a jpg from a file location on my computer. It would basically be the attach command but will just insert the specific file from the location needed at 0,0 -
Thanks,
Danny
(defun c:demo (/ imagefile inimage)
(if (findfile (Setq imagefile "C:\\Downloads\\IMAGE.JPG"))
(progn
(setq inimage (vlax-invoke
(vlax-get
(vla-get-ActiveLayout
(vla-get-activedocument
(vlax-get-acad-object)
)
)
'Block
)
'AddRaster
imagefile
'(0.0 0.0 0.0)
44.5 ;<-width
0.0
)
)
(vla-put-name inimage "MyInsertedPicture") ;<-- Name
(vla-update inimage)
)
)
(princ)
)
HTH
@Anonymous wrote:
. But nothing happens?
The only time it would do nothing when the file is not found:
(defun c:found (/ imagefile)
(princ
(if (findfile (Setq imagefile "C:\\Downloads\\IMAGEs.JPG"))
(strcat "\nImage found at " imagefile)
"\nImage not found"
)
)(princ)
)
What do you see when you load and run this?
OR
The image is too small to see. When you type image do you see "MyInsertedPicture" listed on the File REferences dialog?
@Anonymous wrote:
How would i change the insertion fro 0,0 to insert on the tool tip?
Not sure what you mean by that chewdanny12. Is that prompting for insertion point on screen?
@Anonymous wrote:
Yes, just like when you insert from a tool palette.
Are you aware you can use a dwg or dwt file with all your images attached to it and use that file as a source from tool palette?
Otherwise :
Use a lisp code
(defun _insertImage ( imagefile / imagefile inimage p)
(if (and
(findfile imagefile)
(setq p (Getpoint "\nInsertion point"))
)
(progn
(setq inimage (vlax-invoke
(vlax-get
(vla-get-ActiveLayout
(vla-get-activedocument
(vlax-get-acad-object)
)
)
'Block
)
'AddRaster
imagefile
p
44.5 ;<-width
0.0
)
)
(vla-put-name inimage (vl-filename-base imagefile)) ;<-- Name
(vla-update inimage)
)
(princ (Strcat "\nImage file \"" (vl-filename-base imagefile) "\" not found!"))
)
(princ)
)
(_insertImage "C:/Downloads/IMAGE.JPG")
(_insertImage "C:/Downloads/Another_IMAGE.JPG")
HTH
This is all you need:
(command "_.-attach" "C:\\Libraries\\Pictures\\IMAGE.JPG" "0,0" "" "")
Replace the C with the appropriate drive letter if needed.
Kent Cooper, AIA 
@Kent1Cooper wrote:
(command "_.-attach" "C:\\Libraries\\Pictures\\IMAGE.JPG" "0,0" "" "")
Yes, that too. 
@Anonymous wrote:
....
I have created a custom button on the ribbon that runs the lisp and inserts the image at 0,0. This works fine, but it would be nice to chose the location point for the insertion.
You don't say whose Post you're Replying to. If it's my little code string, just replace the "0,0" with a pause for User input:
(command "_.-attach" "C:\\Libraries\\Pictures\\IMAGE.JPG" pause "" "")
Kent Cooper, AIA
Accepted solution
@Anonymous wrote:
....
(command "_.-attach" "C:\\Downloads\\IMAGE.jpg" "pause" "2" "45")....
Don't put quotation marks around the word pause.
Kent Cooper, AIA
