DrawOrder lisp Routine

[nbawden]

I found the following lisp routine over on the AUGI forums which was created by user alanjt

(defun c:Test (/ layerList data ss)
  (foreach layer '("Water" "Gas" "Electric" "Text" "Dimensions")
    (if (and (setq data (tblsearch "LAYER" layer)) ; layer exists
             (zerop (logand 4 (cdr (assoc 70 data)))) ; layer unlocked
             (setq ss (ssget "_X" (list (cons 8 layer)))) ; layer has objects
        )
      (command "_.draworder" ss "" "_front")
    )
  )
  (princ)
)

After looking around this lisp is almost exactly what I am after - except for one thing.

I would really like to be able to set all of the the specified layers to have their Draw Order below another specified layer.

Could any lisp gurus help out with this tweak?

[ВeekeeCZ · Accepted solution]

(defun c:Test (/ data ss en sr)
  (if (and (setq en (car (entsel "\nSelect object on reference layer: ")))
           (setq sr (ssget "_X" (list (assoc 8 (entget en))))))
    (foreach layer '("Water" "Gas" "Electric" "Text" "Dimensions")
      (if (and (setq data (tblsearch "LAYER" layer)) ; layer exists
               (zerop (logand 4 (cdr (assoc 70 data)))) ; layer unlocked
               (setq ss (ssget "_X" (list (cons 8 layer)))) ; layer has objects
               )
        (command "_.draworder" ss "" "_u" sr ""))))
  (princ)
)

[nbawden]

Thanks - this lisp works - but out of interest how would I tweak this lisp so that the layer being set in front of the others is fixed (hard coded) and not user selected?

[ВeekeeCZ · Accepted solution]

---

@nbawden wrote:

Thanks - this lisp works - but out of interest how would I tweak this lisp so that the layer being set in front of the others is fixed (hard coded) and not user selected?

---

I've simplified the code a little bit for you...

(defun c:Test (/ ss sr)
  (if (and (setq ss (ssget "_A" (list '(8 . "Water,Gas,Electric,Text,Dimensions") 	(cons 410 (getvar 'ctab)))))
           (setq sr (ssget "_A" (list '(8 . "ReferenceLayer1,ReferenceLayer2")		(cons 410 (getvar 'ctab)))))
           )
    (command "_.draworder" ss "" "_a" sr ""))
  (princ)
)

_a stands for "Above", previous "_u" is for "Under"... 

[nbawden]

Works a treat - thanks 

[Anonymous]

When I use this lisp, it asks me to select objects, ok. But then everything on the screen disappears. I don't know enough about lisp to read the routine and know what is happening. Any advice? Thanks.

[devitg]

Please do not repeat post 

https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/delete-a-lisp/td-p/7329186

[Anonymous]

This doesn't do anything.  Is there an update for AutoCAD Map 2019?

---

@ВeekeeCZ wrote:

(defun c:Test (/ data ss en sr)
  (if (and (setq en (car (entsel "\nSelect object on reference layer: ")))
           (setq sr (ssget "_X" (list (assoc 8 (entget en))))))
    (foreach layer '("Water" "Gas" "Electric" "Text" "Dimensions")
      (if (and (setq data (tblsearch "LAYER" layer)) ; layer exists
               (zerop (logand 4 (cdr (assoc 70 data)))) ; layer unlocked
               (setq ss (ssget "_X" (list (cons 8 layer)))) ; layer has objects
               )
        (command "_.draworder" ss "" "_u" sr ""))))
  (princ)
)

---

[dlanorh]

---

@Anonymous wrote:

This doesn't do anything.  Is there an update for AutoCAD Map 2019?

---

@ВeekeeCZ wrote:

(defun c:Test (/ data ss en sr)
  (if (and (setq en (car (entsel "\nSelect object on reference layer: ")))
           (setq sr (ssget "_X" (list (assoc 8 (entget en))))))
    (foreach layer '("Water" "Gas" "Electric" "Text" "Dimensions")
      (if (and (setq data (tblsearch "LAYER" layer)) ; layer exists
               (zerop (logand 4 (cdr (assoc 70 data)))) ; layer unlocked
               (setq ss (ssget "_X" (list (cons 8 layer)))) ; layer has objects
               )
        (command "_.draworder" ss "" "_u" sr ""))))
  (princ)
)

---

---

If you don't have these layers (red items above) in your drawing it won't

[pat_cooper54dkt]

Is there a way to incorporate using a wild card? I have multiple layers all beginning with "PHA"  and want them all sent to the back.

Thanks,

[devitg]

@pat_cooper54dkt 

Please upload the LSP you are using or want to modify , and a sample.dwg