Hello,
I was digging forum but couldn't find anything, I am sorry if someone asked before
How can I know that how many objects are there in polyline, (how many line, how many arc etc)
for example, there are 5 line and 1 arc in this polyline.
Thanks in advance.
(vl-load-com); if needed
(defun C:PLSC ; = PolyLine Segment Count
(/ pl pldata segs bulges arcs lines)
(if
(and
(setq pl (car (entsel "\nSelect LWPolyline for segment line/arc count: ")))
(setq pldata (entget pl))
(member '(0 . "LWPOLYLINE") pldata); LW only for this approach
); and
(progn ; then
(setq
segs (fix (vlax-curve-getEndParam pl)); whether open or closed
bulges (vl-remove-if-not '(lambda (x) (= (car x) 42)) pldata)
); setq
(if (not (vlax-curve-isClosed pl)) (setq bulges (cdr (reverse bulges))))
; remove last bulge factor if open
(setq
arcs (length (vl-remove '(42 . 0.0) bulges)); quantity of non-zero bulges [arc segments]
lines (- segs arcs); the rest
); setq
(prompt (strcat "\nPolyline has " (itoa lines) " line segments and " (itoa arcs) " arc segments."))
); progn
(prompt "\nSelected object is not a LWPolyline."); else
); if
(princ)
)
EDIT: Just corrected an accidental colon that should have been a semicolon.
Of course, this assumes no coincident vertices [two at the same place with a zero-length segment].
(defun c:pl-segs-type(/ *error* pick_poly eo e narcs i ncords nsegs nline)
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ (strcat "\nError: " msg))
)
(princ)
)
(defun pick_poly ()
(setq e (car(entsel "\nSelect polyline >")))
(cond
((and (not e) (= (getvar 'Errno) 7)) (pick_poly))
((and e (not (= (cdr(assoc 0 (entget e))) "LWPOLYLINE"))) (pick_poly))
)
e
)
(setq
eo (vlax-ename->vla-object (pick_poly))
ncords (length(vlax-get eo 'coordinates))
nsegs (fix (* 0.5 ncords))
narcs 0
nline 0
i -1
)
(if (> (vlax-get eo 'Closed) -1) (setq nsegs (1- nsegs)))
(while (<(setq i (1+ i)) nsegs)(if (> (abs(vla-GetBulge eo i)) 0.0) (setq narcs (1+ narcs))))
(setq nline (- nsegs narcs))
(if (and (> narcs 0)(< narcs nsegs))(princ (strcat "\n" (itoa nline) " line and " (itoa narcs) " arc.")))
(if (= narcs nsegs)(princ (strcat "\n" (itoa narcs) " arc.")))
(if (= narcs 0)(princ (strcat "\n" (itoa nsegs) " line.")))
(princ)
)
Miljenko Hatlak
@islerahmet06 wrote:
....
How can I know that how many objects are there in polyline, (how many line, how many arc etc)
....
Since we haven't yet seen any response to suggestions to date, I will raise further questions:
What do you mean by "know"? Do you just want the information reported at the command line as in most suggestions so far? Or drawn in as text, similar to your image, and if so, do you want the segments labeled/numbered, or is all that just for illustration of what you mean by quantities of each segment type? Or are you looking for something more elaborate such as the table in the routine at the link in Message 4? Put into a spreadsheet or text file? Something else?
And what is "etc" [whatever that is, if anything, not being shown in your image]? Details such as in that routine linked in Message 4? Or do you really only want the number of line and arc segments, with actually no "etc" required?
3D Polylines? [They can only be of all line segments.]
Would you want something [though not quantity of line and arc segments] reported about Fit- or Spline-curved "heavy" 2D ones? What about "heavy" ones that are only of ordinary line and arc segments but just happen to be "heavy" instead of "lightweight" [the result would need to be arrived at differently]?
Another approach occurred to me, that's not limited to LWPolylines: EXPLODE the Polyline, and just count how many Lines and Arcs are in the result, then UNDO back past the EXPLODE.
(defun C:PLSC ; = PolyLine Segment Count
(/ pl segs lss lines arcs)
(if
(and
(setq pl (car (entsel "\nSelect Polyline for segment line/arc count: ")))
(wcmatch (cdr (assoc 0 (entget pl))) "*POLYLINE"); LW or heavy incl. 3D
); and
(progn ; then
(command "_.undo" "_mark" "_.explode" pl)
(setq
segs (sslength (ssget "_P"))
lss (ssget "_P" '((0 . "LINE")))
lines (if lss (sslength lss) 0)
arcs (- segs lines)
); setq
(command "_.undo" "_back")
(prompt (strcat "\nPolyline has " (itoa lines) " line segments and " (itoa arcs) " arc segments."))
); progn
(prompt "\nNo Polyline selected."); else
); if
(princ)
)
But it should probably have added to it a check for whether a "heavy" Polyline is Spline-curved. It gives a "result" from one of those, but a meaningless one. It also gives a result for Fit-curved ones that might be of some use, but maybe those should be disallowed, too.
And it should have an *error* handler to ensure un-Exploding if something goes wrong.
I can add those if it seems better than other suggestions, for handling more than only lightweight Polylines.
(defun C:PLSCL ; = PolyLine Segment-type Count and Labeling
(/ plsel plent plobj par lines arcs)
(if
(and
(setq plsel (entsel "\nSelect Polyline for segment-type count and labeling: "))
(wcmatch (cdr (assoc 0 (entget (setq plent (car plsel))))) "*POLYLINE")
); and
(progn ; then
(setq
plobj (vlax-ename->vla-object plent)
par 0 lines 0 arcs 0
); setq
(repeat (fix (vlax-curve-getEndParam plent))
(setq lineseg (= (vla-getBulge plobj par) 0.0))
(command "_.text" "_mc" "_non" (vlax-curve-getPointAtParam plobj (+ par 0.5)) "" 0
(strcat ; text content
(if lineseg "L" "A")
(itoa (set (if lineseg 'lines 'arcs) (1+ (if lineseg lines arcs))))
); strcat
); if
(setq par (1+ par))
); repeat
(prompt (strcat "\nPolyline has " (itoa lines) " line segments and " (itoa arcs) " arc segments."))
); progn [then]
(prompt "\nNo Polyline selected."); else
); if
(princ)
); defun
adds labeling the line and arc segments with L1, L2, A1, L3, A2, etc.:
It currently uses whatever the current Text Style and height are -- specifying those could be built into it. If the current or built-in-specified Style has a fixed height, omit the "".
It handles "heavy" 2D Polylines, but doesn't handle 3D Polylines [the (vla-getBulge) function fails], so those could be prohibited if necessary.
@islerahmet06 wrote:
...for example, there are 5 line and 1 arc in this polyline.
Thanks in advance.
(defun c:whut ( / arc e l p)
(if (setq arc 0
e (car (entsel))
)
(progn
(repeat (setq p (fix (vlax-curve-getEndParam
(setq e (vlax-ename->vla-object e )))) l p
)
(setq arc (If (zerop (vla-getbulge e (setq p (1- p))))
arc (1+ arc)
)
)
)
(princ (strcat "\n"
(itoa (- l arc)) " Line(s) and " (itoa arc)
" Arc segment(s)"
)
)
)
)
(princ)
)HTH
I exploded the dxf and ran the arc to pline and that worked need to add a delete arc once done. Simple addition.
Not sure how your joining all the objects with the small line between arc into a big pline do you have something already ?
What length do you want for the facet when converting arcs ? Can add also as well as do all arcs 1 go.
A bit more after running bpoly just Copy Last say to side then run this it should show how the pline is made up. I added a start and end line need to do more about working out how bpoly assigns start point for your shape is most top most left point. Not sure about CW or CCW.
(defun wow ( / )
(setq lst (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) (entget (car (entsel "\pick pline"))))))
(setq x 0)
(setq pt1 (nth x lst))
(repeat (- (length lst) 1)
(setq pt2 (nth (setq x (1+ x)) lst))
(command "line" pt1 pt2 "")
(command "redraw")
(command "delay" 5)
(setq pt1 pt2)
)
(princ)
)
(wow)
