find block by selected text

[E.S.7.9]

hello

i have text list in my drawing and these text values also embedded to block names .. i wanted to find blocks which contain selected text value via lisp 

could anybody share with me the lisp code something like that . please ? 

thank you 

[dbhunia]

Post a sample drawing...... 

[E.S.7.9]

i attached simple drawing which explains what i eant to do ..

thanks again

[dbhunia · Accepted solution]

Try this......

(defun c:sbbt (/ st ss ssb N)
(vl-load-com)
(setvar 'cmdecho 0)
(setq st (cdr (assoc 1 (entget(car(entsel "\nSelect Text..."))))))
(setq ss (ssget "_A" '((0 . "INSERT"))))
(setq ssb (ssadd))
(repeat (setq N (sslength ss))
	(setq Data (ssname SS (setq N (- N 1))))
	(setq EntityData (entget Data))
	(setq bn (cdr (assoc 2 EntityData)))
	(if (/= nil (vl-string-search st bn)) (ssadd Data ssb))
)
(if (/= 0 (sslength ssb)) (sssetfirst nil ssb)(princ "\nNo Block Found by this Name....."))
(setvar 'cmdecho 1)
(princ)
)

[ronjonp · Accepted solution]

Alternatively you could filter directly like so:

(defun c:foo (/ e s)
  (cond	((and (setq e (car (entsel "\nPick your text: "))) (setq s (cdr (assoc 1 (entget e)))))
	 (setq s (ssget "_X" (list '(0 . "insert") (cons 2 (strcat "*" s "*")))))
	 (and s (sssetfirst nil s) (print (strcat (itoa (sslength s)) " blocks found...")))
	)
  )
  (princ)
)