Community
You're welcome!
Please be aware that the set of attribute functions to which I have referred are not complete programs, but functions to be called from other programs with the required parameters as noted in the comments.
Ask if you need help using the functions in your program.
Lee
No need to apologise, I welcome the questions and appreciate that you are trying to learn.
For this task, I would recommend utilising my Vanilla AutoLISP Set Attribute Values function (either recursive or iterative, it doesn't matter for this task). This function requires an attributed block entity name argument and an association list of tags & values to be set in the supplied block.
Below I have put together a fully-commented example program to demonstrate how you might call this function to operate on your blocks:
(defun c:attchange ( / i l s x )
;; Define function, declare local variable symbols.
;; To understand why variable declaration is important, see http://bit.ly/15Qw104
(if ;; If we can retrieve a set of attributed blocks
(setq s ;; Assign the selection set pointer to variable 's'
(ssget "_X" ;; Search entire database (see http://bit.ly/137NmOJ for more info)
'(
(0 . "INSERT") ;; Block References
(66 . 1) ;; Attributed
(2 . "WD_MLRH") ;; with name WD_MLRH (this assumes block is non-dynamic)
)
) ;; end SSGET
) ;; end SETQ
(progn
;; Evaluate the following expressions and return the result
;; of the last expression evaluated. PROGN is used as a
;; wrapper function so that we can pass multiple expressions
;; to the IF function as a single argument constituting the
;; 'then' parameter.
(initget 6) ;; (+ 2 4): 2=prevent zero, 4=prevent negative
(if (setq x (getint "\nEnter first rung number: ")) ;; Prompt user for rung number > 0
(progn
;; See above explanation for PROGN
;; Construct an association list of attribute tags & values
;; to pass to the LM:setattributevalues function
(setq l
(cons
(cons "RUNGFIRST" (itoa x)) ;; => e.g. ("RUNGFIRST" . "2")
;; Use a quoted literal list for the remaining tags/values
;; as there are no expressions to be evaluated.
;; For an explanation of the apostrophe, see http://bit.ly/1bW3rQK
'(
("RUNGCNT" . "20")
("RUNGDIST" . "1")
)
) ;; end CONS
) ;; end SETQ
;; The resulting list might look like this:
;; l = (("RUNGFIRST" . "2") ("RUNGCNT" . "20") ("RUNGDIST" . "1"))
;; Repeat the following expressions a number of times
;; equal to the number of items in the selection set.
;; Note that the numerical argument for the repeat function
;; is only evaluated once and hence the integer index variable 'i'
;; will only be assigned a value once.
(repeat (setq i (sslength s))
;; Call the LM:setattributevalues function with the block entity name
;; and association list of attribute tags/values to be set.
(LM:SetAttributeValues (ssname s (setq i (1- i))) l)
) ;; end REPEAT
) ;; end PROGN
) ;; end IF
) ;; end PROGN
;; Else no blocks were found...
(princ "\nNo \"WD_MLRH\" blocks were found.")
) ;; end IF
(princ) ;; Supress the return of the last evaluated expression
) ;; end DEFUN
;; Set Attribute Values - Lee Mac
;; Sets the block attributes whose tags are found in the supplied
;; assocation list to their associated values.
;; Arguments:
;; blk - [ent] Block (Insert) Entity Name
;; lst - [lst] Association list of ((<TAG> . <Value>) ... )
;; Returns: nil
(defun LM:SetAttributeValues ( blk lst / enx itm )
(if (= "ATTRIB" (cdr (assoc 0 (setq enx (entget (setq blk (entnext blk)))))))
(if (setq itm (assoc (strcase (cdr (assoc 2 enx))) lst))
(progn
(if (entmod (subst (cons 1 (cdr itm)) (assoc 1 enx) enx))
(entupd blk)
)
(LM:SetAttributeValues blk lst)
)
(LM:SetAttributeValues blk lst)
)
)
)
(princ) ;; Suppress the return of any loading expressions
Do not hesitate to ask if you have any questions about the code.
Lee
@Anonymous wrote:Lee_Mac
This is an amazing explanation, thanks!
The routine works great as well.
Thank you Tom, I'm glad my explanations were comprehensible! 
@Anonymous wrote:I am, however, running into an issue with a maximum integer value, where the value for RUNGFIRST must be between 1 and 32767. Is there a way to increase this number to 50000 or more?
This is a remnant from the early days of AutoLISP: the getint function assumes that integers are stored as 16-bit signed integers, and hence limited to a range of -32,768 to 32,767 (under two's complement).
Compare that to the 32-bit & 64-bit signed integers which we use nowadays, which have respective ranges of -2,147,483,648 to 2,147,483,647 (32-bit) and -9,223,372,036,854,775,808 to 9,223,372,036,854,775,807 (64-bit)...
To circumvent the issue, prompt the user with the getreal function and then use the fix function to convert the real (double) to an integer.
Close! But the issue is because you did not assign the new value to the variable 'x' after converting the double (real) value to an integer.
Consider the following code:
(defun c:attchange ( / i l s x )
;; Define function, declare local variable symbols.
;; To understand why variable declaration is important, see http://bit.ly/15Qw104
(if ;; If we can retrieve a set of attributed blocks
(setq s ;; Assign the selection set pointer to variable 's'
(ssget "_X" ;; Search entire database (see http://bit.ly/137NmOJ for more info)
'(
(0 . "INSERT") ;; Block References
(66 . 1) ;; Attributed
(2 . "WD_MLRH") ;; with name WD_MLRH (this assumes block is non-dynamic)
)
) ;; end SSGET
) ;; end SETQ
(progn
;; Evaluate the following expressions and return the result
;; of the last expression evaluated. PROGN is used as a
;; wrapper function so that we can pass multiple expressions
;; to the IF function as a single argument constituting the
;; 'then' parameter.
(initget 6) ;; (+ 2 4): 2=prevent zero, 4=prevent negative
(if (setq x (getreal "\nEnter first rung number: ")) ;; Prompt user for rung number > 0
(progn
;; See above explanation for PROGN
;; Construct an association list of attribute tags & values
;; to pass to the LM:setattributevalues function
(setq l
(cons
(cons "RUNGFIRST" (itoa (fix x))) ;; => e.g. ("RUNGFIRST" . "2")
;; Use a quoted literal list for the remaining tags/values
;; as there are no expressions to be evaluated.
;; For an explanation of the apostrophe, see http://bit.ly/1bW3rQK
'(
("RUNGCNT" . "20")
("RUNGDIST" . "1")
)
) ;; end CONS
) ;; end SETQ
;; The resulting list might look like this:
;; l = (("RUNGFIRST" . "2") ("RUNGCNT" . "20") ("RUNGDIST" . "1"))
;; Repeat the following expressions a number of times
;; equal to the number of items in the selection set.
;; Note that the numerical argument for the repeat function
;; is only evaluated once and hence the integer index variable 'i'
;; will only be assigned a value once.
(repeat (setq i (sslength s))
;; Call the LM:setattributevalues function with the block entity name
;; and association list of attribute tags/values to be set.
(LM:SetAttributeValues (ssname s (setq i (1- i))) l)
) ;; end REPEAT
) ;; end PROGN
) ;; end IF
) ;; end PROGN
;; Else no blocks were found...
(princ "\nNo \"WD_MLRH\" blocks were found.")
) ;; end IF
(princ) ;; Supress the return of the last evaluated expression
) ;; end DEFUN
;; Set Attribute Values - Lee Mac
;; Sets the block attributes whose tags are found in the supplied
;; assocation list to their associated values.
;; Arguments:
;; blk - [ent] Block (Insert) Entity Name
;; lst - [lst] Association list of ((<TAG> . <Value>) ... )
;; Returns: nil
(defun LM:SetAttributeValues ( blk lst / enx itm )
(if (= "ATTRIB" (cdr (assoc 0 (setq enx (entget (setq blk (entnext blk)))))))
(if (setq itm (assoc (strcase (cdr (assoc 2 enx))) lst))
(progn
(if (entmod (subst (cons 1 (cdr itm)) (assoc 1 enx) enx))
(entupd blk)
)
(LM:SetAttributeValues blk lst)
)
(LM:SetAttributeValues blk lst)
)
)
)
(princ) ;; Suppress the return of any loading expressions
You're very welcome Thomas, I hope you can learn from the code
Forums Links
Can't find what you're looking for? Ask the community or share your knowledge.
Post to forums
