Dynamic Block Visibility States

[chris_lee_3]

Cordial greetings all,

I am reluctant to ask about using a lisp to change the visibility state of a dynamic block since there are so many posts about this topic. However, I am not seeing any that do the straightforward task of changing a specific block’s visibility state. Perhaps I have stumbled across one, but I am not knowledgeable enough to recognize it.  Any help with this is appreciated.

The scenario I am after is to change the visibility state of block 1 from visibility state “on” to visibility state “off”.

[_gile]

Hi,

One way (the simplest one, IMO) is to use the setpropertyvalue function.

For dynamic properties, the syntax is:

(setpropertyvalue ename "AcDbDynBlockProperty<propertyName>" value)

Assuming the property name is: "Visibility1", you could use this:

(setpropertyvalue (car (entsel)) "AcDbDynBlockPropertyVisibility1" "Off")

[chris_lee_3]

Thank you, in the morning I will Jetez un coup d’œil and see if I can understand it.

[Sea-Haven]

This is a dcl solution uses Multi radio buttons.lsp a library function that can be used in any code.

; Change dynamic block properties when inserting look at properties available.
; By Alan H June 2022

;; Get Dynamic Block Property Allowed Values  -  Lee Mac
;; Returns the allowed values for a specific Dynamic Block property.
;; Set Dynamic Block Visibility State  -  Lee Mac
;; Sets the Visibility Parameter of a Dynamic Block (if present) to a specific value (if allowed)
;; Get Visibility Parameter Name  -  Lee Mac
;; Returns the name of the Visibility Parameter of a Dynamic Block (if present)

(defun insdynv (blkname / pt obj lst ans)
(if (not LM:setdynpropvalue )(load "Lee-mac Dynamic block get-put"))
(setq pt (getpoint "\nPick a pt for block "))
(command "-insert" blkname "s" 1  pt 1  0)
(setq obj (vlax-ename->vla-object (entlast)))
(setq visval (LM:getvisibilityparametername obj))
(setq lst (LM:getdynpropallowedvalues obj visval))
(setq lst (cons "Please choose" lst))
(if (not AH:Butts)(load "Multi Radio buttons.lsp"))
(if (not AHbut)(setq AHbut 1))
(setq ans (ah:butts 1 "v"  lst))
(LM:SetVisibilityState obj ans)
(princ)
)

; set existing block visibilty

(defun insdyne (blkname / pt obj lst ans)
(if (not LM:setdynpropvalue )(load "Lee-mac Dynamic block get-put"))
(if (not AH:Butts)(load "Multi Radio buttons.lsp"))
(setq obj (vlax-ename->vla-object (car (entsel "\nPick a dynamic block "))))
(setq visval (LM:getvisibilityparametername obj))
(setq lst (LM:getdynpropallowedvalues obj visval))
(setq lst (cons "Please choose" lst))
(if (not AH:Butts)(load "Multi Radio buttons.lsp"))
(if (not AHbut)(setq AHbut 1))
(setq ans (ah:butts 1 "v"  lst))
(LM:SetVisibilityState obj ans)
(princ)
)

[chris_lee_3]

This worked well thank you.

Is there a way to make this work without the drafter needing to select the block? 

[_gile]

This will select all blocks named "block 1" and set their "Visibility1" dynamic property to "Off".

(if (ssget "_X" '((0 . "INSERT") (2 . "block 1")))
  (repeat (setq i (sslength ss))
    (setq block (ssname ss (setq i (1- i))))
    (setpropertyvalue
      bloc
      "AcDbDynBlockPropertyVisibility1"
      "Off"
    )
  )
)

[Sea-Haven]

If it is a dynamic block when inserted wont its name be like "*U23" ? You could look at say current space and use a ssget then check through the selection for "effective name" = "Block 1"

[chris_lee_3]

Hey Gilles, I’m trying but I cannot get this one to work. I am pasting them into the command line and I have double check the spelling and capitalization (within the block). The first one works beautifully but second one doesn’t. Do you have a suggestion?

[chris_lee_3]

Sea Haven,

That looks impressive.

But it is so over my head it makes me feel like I'm drowning.

Thank You though.    

[_gile · Accepted solution]

Oops!... My mistake.

(if (setq ss (ssget "_X" '((0 . "INSERT") (2 . "block 1,`*U*"))))
  (repeat (setq i (sslength ss))
    (setq block (ssname ss (setq i (1- i))))
    (if	(= (getpropertyvalue
	     (getpropertyvalue block "BlockTableRecord")
	     "Name"
	   )
	   "block 1"
	)
      (setpropertyvalue
	block
	"AcDbDynBlockPropertyVisibility1"
	"Off"
      )
    )
  )
)

[chris_lee_3]

Perfect, thank you very much.

[scot-65]

Gile,

This looks good, and it works, but will not work as a block nested inside a table cell.

Any thoughts?

I have tried fields in the cell, and that works, but would rather use the dynamic block method instead.

Scot-65

[mmitchellH6TRW]

Thank you. This could be what I am looking for.