draw a polyline, then offset it 7 cm, then erase the first polyline

[Anonymous]

i am new at autolisp

i tried to write the lisp by myself but i failed

it suppose to be easy for all you guys

thanx

[dlanorh]

Use the Offset command. If the drawing is in metres then offset distance is 0.07. If it is in millimetres the distance is 70.
Or is something else involved?

[Anonymous]

thanks for reply.

but distance is not the point.

i need a lisp that can draw a polyline with my selected points, and then offsets it,and then erase the first polyline

[CodeDing]

@Anonymous,

I believe this is what you're looking for. Double-check the units, and you will have to select which side to offset..

(defun c:OPL ( / ent)
;;Offset PolyLine

(command-s "_.PLINE")
(setq ent (entlast))
(prompt "\nSelect side to Offset...")

;;vvvvvvv Make sure units are correct vvvvvvvvv (70 is mm)
(command "_.OFFSET" 70 ent pause "")

(entdel ent)
(prompt "\nOPL Complete.")
(princ);finish quietly
);defun

Best,

~DD

[CodeDing · Accepted solution]

@Anonymous,

Correction.. Offset has a built-in erase function..

(defun c:OPL ()
;;Offset PolyLine
(command-s "_.PLINE")
;;vvvvvvv Make sure units are correct vvvvvvvvv (70 is mm)
(command "_.OFFSET" "e" "y" 70 (entlast) pause "")
(prompt "\nOPL Complete.")
(princ);finish quietly
);defun

Best,

~DD

[Anonymous]

thank you CodeDing

i coppied all codes to visual lisp editor and loaded

then entered "opl" command

it only draws polyline nothing else..

what am i doing wrong?

[dlanorh · Accepted solution]

---

@Anonymous wrote:

thank you CodeDing

i coppied all codes to visual lisp editor and loaded

then entered "opl" command

it only draws polyline nothing else..

what am i doing wrong?

---

Try this modified version of @CodeDing's code. Once the offset has happened you will need to end the Offset command with a right mouse button click or enter.

(defun c:OPL ( / of_dist pl)
  (setq of_dist (getvar 'offsetdist))
  ;;Draw PolyLine
  (command "_.PLINE")
  (while (= (logand (getvar "cmdactive") 1) 1) 
    (command pause)
  )   
  ;;vvvvvvv Make sure units are correct vvvvvvvvv (70 is mm)
  (setvar 'offsetdist 70)
  
  (setq pl (entlast));get last entity
  (command "_OFFSET" "" pl)
  (while (= (logand (getvar "cmdactive") 1) 1) 
    (command pause)
  )   
  (command "_erase" pl "");erase initial polyline  
  (prompt "\nOPL Complete.")
  (setvar 'offsetdist of_dist)  
  (princ);finish quietly
);defun

[dlanorh]

You should credit @CodeDing for the original code

[Anonymous]

YES! EXACTLY

IT WORKS PERFECT

thank you dlanorh.

I hope someday I can help you too.thanx 🙂

[Anonymous]

thanx dude.it is really helpful

[scottividal]

Hello, I have been reading this thread and others that I found. Although I understood some things, I can't get a routine to work for me. I'm trying to create a routine that selects all the objects from a specific layer, rectangles, circles, or polylines, and applies an offset to them with a distance of D to the outside. But I can't get the offset to be created. Here is a portion of the code to see if you can help me:

(setvar "OFFSETGAPTYPE" 0)

(setq DISTANCIA 0.025)

(command "_.-layer" "_s" "LAYER1" "")

(setq N (sslength ELEMENT))

(setq I 0)

  (while (< I N)

    (setq ENAME (ssname ELEMENT I)) 

    (if (and (eq (cdr (assoc 0 (entget ENAME))) "LWPOLYLINE")

             (eq (cdr (assoc 8 (entget ENAME))) "LAYER1"))

        (command "_.OFFSET" "e" "y" DISTANCIA ENAME pause "")

    )

    (setq I (1+ I))

  ) 

[Kent1Cooper]

---

@scottividal wrote:

.... I can't get the offset to be created. Here is a portion of the code ...:

....

        (command "_.OFFSET" "e" "y" DISTANCIA ENAME pause "")

.... 

---

Watch the command line:

Select object to offset or [Exit/Undo] <Exit>: {code feeds in your ENAME variable here}
*Invalid selection*
Expects a point or Exit

You can't give OFFSET just an entity name.  But giving it just a point can be dangerous, since the command could "see" something else that passes through the same point.  But you can combine an entity name with a determinable point, like what is returned by (entsel), and it will see only that entity at that point.  Try this:

        (command "_.OFFSET" "e" "y" DISTANCIA (list ENAME (vlax-curve-getStartPoint ENAME)) pause "")

[scottividal]

Thank you for the prompt response.

It still doesn't work.
If I only apply (command "_.OFFSET" "e" "y" DISTANCE (list ENAME (vlax-curve-getStartPoint ENAME)) pause ""), it asks me to indicate an interior or exterior point of the object. And when I do that, it creates the offset by deleting the original object.
I need two things: a) to make it work without having to indicate a point for each object. b) to not delete the original object.

[Kent1Cooper]

---

@scottividal wrote:

.... when I do that, it creates the offset by deleting the original object.

I need two things: a) to make it work without having to indicate a point for each object. b) to not delete the original object.

---

The deleting is because of the  "e" "y" part you have in there.  You can have that behave differently -- run the command manually to be sure of the prompts and the necessary answers.

The indicate-a-point part is also in your original [the pause is for that].  If you always want it outboard, you could try [simple, but in very limited circumstances could go wrong]:

        (command "_.OFFSET" "e" "n" DISTANCIA (list ENAME (vlax-curve-getStartPoint ENAME)) (getvar 'extmax) "")

[scottividal]

Dear: Thank you very much, now it works. You have been very helpful!