help to refine my lisp code

[thecadworker]

Hi,

I have made a code to select the text, set the layer current, move the text and draw an arrow to its position from its original position and in the layer of the text. The code I have asks for the selection twice.

Please let me know how to reduce the selection to 1 time.

(Defun c:Tpx (/ pt1 pt2) ;
(WHILE T
(setvar "cmdecho" 0)
(setq entlist (entget (car (entsel "\nSelect object: "))))
(setvar "clayer" (cdr (assoc 8 entlist)))
(setq txt (car (entsel "\nSelect object: ")))
(if txt
(progn
(setq elist (entget txt)); entity list
(setq IP (cdr (assoc 10 elist))); Insertion Point
); progn
); if
(setq IP2 (getpoint "\nPick Next point: "))
(command "move" txt "" ip IP2 "")
(command "_.leader" IP IP2 "_a" "" "_n")
)
)

[ВeekeeCZ]

OK

also, now you can terminate the routine by RT click (as any other command)

(Defun c:Tpx (/ *error* lay ent pnt pnt2)
  
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (if lay (setvar 'clayer lay))
    (princ))
  
  
  (setq lay (getvar 'clayer))
  
  (while (setq ent (car (entsel "\nSelect text: ")))
    
    (setvar 'clayer (cdr (assoc 8 (entget ent))))
    (setq pnt (trans (cdr (assoc 10 (entget ent))) 0 1))
    (command "_.move" ent "" "_non" pnt pause)
    (setq pnt2 (getvar 'lastpoint))
    (command "_.leader" "_non" pnt "_non" pnt2 "_a" "" "_n")
    )
  
  (*error* "end")
  )

[thecadworker]

Thanks for this help, Also I need to increase the text height to 2.0.

[ВeekeeCZ · Accepted solution]

ok

(Defun c:Tpx (/ *error* lay ent pnt pnt2)
  
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (if lay (setvar 'clayer lay))
    (princ))
  
  
  (setq lay (getvar 'clayer))
  
  (while (setq ent (car (entsel "\nSelect text: ")))
    
    (setvar 'clayer (cdr (assoc 8 (entget ent))))
    (setq pnt (trans (cdr (assoc 10 (entget ent))) 0 1))
    (setpropertyvalue ent "Height" 2)
    (command "_.move" ent "" "_non" pnt pause)
    (setq pnt2 (getvar 'lastpoint))
    (command "_.leader" "_non" pnt "_non" pnt2 "_a" "" "_n")
    )
  
  (*error* "end")
  )
 

[fbyfatih]

Why did you use trans in this code? It works fine without it

[ВeekeeCZ]

@fbyfatih 

If you never use UCS you don't need it.

[WeTanks]

Is it possible to add a frame to the text after the text is moved?

[ВeekeeCZ]

---

@WeTanks wrote:

Is it possible to add a frame to the text after the text is moved?

---

It's fairly easy if it's MTEXT. Is it?

[diagodose2009]

Please .. Hello Expert or AutoCad.

Exists one site with many CAD'programs for CAd - online and Vlide-online for many test/s of our LISP'programs, 

The loginUsers cannot open and save the Drawings but they can test VLIDE and Lisp-programs and ARX?