Input values are getting "error: bad argument type: consp"
You can do a lot of testing & see what AutoCAD returns by copy & pasting each line of code to the command line like this:
When you use getreal function you'll get a real number in return:
You cannot use car function since it's not a list.
But when you use getpoint function you'll get a list in return with 3 real numbers representing x, y & z coordinates:
Now you can use the car function to get the first item in the list:
My suggestion instead of using getreal function to get radius is to use getdist function which offers you the option to pick points on the drawing area and enter a number:
Now as to why both Lines are drawn with the same endpoints on the outer Circle:
your code uses the same to get both endpoints EPR & EPL:
So you'll need to request another value like perhaps an angle between the 2 Lines.
You may be able to just 1. change one of the ARRD's to ALRD in setting the endpoints for the Lines, AND 2. ensure you at least don't have QUAdrant mode running in Object Snap, which could be why your Lines are coming out vertical. [The same-code problem that @paullimapa pointed out should have them both at the same angle, but not vertical.] Preferably, turn off Osnap altogether.
I would also suggest you use (getangle) for the shroud angle, because you can type in a value in degrees but the returned value will be already in radians, so no conversion is needed.
Looked like an interesting challenge, so I tried modifying your code, incorporating the various suggestions and some other efficiencies, like setting System Variables directly instead of using (command) functions to do it, consolidating multiple variable settings into one (setq) function, etc., to draw the shape directly. Very limited testing, but it seems to work.
(defun C:SHD (/ SR LR AN SP AO AR AL OL OS PW LT)
(setq
SR (getdist "\nSMALL RADIUS:")
LR (getdist "\nLARGE RADIUS:")
AN (getangle "\nSHROUD ANGLE:")
SP (getpoint "\nCENTER POINT: ")
AO (/ (- (* pi 2) AN) 2)
AR (- (/ pi 2) AO)
AL (+ (/ pi 2) AO)
OL (getvar 'clayer)
OS (getvar 'osmode)
PW (getvar 'plinewid)
LT (getvar 'celtype)
); setq
(setvar 'clayer "0")
(setvar 'osmode 0)
(setvar 'plinewid 0)
(setvar 'celtype "CONTINUOUS")
(command "_.pline"
(polar SP AR SR)
"_arc" "_second" (polar SP (* pi 1.5) SR) (polar SP AL SR)
"_line" (polar SP AL LR)
"_arc" "_second" (polar SP (* pi 1.5) LR) (polar SP AR LR)
"_line" "_close"
); command
(setvar 'clayer OL)
(setvar 'osmode OS)
(setvar 'plinewid PW)
(setvar 'celtype LT)
(prompt "Shroud has been drawn.")
(prin1)
)
I don't know how you work with linetypes, but if Layer 0's linetype is Continuous [as I suspect it would be for most Users], I would go for setting CELTYPE to BYLAYER instead.
It could also benefit from adding *error* handling to ensure resetting those System Variables if something goes wrong.
[Actually, it doesn't need the Large and Small Radii to be in that relationship -- it still works if the so-called Large one given is smaller than the Small one. It could be made to verify that Large is larger than Small, if it matters.]
EDIT: It could also be made to remember your values and offer them as defaults on subsequent use, if you ever do more than one of these but keeping any of the same values.
1. Gather user input.
2. TEST user input.
3. Execute.
;1. Gather user input.
(if (and
(setq SR (getreal "\nSMALL RADIUS:"))
(setq LR (getreal "\nLARGE RADIUS:"))
(setq AN (getreal "\nSHROUD ANGLE:"))
(setq SP (getpoint "\nCENTER POINT: "))
);and
(progn
...
;2. Test user input here.
...
;A command is being used. Best to first turn off OSMODE.
(if (< getvar 'OSMODE) 16384) (setvar 'OSMODE (+ (getvar 'OSMODE) 16384)));if
...
;3. Execute
...
;Execute ended. Reset OSMODE.
(if (> (getvar 'OSMODE) 16384) (setvar 'OSMODE (- (getvar 'OSMODE) 16384)));if
...
);progn
);if
The first 3 inputs can be made into a dialog and tested before closing dialog to specify a point.
@Kent1Cooper maybe I am doing something wrong. 45 deg = 0.785398163397448 radians
(setq AN (getangle "\nSHROUD ANGLE:"))
SHROUD ANGLE:45
5.49778714378214I also tried pick 2 points approximating 45 and got similar 5.xx answer. Tried changing units to radians etc but no difference. Using Brticscad.
"The first 3 inputs can be made into a dialog "
;The dtr function converts degrees to radians
;The rtd function converts radians to degrees
(defun dtr (a)
(* pi (/ a 180.0))
)
;
(defun rtd (a)
(/ (* a 180.0) pi)
)
(if (not AH:getvalsm)(load "Multi Getvals.lsp"))
(setq ans (AH:getvalsm (list "Enter Values" "Small radius " 5 4 "50" "Big Radius" 5 4 "100" "Shroud angle" 5 4 "25" )))
(setq sr (atof (nth 0 ans))
LR (atof (nth 1 ans))
AN (dtr (atof (nth 2 ans)))
)Save multi getvals into a support path as its auto loaded. Can be used in any code.
@Sea-Haven wrote:
@Kent1Cooper maybe I am doing something wrong. 45 deg = 0.785398163397448 radians
(setq AN (getangle "\nSHROUD ANGLE:")) SHROUD ANGLE:45 5.49778714378214....
It works fine for me, in both AutoCAD 2020 and 2026:
And stand-alone:
Command: (getangle "\nAngle: ")
Angle: 45
0.785398
Must be a Bricscad issue.
@scot-65 wrote:
....
Which code resulted in that message? It's not true, at least not for my routine -- see the first two shapes in the image in Message 4, both of which have shroud angles greater than 180°. It's not true of the (getangle) function in general, either, unless somehow LT works differently with that.
