How to save insert scale factor upon quiting dwg session and use the same scale factor working back to the same dwg
@owitzki wrote:
.... How can I set to remember that value until someone change it?
You can use an environment variable. Read about the (setenv) and (getenv) AutoLisp functions. They can only hold text, so you will need to convert your scale factor number to its text equivalent to set it, and convert it back to a number after you get it, to use it. But you can have as many of them as you want, called whatever you want, and they will be available to any drawing, since they are not saved in the drawing file, but in the "environment."
EDIT: Something like these? [very lightly tested]:
(defun C:IP () ;Set insert scale factor
(setenv "BlockScale"
(rtos ; because it needs to be text
(cond
( (getreal ; User input [nil on Enter]
(strcat
"\nEnter scale factor <"
(if (getenv "BlockScale")
(rtos (atof (getenv "BlockScale")) 2 3); then
;; EDIT # of displayed decimal places [up to 8 in stored value]
"1.0" ; initial default
); if
">: "
); strcat
); getreal
); user-entry condition
((atof (getenv "BlockScale"))); prior value if present
(1.0); initial default on Enter with no prior value
); cond
2 8 ; mode/precision [max. precision for e.g. fractional value]
); rtos
); setenv
(prin1)
)
(defun C:IB () ;Insert block name
(if (not (getenv "BlockScale")) (setenv "BlockScale" "1.0"))
(setq BNAME
(getstring T
(strcat
"\nEnter block name"
(if (/= (getvar 'insname) ""); there's a prior Block name
(strcat " <" (getvar 'insname) ">"); then -- offer as default
"" ; elses -- no default
); if
": "
); strcat
); getstring
); setq
(command "_.insert" BNAME "s" (atof (getenv "BlockScale")))
(prin1)
)
Line 27 in IB will not be needed after the very first use of IP, so if you use IP even once before ever using IB, that line can be eliminated.
Consider adding an option in IB to change the scale factor there, with a notification of what the current scale factor is before the prompt for the Block name.
@owitzki wrote:
Thank you Kent!
.... Is there a way to save just the value of scale factor for each individual drawing? .....
Not with environment variables. But you can use one of the USERR1 through USERR5 System Variables if you're sure nothing else is going to use the same one. Or if your scale factors are always whole numbers, USERI1 through USERI5. Those are saved separately in every drawing.
This seems to work. I just don't get to show the last input here
(defun C:IP () ;Set insert scale factor
(if (= BlockScale nil)(vlax-ldata-put "dict" "BlockScale" 2))
(vlax-ldata-put "dict" "BlockScale" BlockScale)
(setq BlockScale (vlax-ldata-get "dict" "BlockScale" ))
(vlax-ldata-put "dict" "BlockScale" (rtos (cond ( (getreal
(strcat "\nEnter scale factor <"
(if (vlax-ldata-get "dict" "BlockScale")
(rtos (atof (vlax-ldata-get "dict" "BlockScale")) 2 3) "1.0" ) ">: " )))
((atof (vlax-ldata-get "dict" "BlockScale")))(1.0)) 2 8 ))
(prin1)
)
(defun C:IB () ;Insert block name
(if (not (vlax-ldata-get "dict" "BlockScale")) (vlax-ldata-put "dict" "BlockScale" "1.0"))
(setq BNAME (getstring T (strcat "\nEnter block name"
(if (/= (getvar 'insname) "")(strcat " <" (getvar 'insname) ">") "" ) ": " )))
(command "_.insert" BNAME "s" (atof (vlax-ldata-get "dict" "BlockScale")))
(prin1)
)
Anyway, big thanks to all of you!
