Error no function definition VLAX-CURVE-GETENDPARAM

[noble_eye]

Hi,

Ive installed this 'plugin' TOTALLENGTH to my AutoCAD 2020. Before this, it just work fine. But suddenly, now, it shows this error:

error: no function definition: VLAX-CURVE-GETENDPARAM

ive tried to load and unload the 'plugin', restarting my CAD, and flattening the polylines. still doesn't work.

Help!

[Automohan]

No need of installing for this such a small software for small job, Just a loading of Autolisp

From where did you downloaded that plug-in ?

Below Routine at https://www.lee-mac.com/totallengthandarea.html 

---

---

;;--------------------=={ Total Length }==--------------------;;
;;                                                            ;;
;;  Displays the total length of selected objects at the      ;;
;;  command line. The units and precision format of the       ;;
;;  printed result is dependent upon the settings of the      ;;
;;  LUNITS & LUPREC system variables respectively.            ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2013 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;

(defun c:tlen ( / e i l s )
    (if (setq s
            (ssget
               '(   (0 . "ARC,CIRCLE,ELLIPSE,LINE,*POLYLINE,SPLINE")
                    (-4 . "<NOT")
                        (-4 . "<AND")
                            (0 . "POLYLINE") (-4 . "&") (70 . 80)
                        (-4 . "AND>")
                    (-4 . "NOT>")
                )
            )
        )
        (progn
            (setq l 0.0)
            (repeat (setq i (sslength s))
                (setq e (ssname s (setq i (1- i)))
                      l (+ l (vlax-curve-getdistatparam e (vlax-curve-getendparam e)))
                )
            )
            (princ "\nTotal Length: ")
            (princ (rtos l))
        )
    )
    (princ)
)
(vl-load-com) (princ)

[paullimapa]

VLAX-CURVE-GETENDPARAM should work: 

https://help.autodesk.com/view/OARX/2024/ENU/?guid=GUID-B939A11A-DF89-4450-B520-11D59BD2A126

Perhaps you need to enter this first:

(vl-load-com) (princ)