Get attribute values
@Anonymous wrote:
What I'm hoping to do with the second routine is to run it in paper space, even though the blocks are in model space.
Post a sample .dwg with the blocks...
The block in model space, and the 'Note Number' in a layout...
Henrique
Hi Larry,
in model we have a dynamic block 'NOTE_FLAG1' with four attributes, NOTE#, NOTE, ANSWER and SKETCH.
In a layout we have a dynamic block 'NOTE#' with two attributes, NOTE and ANSWER.
So, let's see if I have understood.
you need to select the 'NOTE_FLAG1' in model, store the att values, select the 'NOTE#' in a layout, and copy NOTE# to NOTE, and ANSWER to ANSWER, I'm correct?
Henrique
Hi Larry,
quick and dirty, and as a starting point.
Assumes "NOTE#" definition already exists, and I have declared 'att_lst' as a local variable, if you're gonna need the other attribute values for a later use, we'll have to add that in this code...
(vl-load-com)
(defun c:demo ( / att_lst atts atts1 obj obj1 pt s1 tab)
(if (and
(= (getvar "tilemode") 0)
(= (getvar "cvport") 1)
)
(if (setq pt (getpoint "\nSpecify \"NOTE#\" insertion point: "))
(progn
(setq tab (getvar 'CTAB))
(setvar 'CTAB "Model")
(if (and (setq s1 (ssget "_+.:E:S" '((0 . "INSERT") (66 . 1))))
(setq obj (vlax-ename->vla-object (ssname s1 0)))
(eq (vla-get-effectivename obj) "NOTE_FLAG1")
)
(progn
(setq atts (vlax-safearray->list (vlax-variant-value (vla-getattributes obj))))
(foreach att atts
(setq att_lst (cons (cons (vla-get-tagstring att) (vla-get-textstring att)) att_lst))
)
(setvar 'CTAB tab)
(setq obj1 (vlax-invoke
(vlax-get-property
(vla-get-activedocument (vlax-get-acad-object))
'paperspace
)
'insertblock
pt
"NOTE#"
1.0
1.0
1.0
0.0
)
)
(setq atts1 (vlax-safearray->list (vlax-variant-value (vla-getattributes obj1))))
(foreach att atts1
(if (eq (vla-get-tagstring att) "NOTE")
(vla-put-textstring att (cdr (assoc "NOTE#" att_lst)))
)
)
)
(princ "\n\"NOTE_FLAG1\" not selected...")
)
)
)
(princ "\nYou'll need to be in paper space to run this code... ")
)
(princ)
)
Hope this helps,
Henrique
@Anonymous wrote:
That worked perfectly for inserting the "NOTE#" block with the note number
Now, I need to add this (COMMAND "MTEXT" P1 "H" "0.1" "W" "3.65" NOT "") to the routine. Where NOT is the value of the NOTE attribute from the block "NOTE_FLAG1"
I'll set the P1 variable
As I said earlier
'Quick and dirty, and as a starting point.
Assumes "NOTE#" definition already exists...'
We'll have to test if "NOTE#" is already defined in dwg, if not, test if is found in SFSP...
(vl-load-com)
(defun c:demo (/ att_lst atts atts1 obj obj1 pspace pt s1 tab)
(if (and
(= (getvar "tilemode") 0)
(= (getvar "cvport") 1)
)
(if (setq pt (getpoint "\nSpecify \"NOTE#\" insertion point: "))
(progn
(setq tab (getvar 'CTAB))
(setvar 'CTAB "Model")
(if (and (setq s1 (ssget "_+.:E:S" '((0 . "INSERT") (66 . 1))))
(setq obj (vlax-ename->vla-object (ssname s1 0)))
(eq (vla-get-effectivename obj) "NOTE_FLAG1")
)
(progn
(setq atts (vlax-safearray->list (vlax-variant-value (vla-getattributes obj))))
(foreach att atts
(setq att_lst (cons (cons (vla-get-tagstring att) (vla-get-textstring att)) att_lst))
)
(setvar 'CTAB tab)
(setq pspace (vla-get-paperspace (vla-get-activedocument (vlax-get-acad-object))))
(setq obj1 (vlax-invoke
pspace 'insertblock pt "NOTE#" 1.0 1.0 1.0 0.0)
)
(setq atts1 (vlax-safearray->list (vlax-variant-value (vla-getattributes obj1))))
(foreach att atts1
(if (eq (vla-get-tagstring att) "NOTE")
(vla-put-textstring att (cdr (assoc "NOTE#" att_lst)))
)
)
(setq
obj (vla-addmtext pspace (vlax-3d-point (polar pt 0.435667 0.319844)) 3.7 (cdr (assoc "NOTE" att_lst)))
)
(vla-put-height obj 0.1)
(vla-put-width obj 3.65)
)
(princ "\n\"NOTE_FLAG1\" not selected...")
)
)
)
(princ "\nYou'll need to be in paper space to run this code... ")
)
(princ)
)
Hope this helps,
Henrique