duplicate AcDbText and turn it to AcDbAttributeDefinition
@Moshe-A wrote:
.... i tried to get the text database with (entget) and replace (0 . "text") to (0. "attdef") add tagname (2 . "tag") add prompt (3 . "prompt") add flag (70 . 0) and call (entmake elist) and it does not work, to me it look like the 210 field is interrupting?
....
The 210 entry is just the extrusion direction -- I wouldn't think that would interfere. But did you remove the entity name [e.g. (-1 . <Entity name: 34156060>)] entry and the handle [e.g. (5 . "8E3AE")] entry from the entity data list? You can't make a second entity with the same entity name or handle as another. If those were still in the list, try taking those out and see whether (entmake) works [I'm not guaranteeing... untested].
[Never mind -- I just opened up the AutoLisp Reference about (entmake), and it says that if the entity name and/or handle are present, they are ignored.]
EDIT AGAIN: But I thought the idea sounded familiar! Check >this< out, with its T2A command. I haven't analyzed to see what I may have done differently than what you've tried, but it works in minimal testing.
@dlanorh wrote:
1. Is this by any means or must I use "entmod"?
2. Where do you want the attdef in relation to the text?
T2A in the link in Message 4 does it with (entmake) rather than (entmod), which is also the way @Moshe-A described having trouble doing it in Message 1, so I assume that's okay. It leaves it in the same location, justification, rotation, size, style, etc., as the source Text, with the one difference that if it isn't already, it becomes ALL-UPPERCASE, because [for whatever unknown reason] Attribute Tags always are, no matter how you type them in.
@Moshe-A wrote:
....
As i said my situation is text is inside a block and the text it is not in WCS
can you run your code on that text?
....
I would think [without trying it] that it ought to work inside the Block Editor, as other commands do.
@Moshe-A wrote:
tried it, doesn't work. do you have an idea how can i transform it to wcs?
What does "doesn't work" mean? Does it not turn the Text into an Attdef while you are in the Block Editor? Does it succeed in doing that, but it's in the wrong place [a (trans) function should get around that]? Or does it succeed in doing that, but you don't see it in existing Insertions of the Block afterward? If it's the latter, ATTSYNC may be needed, and/or you may only need to double-click on an Insertion for the Attribute Editor to come up so you can give it a value, which T2A doesn't do for you [it uses the original text content for the Tag and the Prompt, but that's all].
This seems to work:
(vl-load-com)
(or *acad* (setq *acad* (vlax-get-acad-object)))
(or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
(or *blocks* (setq *blocks* (vla-get-Blocks *acdoc*)))
(defun c:test (/ blk props attdef)
(setq blk (vla-item *blocks* "a1"))
(vlax-for obj blk
(if (= (vla-get-ObjectName obj) "AcDbText")
(progn
(foreach prop '(Alignment
Backward
Layer
Linetype
LinetypeScale
Lineweight
Material
Normal
ObliqueAngle
Rotation
ScaleFactor
StyleName
Thickness
TrueColor
UpsideDown
Visible
)
(setq props (cons (cons prop (vlax-get-Property obj prop)) props))
)
(setq attdef (vla-AddAttribute blk
(vla-get-Height obj)
acAttributeModeConstant
""
(vlax-3d-point '(0. 0. 0.))
"CONST"
"this is now an attdef"
)
)
(foreach prop props
(vlax-put-Property attdef (car prop) (cdr prop))
)
(if (/= (vla-get-Alignment obj) 0)
(vla-put-TextAlignmentPoint attdef (vla-get-TextAlignmentPoint obj))
(vla-put-InsertionPoint attdef (vla-get-InsertionPoint obj))
)
(vla-Delete obj)
)
)
)
(vla-Regen *acdoc* acAllViewports)
(princ)
)
Still not sure to understand but you can try this new version, it seems to work with the drawing you posted.
(vl-load-com)
(or *acad* (setq *acad* (vlax-get-acad-object)))
(or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
(or *blocks* (setq *blocks* (vla-get-Blocks *acdoc*)))
(defun c:test (/ blk props attdef ll ur pt)
(setq blk (vla-item *blocks* "a1"))
(vlax-for obj blk
(if (= (vla-get-ObjectName obj) "AcDbText")
(progn
(vla-GetBoundingBox obj 'll 'ur)
(setq ll (vlax-safearray->list ll)
ur (vlax-safearray->list ur)
pt (list (/ (+ (car ll) (car ur)) 2.) (/ (+ (cadr ll) (cadr ur)) 2.) 0.)
)
(foreach prop '(Alignment
Backward
Layer
Linetype
LinetypeScale
Lineweight
Material
Normal
ObliqueAngle
Rotation
ScaleFactor
StyleName
Thickness
TrueColor
UpsideDown
Visible
)
(setq props (cons (cons prop (vlax-get-Property obj prop)) props))
)
(setq attdef (vla-AddAttribute blk
(vla-get-Height obj)
0
""
(vlax-3d-point '(0. 0. 0.))
"TAG"
(vla-get-Textstring obj)
)
)
(foreach prop props
(vlax-put-Property attdef (car prop) (cdr prop))
)
(vla-put-Alignment attdef acAlignmentMiddlecenter)
(vla-put-TextAlignmentPoint attdef (vlax-3d-point pt))
(vla-put-Visible obj :vlax-false)
)
)
)
(command-s "_.attsync" "_name" "a1")
(princ)
)
Gills,
As always you are right - it works - thank you very much.
the only different of what i did\has is that i set the alignment first then copied all other properties. turns out 'timing' is the most 'important thing' 
another issue with this kind of blocks (as "a1") is after mirror the return text angle is the block ucs and that still in some cases leave the text unreadable. sure you will say that need matrix transformation? but i for now decide to leave this problem to the users. they now have attributes and they can handle this on their own.
thanks
Moshe
