Extracting insertion point of invisible attributes in a block
@cdmiske wrote:
Hello all. I am looking around the interwebs to find out how to extract the insertion point of a n invisible attribute in a block. So far I have not had much luck. I am assuming it can be done with dotted pairs but need to know what I am looking for in order to make that happen. If anyone has any idea or info on how I might be able to do that would be greatly appreciated. Thank you in advance.
Check for property "Invisible" , if true or -1 , extract property Insertion point.
(defun c:demo2 ( / blockwithattribute)
(if (setq blockwithattribute (ssget "_+.:S:E" '((0 . "INSERT")(66 . 1))))
(foreach itm
(vlax-invoke
(vlax-ename->vla-object (ssname blockwithattribute 0))
'GetAttributes)
(if (minusp (vlax-get itm 'Invisible))
(progn(princ (Strcat "\nTag " (vla-get-tagstring itm)))
(print (Vlax-get itm 'InsertionPoint))))))
(princ)
)
HTH
(defun c:demo ( / blockwithattribute n e )
(if (setq blockwithattribute (ssget "_+.:S:E" '((0 . "INSERT") (66 . 1))))
(progn
(setq n (entnext (ssname blockwithattribute 0)))
(while (not (eq (cdr (assoc 0 (setq e (entget n)))) "SEQEND"))
(if (and (not (eq (cdr (assoc 1 e)) nil))
(= (cdr (assoc 70 e)) 1))
(progn
(princ (Strcat "\nTag " )) (Cdr (assoc 2 e))
(print (cdr (assoc 10 e))))
)
(setq n (entnext n))
)
)
)
(princ)
)
(defun c:attr_ins (/ e ent p lst)
(setq e (car (entsel "\nSelect block >")))
(while (setq e (entnext e))
(setq ent (entget e))
(setq p (cdr(assoc 0 ent)))
(if (and (eq p "ATTRIB") (= (cdr (assoc 70 ent)) 1))(setq lst (cons (list (cdr(assoc 2 ent)) (cdr(assoc 10 ent))) lst)))
)
(reverse lst)
)Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@cdmiske wrote:
Greatly appreciated! I can see I still have much to learn on how to extract data from objects in autolisp. At least I was heading in the right direction with (0, "insert") just had quite a bit more to learn in order to accomplish what I was needing.
Good for you @cdmiske , just keep at it. you'll get there, we all have to start somewhere 😊
And you are welcome
@cdmiske wrote:
.... The objective in using this info is to create an insertion point for a mleader to label blocks in a selection.
Then I think you're going to have to do some further conversion to make use of the information. The positional data stored for an Attribute [or anything else] in a Block definition is relative to the Block's defined insertion point as virtual 0,0 location, not in terms of coordinates in the drawing that Block is inserted in. It's easy enough to add that information to the Block's in-the-drawing insertion point, provided the Block is at scale factors of +1 and rotation of 0. It gets far more complicated if other scales and/or rotations are possible.
@cdmiske wrote:
.... What I am trying to figure out is the piece after the ssget, "_+.:S:E". I am curious to know if that is another dotted pair call and also want to know what is it referring to? ....
That's making (ssget)'s selection emulate (entsel)'s, limited to one object by point pick. See Lee Mac's page about (ssget) modes and options, some of which are unaccountably undocumented in the AutoLisp Reference.
@cdmiske wrote:
I have a question, as it is not showing up easily in google searches. Per @Kent1Cooper suggestion that the insertion point of the attribute is relative to the Block's defined insertion point ..
Yup, leave it to kent to find small things that get past us mere mortals. Need to look into that really.
@cdmiske wrote:
"Mysteries of Autodesk's caves" ...
Me likey 🙂
@cdmiske wrote:
What I am trying to figure out is the piece after the ssget, "_+.:S:E". I am curious to know if that is another dotted pair call and also want to know what is it referring to? Thank you for all your help so far.
Want to know more about ssget filters and their usage? look no further ->> SSGET Function Format by Lee Mac
You will find all that under Filter List Operators.
Its great to know that you're keen on learning all that by researching first then ask later , kudos to you @cdmiske
👍
EDIT: Kent posted the same link, fast draw kent is. [ Yoda ]
@cdmiske wrote:
As I am looking into this I am guessing I could set a list to look for all the named attributes that are to be labeled and use a (repeat (sslength [list])) cycle to make sure that each attribute in the list is labeled contained within the block before cycling to the next block.
Along with the previous post, its a lot to take in in one seating @cdmiske
In a nutshell, what you're trying to achive is to label ALL parts of the block where an invisible attribue is found correct?
And you dont want to select the block the second time
(setq inspnt (ssget "_+.:S:E" '((0 . "INSERT") (66 . 1))))after the initial call to ssget...
(setq ent (SSget))
I will make a similar one, and you can disect the code and learn from it.
Sounds go to you?
@cdmiske wrote:
So far I have been able to get everything to work as I hoped to. I am figuring that the order of operations is need to be adjusted. So digging through tutorials and books along with trying to experiment on rearranging the code to see if I can make things work in the order I am thinking it need to flow.
Here it is [ tested on your sample drawing ]
(defun c:demo (/ indexNumber SelectedBlocksWithAttribute
ObjectAtIndexPositiononSelectionSet
entityData )
(if (setq indexNumber 0
; this ensures the selection has attributes ;
SelectedBlocksWithAttribute (SSget '((0 . "INSERT") (66 . 1)))
)
(repeat (sslength SelectedBlocksWithAttribute)
(setq ObjectAtIndexPositiononSelectionSet
(ssname SelectedBlocksWithAttribute indexNumber)
) ;_ end of setq
(while (setq ObjectAtIndexPositiononSelectionSet
(entnext ObjectAtIndexPositiononSelectionSet)
) ;_ end of setq
(setq entityData (entget ObjectAtIndexPositiononSelectionSet))
(setq ObjectType (cdr (assoc 0 entityData)))
; This line only include invisible attribites ;
(if (and (eq ObjectType "ATTRIB")
(= (cdr (assoc 70 entityData)) 1)
) ;_ end of and
(progn
(command "_Point" "_non" (cdr (assoc 10 entityData)))
(print (cdr (Assoc 1 entityData)))
) ;_ end of progn
) ;_ end of if
) ;_ end of while
(setq indexNumber (1+ indexNumber))
) ;_ end of repeat
) ;_ end of if
(princ)
) ;_ end of defun
Now if you want to target specific TAG names, add these lines
...
(Setq targetTags '("ACCESS" "OTHERTAGS")) (if (setq indexNumber 0 ; this ensures the selection has attributes ; SelectedBlocksWithAttribute (SSget '((0 . "INSERT") (66 . 1))) ) ... (and (eq ObjectType "ATTRIB") (= (cdr (assoc 70 entityData)) 1) (member (cdr (assoc 2 entityData)) targetTags) )
Hope this helps
Right now , all it does is place a point entity on the insertionpoint of the attribute and print the value on the commandline.
@cdmiske wrote:
I am learning quite a bit on this one and semi abandoned the other things I am working on as my position was eliminated working on developing restaurants. Luckily I was able to get a new gig working on VA hospitals and specifically developing tools improve performance and develop design standards / template systems to help normalize the department.
We are all affected by the pandemic one way or the another @cdmiske . A lot in our industry here was given a choice between a salary cut or the highway. Its good to know that you decided to learn all this on your own time. Kudos to you. 👍
@cdmiske wrote:
I am also thinking that I would be better off using a foreach to cycle through each block or maybe for both the block and the attribute list. I still confuse myself on when to use foreach,while, and repeat. Is there a rule of thumb I can use for guidance?
All three functions are equally fast.
- Foreach process the items from a list a based on the its length
- Repeat as the name implies evaluates expression by a specified number of times via int value
Both will run its course at an exact number of times specified by the supplied argument. With while on the other hand will continue to run an expression until the main condition evaluates to nil, you can terminate the loop at at given condition.
Functions Reference (AutoLISP)
HTH
@cdmiske wrote:
I do have a unique glitch happening. In the attached block if you run the lisp and only select the handicap
There is a glitch and it's not yoursbut mine. My bad, I should've picked up on that before i posted.
For that I apologize @cdmiske
(defun c:note ( / indexNum obj ent items ent entityData )
(setq targetTags '("ACCESS""ACCESS2""ACCESS3" "MARK"))
(if (setq indexNum 0
obj (SSget '((0 . "INSERT") (66 . 1)))
)
(repeat (sslength obj)
(setq ent (ssname obj indexNum))
(while (and (setq ent (entnext ent))
(= "ATTRIB" (cdr (assoc 0 (setq entityData (entget ent))))))
(if
(and
(not (eq (cdr (assoc 1 entityData)) nil))
(= (cdr (assoc 70 entityData)) 1)
(member (cdr (assoc 2 entityData)) targetTags)
)
(progn
(print
(itoa (vla-get-objectid
(vlax-ename->vla-object
(entnext (cdr (assoc 330 entityData)))
)
)
)
)
(print (cdr (assoc 2 entityData)))
(command "mleader"
(cdr (assoc 10 entityData))
(list (+ (car (cdr (assoc 10 entityData))) 12)
(+ (cadr (cdr (assoc 10 entityData))) 12)
(caddr (cdr (assoc 10 entityData)))
)
(strcat (cdr (Assoc 1 entityData)))
)
)
)
)
(setq indexNum (1+ indexNum))
)
)
(princ)
)
HTH
