Error when adding a wcmatch to a conditional inside a loop

[TaytaRuiz]

Hello everyone,

I have been using a functioning LISP that turns all the SOLID hatches to a specific hatch. Now I wanted to add a conditional filter for layers with 

(wcmatch (vla-get-layer x) "*MASS*")

but I only obtain errors.

The two codes that I tried in AutoCAD 2021 and that return "nil" results are below. In the first I added it in line 5 and in the second in line 7:

(defun c:hdwsol2was ( / doc )
   (vlax-for blk (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
       (if (= :vlax-false (vla-get-isxref blk))
           (vlax-for obj blk
               (if 
                   (and
                       (wcmatch (vla-get-layer x) "*MASS*")
                       (= "AcDbHatch" (vla-get-objectname obj))
                       (= "SOLID" (strcase (vla-get-patternname obj)))
                       (vlax-write-enabled-p obj)
                   )
                   (progn
                       (vla-setpattern obj achatchpatterntypepredefined "CORK")
                       (vla-put-patternscale obj 50)
                   )
               )
           )
       )
   )
   (vla-regen doc acallviewports)
   (princ)
)
(vl-load-com) (princ)

(defun c:hdwsol2was ( / doc )
   (vlax-for blk (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
       (if (= :vlax-false (vla-get-isxref blk))
           (vlax-for obj blk
               (if (wcmatch (vla-get-layer x) "*MASS*")
                   (and
                       (= "AcDbHatch" (vla-get-objectname obj))
                       (= "SOLID" (strcase (vla-get-patternname obj)))
                       (vlax-write-enabled-p obj)
                   )
                   (progn
                       (vla-setpattern obj achatchpatterntypepredefined "CORK")
                       (vla-put-patternscale obj 50)
                   )
               )
           )
       )
   )
   (vla-regen doc acallviewports)
   (princ)
)
(vl-load-com) (princ)

I'd appreciate it if anyone could point to my error.

Thank you.

Eloy

[ВeekeeCZ · Accepted solution]

get layer of x ??

[hak_vz · Accepted solution]

(wcmatch (vla-get-layer x) "*MASS*")

It should stand

(wcmatch (vla-get-layer obj) "*MASS*")

[TaytaRuiz]

Thank you both,
I changed it and now the first variant does what I want, but not the second.
In my head they mean the same, so I'd assume that I still have some reading to do about conditionals and loops.

(defun c:hdwsol2was ( / doc )
   (vlax-for blk (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
       (if (= :vlax-false (vla-get-isxref blk))
           (vlax-for obj blk
               (if 
                   (and
				       (wcmatch (vla-get-layer obj) "*MASS*")
                       (= "AcDbHatch" (vla-get-objectname obj))
                       (= "SOLID" (strcase (vla-get-patternname obj)))
                       (vlax-write-enabled-p obj)
                   )
                   (progn
                       (vla-setpattern obj achatchpatterntypepredefined "net3")
                       (vla-put-patternscale obj 50)
                   )
               )
           )
       )
   )
   (vla-regen doc acallviewports)
   (princ)
)
(vl-load-com) (princ)

 
Cheers

[ВeekeeCZ]

Well, it should. Post a dwg sample that gives you the error.

[hak_vz]

@TaytaRuiz 

Code works as it should. Create solid pattern objects in layer *mass* (it has mass in its name) and convert to block.

Run code and it changes block pattern to net3

[Sea-Haven]

Is it non Autocad may need "NET3" agree works.