how to filter underlined MTEXTs

[msarqui]

Hello guys,

Could someone help me please.

I would like to know how to filter underlined MTEXTs in a selection set with SSGET.

I need to select MTEXTs, except those that are underlined.

Thanks,

Marcelo

[Jonathan3891]

Give this a try:

(SETQ SS (SSGET '((0 . "TEXT,MTEXT")(1 . "*%%U**%%u*,{*\L*}"))))

[msarqui]

Hi Jonathan

Thanks for reply but it returns nil. The selection does not select anything

I tested on the attached exemple.

Marcelo

[kerry_w_brown]

Perhaps try something like

(SETQ SS (SSGET '((0 . "TEXT,MTEXT")(1 . "*%%U*,*%%u*,*{*\L*}"))))

[Jonathan3891]

Thats strange. It works fine on the drawing I attached, but it wont work on your drawing.

[msarqui]

Hi Kerry,

---

@KerryBrown wrote:

Perhaps try something like

(SETQ SS (SSGET '((0 . "TEXT,MTEXT")(1 . "*%%U*,*%%u*,*{*\L*}"))))

---

This is actually selecting underlined MTEXTs and I would like to exclude them. But, you show me the way and with a small change I could get it work.

Here is what I did:

(setq ss2 (ssget "_:S:L" '((0 . "*TEXT")
			    (-4 . "<NOT")
	                            (1 . "*%%U*,*%%u*,*{*\L*}")	;Avoid texts underlined
	                    (-4 . "NOT>")
			    (-4 . "<NOT")
	                            (62 . 1)			;Avoid texts in RED color
	                    (-4 . "NOT>")
)))

Many thanks.

Marcelo

[msarqui]

@Anonymous_dude wrote:

Thats strange. It works fine on the drawing I attached, but it wont work on your drawing.

---

Well, strange it is. I did a test in your drawing and it works. I have no idea why...

[dbroad · Accepted solution]

Technically, if you only want to select MTEXT objects that have no underlined words, you would need the following:

(SETQ SS (SSGET '((0 . "MTEXT")(1 . "~*{*\L*"))))

Mtext has no uses for %%U or %%u.

If you want to select either text or mtext that is not underlined:

(setq ss (ssget	'((-4 . "<OR")
		  (-4 . "<AND")
		  (0 . "MTEXT")
		  (1 . "~*{*\L*")
		  (-4 . "AND>")
		  (-4 . "<AND")
		  (0 . "TEXT")
		  (1 . "~*%%U*,~*%%u*")
		  (-4 . "AND>")
		  (-4 . "OR>")
		 )
	 )
)

[msarqui]

Hello dbroad

In my tests, your suggestion will not select:

BOLD, ITALIC, UNDERLINE, OVERLINE

But it will select: 

NORMAL, WIDTH, STRIKETHROUGH

Weird?

Please, see attached file

[kerry_w_brown]

msarqui,

You will need to be more explicit with your question.

What test are you using exactly.

You have made no previous mention of those properties.

weird, I don't recall your original post asking for the EXCLUSION of underlined text ??

[kerry_w_brown]

What is the DXF 1 value of the Mtext that is not being selected ??

Try something like this on the MText

(defun c:dxflist (/ eko)
  (setq eko (getvar 'cmdecho))
  (setvar 'cmdecho 0)
  (setq
    *lent* (entget
             (car (entsel "\nSelect entity to display its DXF value data "))
             '("*")
           )
  )
  (textscr)
  (list *lent*)
  (foreach n *lent* (print n))
  (setvar 'cmdecho eko)
  (princ)
)

[msarqui]

---

@msarqui wrote:

Hello guys,

Could someone help me please.

I would like to know how to filter underlined MTEXTs in a selection set with SSGET.

I need to select MTEXTs, except those that are underlined.

Thanks,

Marcelo

---

Hi Kerry,

Thanks for the reply.

In my first original post I DO asked for the EXCLUSION of underlined MTEXTs

In my drawings I have different types of MTEXTs formatting. Someones with BOLD, others with ITALIC, others with OVERLINE, etc.

I would like to select all of them, except (excluding) those that are underlined. 

In my tests, I copied and pasted @dbroad's suggestion in the command line and I selected the MTEXTS to see wich ones are highlighted.

---

@msarqui wrote:

Hello @dbroad

In my tests, your suggestion will not select:

BOLD, ITALIC, UNDERLINE, OVERLINE

But it will select: 

NORMAL, WIDTH, STRIKETHROUGH

Weird?

Please, see attached file

---

I made a mistake in my last post. @dbroad's suggestion is working very well with underlined MTEXTs. Sorry about that 

The only problem is that is also excluding the BOLD, ITALIC and OVERLINED ones.

[hmsilva · Accepted solution]

Marcelo,

dbroad's filter list is correct, just add a second backslash in (1 . "~*{*\\L*")

Hope this helps,
Henrique

[doni49]

---

@msarqui wrote:

The only problem is that is also excluding the BOLD, ITALIC and OVERLINED ones.

---

Paste the following into your command line, when prompted, select one of the text elements that it's failing to select and paste the results here.

(assoc 1 (entget(car(entsel))))

[dbroad]

@hmsilva,

I did test it before I posted it and it did work fine with a single backslash.  It might also work fine with a second escaping backslash.

Funny what got marked as a solution.  Oh well.

[hmsilva]

---

@Anonymous wrote:

@hmsilva,

I did test it before I posted it and it did work fine with a single backslash.  It might also work fine with a second escaping backslash.

Funny what got marked as a solution.  Oh well.

---

@dbroad,

I did test with the dwg in msg#9 and only with a second backslash works as expected...rejecting underlined text...

I did also test in others dwgs, and with a single backslash works as expected, and with double backslashes works as expected also...

Being transversal to several tests, the 'double backslashes' in the list, do you mind to add a second backslash to your code, to provide a more universal solution?

Henrique

[dbroad]

Interesting.  I missed that post.  Thanks for adding the extra backslash!

[hmsilva]

---

@Anonymous wrote:

Interesting.  I missed that post.  Thanks for adding the extra backslash!

---

You're welcome, dbroad!

Henrique