Edit lisp help

[chan230984]

Hi all,

I'm looking for some help editing a lisp

I have Lisp and I want some help.
After Command asks Next level Position, I want to select object of the all circle.
And get results as in the picture

thanks !

(defun LM:UnFormat ( str mtx / _replace rx )
(defun _replace ( new old str )
(vlax-put-property rx 'pattern old)
(vlax-invoke rx 'replace str new)
)
(if (setq rx (vlax-get-or-create-object "VBScript.RegExp"))
(progn
(setq str
(vl-catch-all-apply
(function
(lambda ( )
(vlax-put-property rx 'global actrue)
(vlax-put-property rx 'multiline actrue)
(vlax-put-property rx 'ignorecase acfalse)
(foreach pair
'(
("\032" . "\\\\\\\\")
(" " . "\\\\P|\\n|\\t")
("$1" . "\\\\(\\\\[ACcFfHLlOopQTW])|\\\\[ACcFfHLlOopQTW][^\\\\;]*;|\\\\[ACcFfHLlOopQTW]")
("$1$2/$3" . "([^\\\\])\\\\S([^;]*)[/#\\^]([^;]*);")
("$1$2" . "\\\\(\\\\S)|[\\\\](})|}")
("$1" . "[\\\\]({)|{")
)
(setq str (_replace (car pair) (cdr pair) str))
)
(if mtx
(_replace "\\\\" "\032" (_replace "\\$1$2$3" "(\\\\[ACcFfHLlOoPpQSTW])|({)|(})" str))
(_replace "\\" "\032" str)
)
)
)
)
)
(vlax-release-object rx)
(if (null (vl-catch-all-error-p str))
str
)
)
)
)
(vl-load-com)
(defun c:chm ( / level p0 p1)
(setvar "cmdecho" 0)
(command "._undo" "_begin")
(if (and (setq level (atof (LM:UnFormat (cdr (assoc 1 (entget (car (entsel "\nFirst level: "))))) nil)))
(setq p1 (getpoint "\nSpecify first level position: "))
)
(progn
(setq p0 p1)
(command "._leader" p1 "@0.65<45" "" (strcat "EL=" (rtos level 2 3)) "")

(while (setq p1 (getpoint "\nSpecify next level position: "))
(command "._leader" p1 "@0.65<45" "" (strcat "EL=" (rtos (+ level (- (cadr p1) (cadr p0))) 2 3)) "")
)
); progn
); if
(command "._undo" "_end")
(setvar "cmdecho" 1)
(princ)
)

[pbejse]

---

@chan230984 wrote:

After Command asks Next level Position, I want to select the object of the circle.

---

How is that different from selecting the center of the circle ?

That appears to be working fine @chan230984 

[chan230984]

@pbejse 

I have a lot of circles
And it will make my work faster If I select all circle, just one click.

[chan230984]

@pbejse  I typed it wrong

select all circle not a circle

[pbejse · Accepted solution]

---

@chan230984 wrote:

@pbejse 

I have a lot of circles
And it will make my work faster If I select all circle, just one click.

---

You want to select mulitple cirlces?

(defun c:chm ( / level p0 p1)
(setvar "cmdecho" 0)
(command "._undo" "_begin")
(if (and (setq level (atof (LM:UnFormat (cdr (assoc 1 (entget (car (entsel "\nFirst level: "))))) nil)))
         (setq p1 (getpoint "\nSpecify first level position: "))
	 (null 
	   (command "._leader" p1 "@0.65<45" "" (strcat "EL=" (rtos level 2 3)) "")
	   )
	 (princ "\nSelect Circle object for Next level position: ")
	 (setq circles (setq on (ssget  '((0 . "Circle")))))
    )
      	(repeat (setq i (sslength circles))
	  (setq p0 p1)
		(setq p1 (cdr (assoc 10 (entget (ssname circles (setq i (1- i)))))))
			(command "._leader" p1 "@0.65<45" "" (strcat "EL=" (rtos (+ level (- (cadr p1) (cadr p0))) 2 3)) "")
	) 
); if
(command "._undo" "_end")
(setvar "cmdecho" 1)
(princ)
)

[chan230984]

@pbejse 

Hi friend, Please Edit this Lisp again Because something wrong

thank you !

[Kent1Cooper]

I suspect this much:

....
  (repeat (setq i (sslength circles))
    (setq p0 p1)
    (setq p1 (cdr (assoc 10 (entget (ssname circles (setq i (1- i)))))))
    (command "._leader" p1 "@0.65<45" ""
      (strcat "EL=" (rtos (+ level (- (cadr p1) (cadr p0))) 2 3))
      ""
    )
....

should be more like this:

....
  (repeat (setq i (sslength circles))
    ;;;;; (setq p0 p1) ; not needed -- all in relation to 'level' value, not previous Circle
    (setq p1 (cdr (assoc 10 (entget (ssname circles (setq i (1- i)))))))
    (command "._leader" p1 "@0.65<45" "" (strcat "EL=" (rtos (+ level (- (cadr p1) level)) 2 3)) "")
.... 

[chan230984]

@Kent1Cooper 

Not yet

[pbejse]

Is it all good now? 

[chan230984]

@pbejse 

not

[pbejse]

---

@chan230984 wrote:

@pbejse 

not

---

Remind me again what the lisp code is about? can you please post the equivalent drawing sample of the imaghe you posted and show the "correct" results.

[chan230984]

@pbejse 

Sorry I am not good an English

Please see Picture Below

[pbejse · Accepted solution]

(defun c:chm ( / level p0 p1)
(setvar "cmdecho" 0)
(command "._undo" "_begin")
(if (and (setq level (atof (LM:UnFormat (cdr (assoc 1 (entget (car (entsel "\nFirst level: "))))) nil)))
         (setq p1 (getpoint "\nSpecify first level position: "))
	 (null 
	   (command "._leader" p1 "@0.65<45" "" (strcat "EL=" (rtos level 2 3)) "")
	   )
	 (princ "\nSelect Circle object for Next level position: ")
	 (setq p0 p1 circles (setq on (ssget  '((0 . "Circle")))))
    )
      	(repeat (setq i (sslength circles))
		(setq p1 (cdr (assoc 10 (entget (ssname circles (setq i (1- i)))))))
			(command "._leader" p1 "@0.65<45" "" (strcat "EL=" (rtos (+ level (- (cadr p1) (cadr p0))) 2 3)) "")
	) 
); if
(command "._undo" "_end")
(setvar "cmdecho" 1)
(princ)
)

HTH 

[chan230984]

@pbejse 

thanks again! you are a good man

[pbejse]

---

@chan230984 wrote:

@pbejse 

thanks again! you are a good man

---

Good for you, You are welcome.