I have a multi point poly line, need to fix strech block on each as given drawing and delete the polyline. is that possible?
Help need to make a lisp
I think this could be fairly simple, but what I have in mind would require that the Block be better defined. Its insertion point is off-center -- when Inserted at scale factors of 1 and rotation of 0:
With a Block definition with the insertion point actually in the middle, I can picture an easy way to do what you're asking.
But it would also involve "plain" Insertions, using the lengths of the Polyline segments to calculate the X scale factor, rather than having them all at X scale factors of 1 with dynamically stretched ends as in your sample. Is that acceptable? It has the benefit that you can pick one and look at the Properties palette to see its length in the X scale factor, which you can't do in the sample drawing.
Kent Cooper, AIA 
@Kent1Cooper wrote:
.... With a Block definition with the insertion point actually in the middle, I can picture an easy way to do what you're asking.
But it would also involve "plain" Insertions, using the lengths of the Polyline segments to calculate the X scale factor.....
Subject to that caveat, something like this [in simplest terms, lightly tested]:
(defun C:PL2PIPES (/ gpap ss n pl m)
(defun gpap (par) (vlax-curve-getPointAtParam pl par))
(setvar 'clayer "pipe")
(if (setq ss (ssget "_:L" '((0 . "*POLYLINE") (8 . "pipe root"))))
(repeat (setq n (sslength ss))
(setq pl (ssname ss (setq n (1- n))))
(repeat (setq m (fix (vlax-curve-getEndParam pl)))
(command "_.insert" "pipe"
"_X" (/ (distance (gpap m) (gpap (1- m))) 100)
"_non" (gpap (- m 0.5)); insertion point
"_non" (gpap m); rotation
); command
(setq m (1- m))
); repeat
(entdel pl)
); repeat
); if
(command "_.layerp")
(prin1)
); defun
It works on open or closed Polylines, "heavy" or "lightweight." Of course, it's suitable only to Polylines made up of only line segments -- your Block approach to pipe segments couldn't handle arc segments no matter what, anyway.
And it can use all the usual bells and whistles [*error* handling, creating the Layer if needed, Undo begin/end wrapping, etc.) and maybe some specialized ones [e.g. verify only line segments].
Kent Cooper, AIA
@ec-cad wrote:
I see (command "_.layerp") ?
Never saw that one before, is that 'layer' Previous ?
It's in there [in Help, that is].
Kent Cooper, AIA
@ec-cad wrote:
See also sys var 'LAYERPMODE'.
I wasn't aware of that one. [Curiously, while it sure looks like a System Variable name, and its effect seems exactly like a System Variable, it isn't one -- it's really a Command, at least in Acad2020 that I have here]
Kent Cooper, AIA
